gpd/duo: init GPD Duo profile

- Fix boot screen invertion.
- Add audio fixes for the Framework 13, given a shared chipset.
- Add Bluetooth fixes.
- Import AMD 7000-series GPU fix (Raphael).
- Add GPD PPT (TDP) control from GPD Win Max 2
- Set `panel_orientation` kernel parameter.
- Add AC wakeup fix as a config option; disabled by default.
- Enable `power-profiles-daemon` by default, and disable TLP - can be
  configured.
- Disable both PSR and PSR-SU on amdgpu module.
- Fix touchscreen properties - upside down rotation
- Update README.md for GPD Duo.

Co-authored-by: Dom Rodriguez <[email protected]>

Author: mavericm1

README.md

@@ -215,6 +215,7 @@ See code for all available configurations.
 | [Gigabyte B550](gigabyte/b550)                                                    | `<nixos-hardware/gigabyte/b550>`                        | `gigabyte-b550`                        |
 | [Gigabyte B650](gigabyte/b650)                                                    | `<nixos-hardware/gigabyte/b650>`                        | `gigabyte-b650`                        |
 | [GMKtec NucBox G3 Plus](gmktec/nucbox/g3-plus)                                    | `<nixos-hardware/gmktec/nucbox/g3-plus>`                | `gmktec-nucbox-g3-plus`                |
+| [GPD Duo](gpd/duo)                                                                | `<nixos-hardware/gpd/duo>`                              | `gpd-duo`                         |
 | [GPD MicroPC](gpd/micropc)                                                        | `<nixos-hardware/gpd/micropc>`                          | `gpd-micropc`                          |
 | [GPD P2 Max](gpd/p2-max)                                                          | `<nixos-hardware/gpd/p2-max>`                           | `gpd-p2-max`                           |
 | [GPD Pocket 3](gpd/pocket-3)                                                      | `<nixos-hardware/gpd/pocket-3>`                         | `gpd-pocket-3`                         |

flake.nix

@@ -182,6 +182,7 @@
           gigabyte-b650 = import ./gigabyte/b650;
           gmktec-nucbox-g3-plus = import ./gmktec/nucbox/g3-plus;
           google-pixelbook = import ./google/pixelbook;
+          gpd-duo = import ./gpd/duo;
           gpd-micropc = import ./gpd/micropc;
           gpd-p2-max = import ./gpd/p2-max;
           gpd-pocket-3 = import ./gpd/pocket-3;

gpd/duo/default.nix

@@ -0,0 +1,60 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.hardware.gpd.duo;
+in
+with lib;
+{
+  imports = [
+    ./duo-specific
+    ../../common/pc/laptop
+    ../../common/pc/ssd
+    ../../common/hidpi.nix
+  ];
+
+  options = {
+    hardware.gpd.duo.preventWakeOnAC = mkOption {
+      type = types.bool;
+      default = false;
+      description = ''
+        Stop the system waking from suspend when the AC is plugged
+        in. The catch: it also disables waking from the keyboard.
+
+        See:
+        https://community.frame.work/t/tracking-framework-amd-ryzen-7040-series-lid-wakeup-behavior-feedback/39128/45
+      '';
+    };
+  };
+
+  config = {
+    # Workaround applied upstream in Linux >=6.7 (on BIOS 03.03)
+    # https://github.com/torvalds/linux/commit/a55bdad5dfd1efd4ed9ffe518897a21ca8e4e193
+    services.udev.extraRules =
+      mkIf (versionOlder config.boot.kernelPackages.kernel.version "6.7" && cfg.preventWakeOnAC)
+        ''
+          # Prevent wake when plugging in AC during suspend. Trade-off: keyboard wake disabled. See:
+          # https://community.frame.work/t/tracking-framework-amd-ryzen-7040-series-lid-wakeup-behavior-feedback/39128/45
+          ACTION=="add", SUBSYSTEM=="serio", DRIVERS=="atkbd", ATTR{power/wakeup}="disabled"
+        '';
+
+    # Replace 'left' with 'right' or 'inverted' as needed
+    # Fixes DUO stupid inverted display at boot
+    # Enable kernel module for your graphics (adjust if needed)
+    boot.kernelModules = [ "amdgpu" ];
+
+    # Set the eDP-1 panel video parameters for display rotation
+    boot.kernelParams = mkBefore [
+      "video=eDP-1:2880x1800,panel_orientation=upside_down"
+      "video=DP-3:2880x1800"
+      "i2c_touchscreen_props=GXTP7380:touchscreen-inverted-x:touchscreen-inverted-y"
+    ];
+
+    hardware.gpd.duo.audioEnhancement.rawDeviceName =
+      mkDefault "alsa_output.pci-0000_c1_00.6.analog-stereo";
+  };
+}

gpd/duo/duo-specific/amd.nix

@@ -0,0 +1,28 @@
+{ lib, config, ... }:
+with lib;
+{
+  imports = [
+    ../../../common/cpu/amd
+    ../../../common/cpu/amd/pstate.nix
+    ../../../common/gpu/amd
+  ];
+
+  boot.kernelParams =
+    [
+      # There seems to be an issue with panel self-refresh (PSR) that
+      # causes hangs for users.
+      #
+      # https://community.frame.work/t/fedora-kde-becomes-suddenly-slow/58459
+      # https://gitlab.freedesktop.org/drm/amd/-/issues/3647
+      "amdgpu.dcdebugmask=0x210"
+    ]
+    # Workaround for SuspendThenHibernate: https://lore.kernel.org/linux-kernel/[email protected]/
+    ++ optionals (versionOlder config.boot.kernelPackages.kernel.version "6.8") [
+      "rtc_cmos.use_acpi_alarm=1"
+    ];
+
+  # AMD has better battery life with PPD over TLP:
+  # https://community.frame.work/t/responded-amd-7040-sleep-states/38101/13
+  services.power-profiles-daemon.enable = mkDefault true;
+  services.tlp.enable = mkDefault false;
+}