build.gradle

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '2.3.20'
    id 'signing'
    id 'maven-publish'
}

java {
    withSourcesJar()
    withJavadocJar()
    // Pattern-matching switch in Connection.coerceParam requires Java 21+.
    // Keep this in sync with CMAKE_JAVA_COMPILE_FLAGS in CMakeLists.txt and
    // the java.version / maven.compiler.{source,target} POM properties below.
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

// Kotlin must target the same JVM level as Java, otherwise Gradle refuses
// to build (inconsistent jvm-target between compileTestJava and compileTestKotlin).
tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        jvmTarget = '21'
    }
}

group = 'com.ladybugdb'
def projectRoot = projectDir.parentFile.parentFile
def cmakeFileRef = new File(projectRoot, 'CMakeLists.txt')
if (!cmakeFileRef.exists()) {
    cmakeFileRef = new File(projectDir.parentFile, 'ladybug/CMakeLists.txt')
}
if (cmakeFileRef.exists()) {
    def cmakeFile = cmakeFileRef.text
    def versionLine = cmakeFile.readLines().find { it.startsWith('project(Lbug VERSION ') }
    def cmakeVersion = versionLine.split(' ')[2]
    def versionParts = cmakeVersion.split('\\.')
    if (versionParts.length > 3) {
        version = versionParts[0] + '.' + versionParts[1] + '.' + versionParts[2] + '-SNAPSHOT'
    } else {
        version = cmakeVersion
    }
} else {
    version = providers.environmentVariable('LBUG_JAVA_VERSION').orElse('0.0.0-SNAPSHOT').get()
}

println "Project version: $version"

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.apache.arrow:arrow-c-data:18.2.0'
    implementation 'org.apache.arrow:arrow-vector:18.2.0'
    implementation 'org.apache.arrow:arrow-memory-core:18.2.0'
    testImplementation platform('org.junit:junit-bom:5.10.0')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testRuntimeOnly 'org.apache.arrow:arrow-memory-netty:18.2.0'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

if (System.getenv('SKIP_CMAKE_BUILD') != 'true') {
    processResources {
        dependsOn 'copyNativeLibs'
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            pom {
                name = 'lbug'
                description = 'Lbug is an embedded graph database built for query speed and scalability.'
                url = 'http://ladybugdb.com'
                inceptionYear = '2020'
                properties = [
                        'project.build.sourceEncoding'    : 'UTF-8',
                        'project.reporting.outputEncoding': 'UTF-8',
                        'java.version'                    : '21',
                        'maven.compiler.source'           : '21',
                        'maven.compiler.target'           : '21'
                ]
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://github.com/LadybugDB/ladybug/blob/master/LICENSE'
                    }
                }
                developers {
                    developer {
                        id = 'ladybugdb'
                        name = 'LadybugDB'
                        email = 'social@ladybugdb.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/LadybugDB/ladybug.git'
                    developerConnection = 'scm:git:ssh://github.com/LadybugDB/ladybug.git'
                    url = 'https://github.com/LadybugDB/ladybug'
                }
            }
            from components.java
        }
    }

    repositories {
        // The local repository is used for manual publishing to Maven Central
        // Portal. It is located in `build/repo`.
        // To publish, run `././gradlew publishMavenJavaToLocalRepo`
        // This is a workaround to force Gradle handle signing and checksum
        maven {
            name = 'LocalRepo'
            url = uri("$buildDir/repo")
        }
        maven {
            name = 'GitHubPackages'
            url = uri('https://maven.pkg.github.com/LadybugDB/ladybug')
            credentials {
                username = System.getenv('GITHUB_ACTOR')
                password = System.getenv('GITHUB_TOKEN')
            }
        }
    }
}

signing {
    def signingKey = providers
            .environmentVariable("GPG_SIGNING_KEY")
    def signingPassphrase = providers
            .environmentVariable("GPG_SIGNING_PASSPHRASE")
    if (signingKey.isPresent() && signingPassphrase.isPresent()) {
        useInMemoryPgpKeys(signingKey.get(), signingPassphrase.get())
        sign publishing.publications.mavenJava
    } else {
        println "Skipping signing, no GPG key found"
    }
}

task cmake(type: Exec) {
    workingDir '../..'
    commandLine 'make', 'java'
    environment NUM_THREADS: Runtime.getRuntime().availableProcessors()
}

task copyNativeLibs(type: Copy) {
    from('build') {
        include 'liblbug_java_native.*'
    }
    into 'src/main/resources'
    dependsOn 'cmake'
}

tasks.sourcesJar {
    mustRunAfter 'copyNativeLibs'
}

test {
    useJUnitPlatform()
    systemProperty 'ladybug.projectDir', projectDir.absolutePath
    testLogging {
        events 'passed', 'skipped', 'failed'
        exceptionFormat = 'full'
        showStandardStreams = true
    }
    jvmArgs(
            '-XX:+UnlockDiagnosticVMOptions',
            "-XX:ErrorFile=${layout.buildDirectory.file('hs_err_pid%p.log').get().asFile.absolutePath}",
            '-XX:+CreateCoredumpOnCrash'
    )
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}