CPack Debian packaging, mk. 1

Author: TheAssassin

CMakeLists.txt

@@ -37,3 +37,6 @@ add_subdirectory(lib)
 
 # core source directory, contains its own CMakeLists.txt
 add_subdirectory(src)
+
+# packaging
+include(${PROJECT_SOURCE_DIR}/cmake/cpack-deb.cmake)

cmake/cpack-deb.cmake

@@ -0,0 +1,64 @@
+# required for DEB-DEFAULT to work as intended
+cmake_minimum_required(VERSION 3.6)
+
+# TODO: modify dependency lists depending on settings like USE_SYSTEM_CURL
+# this file has been built for the default settings
+
+set(PROJECT_VERSION 1.0)
+set(CPACK_GENERATOR "DEB")
+
+set(CPACK_DEBIAN_PACKAGE_DEBUG ON)
+
+# packaging only libappimageupdate for now
+#set(CPACK_COMPONENTS_ALL APPIMAGEUPDATE APPIMAGEUPDATETOOL LIBAPPIMAGEUPDATE LIBAPPIMAGEUPDATE-DEV LIBAPPIMAGEUPDATE-QT LIBAPPIMAGEUPDATE-QT-DEV)
+set(CPACK_COMPONENTS_ALL LIBAPPIMAGEUPDATE LIBAPPIMAGEUPDATE-DEV)
+
+# global options
+set(CPACK_PACKAGE_CONTACT "TheAssassin")
+set(CPACK_PACKAGE_HOMEPAGE "https://github.com/AppImage/AppImageUpdate")
+set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
+set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/LICENSE.txt")
+
+# allow building Debian packages on non-Debian systems
+if(DEFINED ENV{ARCH})
+    set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE $ENV{ARCH})
+    if(CPACK_DEBIAN_PACKAGE_ARCHITECTURE MATCHES "i686")
+        set(CPACK_DEBIAN_PACKAGE_ARCHITECTURE "i386")
+    endif()
+endif()
+
+# make sure to package components separately
+#set(CPACK_DEB_PACKAGE_COMPONENT ON)
+set(CPACK_DEB_COMPONENT_INSTALL ON)
+
+# override default package naming
+set(CPACK_DEBIAN_FILE_NAME DEB-DEFAULT)
+
+# Debian packaging global options
+set(CPACK_DEBIAN_COMPRESSION_TYPE xz)
+
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE_PACKAGE_NAME "libappimageupdate")
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE_PACKAGE_VERSION "${APPIMAGEUPDATE_VERSION}")
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE_PACKAGE_RELEASE "git${APPIMAGEUPDATE_GIT_COMMIT}")
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE_PACKAGE_DEPENDS "libcurl3, libstdc++6, libgcc1, libc6")
+
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE-DEV_PACKAGE_NAME "libappimageupdate-dev")
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE-DEV_PACKAGE_VERSION "${APPIMAGEUPDATE_VERSION}")
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE-DEV_PACKAGE_RELEASE "git${APPIMAGEUPDATE_GIT_COMMIT}")
+set(CPACK_DEBIAN_LIBAPPIMAGEUPDATE-DEV_PACKAGE_DEPENDS "libappimageupdate, libcurl3-gnutls-dev, libstdc++-5-dev")
+
+# improve dependency list
+set(CPACK_DEBIAN_PACKAGE_SHLIBDEPS ON)
+
+# TODO: insert some useful description
+set(CPACK_COMPONENT_APPIMAGELAUNCHER_PACKAGE_DESCRIPTION "AppImageLauncher")
+
+# find more suitable section for package
+set(CPACK_COMPONENT_APPIMAGELAUNCHER_PACKAGE_SECTION misc)
+
+# add postinst and prerm hooks to Debian package
+set(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA
+    "${PROJECT_SOURCE_DIR}/cmake/debian/postinst;${PROJECT_SOURCE_DIR}/cmake/debian/prerm")
+
+# must be the last instruction
+include(CPack)

src/CMakeLists.txt

@@ -30,6 +30,7 @@ add_subdirectory(elf)
 # core library
 add_library(
     libappimageupdate
+    SHARED
     ${PROJECT_SOURCE_DIR}/include/appimage/update.h updater.cpp
     util.h
 )
@@ -50,23 +51,50 @@ target_include_directories(libappimageupdate PUBLIC
     $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/lib/zsync2/include>
 )
 
+
+# core library
+add_library(
+    libappimageupdate_static
+    STATIC
+    ${PROJECT_SOURCE_DIR}/include/appimage/update.h updater.cpp
+    util.h
+)
+# since the target is called libsomething, one doesn't need CMake's additional lib prefix
+set_target_properties(libappimageupdate_static
+    PROPERTIES
+    PREFIX ""
+    OUTPUT_NAME "libappimageupdate"
+    PUBLIC_HEADER ${PROJECT_SOURCE_DIR}/include/appimage/update.h
+)
+# link thread libraries
+target_link_libraries(libappimageupdate_static PUBLIC elf PRIVATE ${CMAKE_THREAD_LIBS_INIT} libzsync2 ${CPR_LIBRARIES})
+# include directories, publicly
+target_include_directories(libappimageupdate_static PUBLIC
+    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
+    $<INSTALL_INTERFACE:include>
+    # FIXME: works for now, but should be possible without these workaround
+    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/lib/zsync2/lib/cpr/include>
+    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/lib/zsync2/include>
+)
+
+
 # CLI application
 add_executable(appimageupdatetool main.cpp)
 # link to core lib
 target_link_libraries(appimageupdatetool libappimageupdate args)
 
 # install targets
 install(
-    TARGETS libappimageupdate appimageupdatetool
-    RUNTIME DESTINATION bin
-    LIBRARY DESTINATION lib
-    ARCHIVE DESTINATION lib/static
-    PUBLIC_HEADER DESTINATION include/appimage
+    TARGETS libappimageupdate libappimageupdate_static appimageupdatetool
+    RUNTIME DESTINATION bin COMPONENT APPIMAGEUPDATETOOL
+    LIBRARY DESTINATION lib COMPONENT LIBAPPIMAGEUPDATE
+    ARCHIVE DESTINATION lib COMPONENT LIBAPPIMAGEUPDATE
+    PUBLIC_HEADER DESTINATION include/appimage COMPONENT LIBAPPIMAGEUPDATE-DEV
 )
 
 
 # include Qt UI
 set(BUILD_QT_UI BOOL CACHE "Build Qt UI (widget library and demo application)" OFF)
-if (BUILD_QT_UI)
+if(BUILD_QT_UI)
     add_subdirectory(qt-ui)
 endif()

src/qt-ui/CMakeLists.txt

@@ -31,8 +31,8 @@ target_compile_definitions(AppImageUpdate PRIVATE -DQT_UI)
 # install targets
 install(
     TARGETS libappimageupdate-qt AppImageUpdate
-    RUNTIME DESTINATION bin
-    LIBRARY DESTINATION lib
-    ARCHIVE DESTINATION lib/static
-    PUBLIC_HEADER DESTINATION include/appimage/update
+    RUNTIME DESTINATION bin COMPONENT APPIMAGEUPDATE
+    LIBRARY DESTINATION lib COMPONENT LIBAPPIMAGEUPDATE-QT
+    ARCHIVE DESTINATION lib COMPONENT LIBAPPIMAGEUPDATE-QT
+    PUBLIC_HEADER DESTINATION include/appimage/update COMPONENT LIBAPPIMAGEUPDATE-QT-DEV
 )