StationofDoomPlugin/build.gradle.kts at master · AtomPilz-DevTeam/StationofDoomPlugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
import net.minecrell.pluginyml.bukkit.BukkitPluginDescription

plugins {
    id("java")
    id("xyz.jpenilla.run-paper") version "3.0.2"
    id("net.minecrell.plugin-yml.bukkit") version "0.6.0"
    id("io.papermc.paperweight.userdev") version "2.0.0-beta.21"
    id("maven-publish")
    id("com.modrinth.minotaur") version "2.+"
}

val minecraftVersion = "1.21.11"
val pluginVersion: String = "1.15.1" + if (System.getenv("runnumber") != null) "." + System.getenv("runnumber") else ""

group = "com.github.atompilz-devteam"
version = pluginVersion

repositories {
    mavenLocal()
    maven { url = uri("https://repo.papermc.io/repository/maven-public/") }
}

dependencies {
    library("com.google.code.gson:gson:2.13.2")
    library("club.minnced:discord-webhooks:0.8.4")
    paperweight.paperDevBundle("$minecraftVersion-R0.1-SNAPSHOT")
    library("org.postgresql:postgresql:42.7.10")
    library("de.chojo.sadu:sadu-postgresql:2.3.8")
    library("de.chojo.sadu:sadu-datasource:2.3.8")
    library("de.chojo.sadu:sadu-queries:2.3.8")
    library("com.zaxxer:HikariCP:6.3.3")
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
}

tasks {
    runServer {
        minecraftVersion(minecraftVersion)
    }

    withType<JavaCompile> {
        options.encoding = "UTF-8"
    }

    compileJava {
        options.encoding = "UTF-8"
    }
}

modrinth {
    token.set(System.getenv("MODRINTH_TOKEN"))
    projectId.set("NgIVqJpi")
    versionNumber.set(pluginVersion)
    val releaseType = if (System.getenv("modrinthrelease") == "release") "release" else "alpha"
    versionType.set(releaseType)
    uploadFile.set(tasks.jar)
    gameVersions.add(minecraftVersion)
    loaders.addAll("paper", "purpur", "folia")
    syncBodyFrom = rootProject.file("README.md").readText()
}

publishing {
    publications {
        create<MavenPublication>("release") {
            groupId = "com.github.atompilz-devteam"
            artifactId = "stationofdoom"
            version = pluginVersion
            from(components["java"])
        }

        create<MavenPublication>("snapshot") {
            groupId = "com.github.atompilz-devteam"
            artifactId = "stationofdoom"
            version = "$pluginVersion-SNAPSHOT"
            from(components["java"])
        }
    }
}


bukkit {
    name = "StationOfDoom"
    version = pluginVersion
    description = ""

    main = "de.j.stationofdoom.main.Main"

    generateLibrariesJson = true

    foliaSupported = true

    apiVersion = "1.20"

    load = BukkitPluginDescription.PluginLoadOrder.STARTUP
    authors = listOf("LuckyProgrammer")

}