mitm2openapi/flake.nix at main · Arkptz/mitm2openapi · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
{
  description = "mitm2openapi — convert mitmproxy/HAR captures to OpenAPI 3.0 specs";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
      ...
    }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ (import rust-overlay) ];
      };
      toolchain = pkgs.rust-bin.stable.latest.default.override {
        extensions = [
          "rust-src"
          "rust-analyzer"
        ];
      };

      oasdiff = pkgs.buildGoModule rec {
        pname = "oasdiff";
        version = "1.11.10";

        src = pkgs.fetchFromGitHub {
          owner = "oasdiff";
          repo = "oasdiff";
          rev = "v${version}";
          hash = "sha256-/Pk2mKzdYKl51RvEkm5yRDMHz2vISgoHlnel+llDJus=";
        };

        vendorHash = "sha256-ZKs9Ai8Q9Yj4V9GIufYRh9cl3ZUKnSehwpaodyGXtfg=";
        subPackages = [ "." ];

        ldflags = [
          "-s"
          "-w"
        ];
      };
    in
    {
      packages.${system}.default = pkgs.rustPlatform.buildRustPackage {
        pname = "mitm2openapi";
        version = "0.1.0";
        src = ./.;
        cargoLock.lockFile = ./Cargo.lock;
        nativeBuildInputs = [ pkgs.pkg-config ];
        buildInputs = [ pkgs.openssl ];
      };

      devShells.${system}.default = pkgs.mkShell {
        buildInputs = [
          toolchain
          pkgs.pkg-config
          pkgs.openssl

          # capture
          pkgs.python3
          pkgs.python3Packages.mitmproxy

          # integration tests
          oasdiff
          pkgs.nodejs
          pkgs.shfmt
          pkgs.actionlint
          pkgs.yq-go
          pkgs.prettier

          # demo GIF pipeline
          pkgs.act
          pkgs.vhs
          pkgs.ffmpeg
          pkgs.gifski
          pkgs.gifsicle
        ];
      };
    };
}