build.gradle

version = '1.0'

def v = [
            spring: '3.1.4.RELEASE',
            slf4j: '1.7.5',
            logback: '1.0.13'
]

subprojects {
    apply plugin: 'eclipse'
    apply plugin: 'idea'
    apply plugin: 'java'

    repositories {
        mavenCentral()
    }
    idea {
        module {
            downloadSources = true
        }
    }
}

project(':zipExample') {
    dependencies {
        compile project(':zipStarter')
    }
    task myjar(type: Jar) {
        into('/') {
            from project(':zipStarter').sourceSets.main.output
        }
        into('classes') {
            from sourceSets.main.output
        }
        destinationDir = file("$buildDir/libs")
        archiveName = 'zipExample.zip'
        manifest {
            attributes 'Main-Class': 'boot.ZipStarter'
            attributes 'ZipStarter-Class-Path': 'classes'
            attributes 'ZipStarter-Main-Class': 'com.sahlbach.zipstarter.zip.HelloWorld'
        }
        doLast {
            println "Try this: java -jar zipExample/build/libs/zipExample.zip"
        }
    }
    jar {
        actions = []
        dependsOn myjar
    }

}

project(':warExample') {
    apply plugin: 'jetty'
    dependencies {
        compile("org.springframework:spring-webmvc:$v.spring")
        compile("ch.qos.logback:logback-classic:$v.logback")
        runtime("org.slf4j:slf4j-api:$v.slf4j",
                "org.slf4j:jcl-over-slf4j:$v.slf4j")
        providedCompile project(':zipStarter')
    }
    configurations {
        all*.exclude group: "commons-logging", module: "commons-logging"
    }
    war {
        manifest {
            attributes 'Main-Class': 'boot.ZipStarter'
            attributes 'ZipStarter-Class-Path': 'WEB-INF/classes WEB-INF/lib'
            attributes 'ZipStarter-Main-Class': 'com.sahlbach.zipstarter.war.HelloWebWorld'
        }
        archiveName = 'warExample.war'
        into('/') {
            from project(':zipStarter').sourceSets.main.output
        }
        doLast {
            println "Try this: java -jar warExample/build/libs/warExample.war"
            println "Try gradle jettyRun and access http://localhost:8080/warExample/service/hello"
        }
    }

}