Unit discrepancy between SKY130 (gds extraction in um) and GF180 (gds extraction in SI)

[amisapta15]

There is a documented unit discrepancy between SKY130 and GF180 when extracting the Netlist from the Layout for the LVS operation.

• For Sky130:
  The tech file included in the open_pdk tech stack extracts the Netlist from the GDS using the um units by default. This does not cause an error in the LVS as the Schematic Netlist generated in the gLayout is also extracted in microns (μm) units. Thus, the LVS passes.

Extracted from Layout

* NGSPICE file created from FVF.ext - technology: sky130A
.subckt FVF VBULK VIN VOUT Ib
X0 VBULK VBULK VBULK VBULK sky130_fd_pr__nfet_01v8 ad=1.425 pd=6.95 as=12.825 ps=62.55 w=3 l=0.15
X1 VBULK VBULK VBULK VBULK sky130_fd_pr__nfet_01v8 ad=1.425 pd=6.95 as=0 ps=0 w=3 l=0.15
X2 VBULK VBULK VBULK VBULK sky130_fd_pr__nfet_01v8 ad=1.425 pd=6.95 as=0 ps=0 w=3 l=0.15
X3 VOUT Ib VBULK VBULK sky130_fd_pr__nfet_01v8 ad=1.425 pd=6.95 as=1.425 ps=6.95 w=3 l=0.15
X4 Ib VIN VOUT VBULK sky130_fd_pr__nfet_01v8 ad=1.425 pd=6.95 as=1.425 ps=6.95 w=3 l=0.15
X5 VBULK VBULK VBULK VBULK sky130_fd_pr__nfet_01v8 ad=1.425 pd=6.95 as=0 ps=0 w=3 l=0.15
.ends

Extracted from Schematic

.include /foss/designs/Subham_MR/gLayout/src/glayout/pdk/sky130_mapped/sky130_fd_sc_hd.spice
.subckt NMOS D G S B l=0.15 w=3 m=1 dm=1 
XMAIN   D G S B sky130_fd_pr__nfet_01v8 l={l} w={w} m={m}
XDUMMY1 B B B B sky130_fd_pr__nfet_01v8 l={l} w={w} m={dm}
XDUMMY2 B B B B sky130_fd_pr__nfet_01v8 l={l} w={w} m={dm}
.ends NMOS

.subckt FVF VIN VBULK VOUT Ib
X0 Ib VIN VOUT VBULK NMOS l=0.15 w=3 m=0.5 dm=1
X1 VOUT Ib VBULK VBULK NMOS l=0.15 w=3 m=0.5 dm=1
.ends FVF

This pass.

• For GF180
  The tech file extracts the Netlist from the layout in SI units. However, gLayout still extracts the Netlist from the schematic in micros. This causes a discrepancy in the element sizing between the two Netlists, causing the LVS to fail with this error

Netlists match uniquely with property errors.
nfet_03v3:2 vs. NMOS:0/nfet_03v3:MAIN:
 l circuit1: 2.8e-07   circuit2: 0.28   (delta=200%, cutoff=1%)
 w circuit1: 3e-06   circuit2: 3   (delta=200%, cutoff=1%)
nfet_03v3:0 vs. NMOS:0/nfet_03v3:DUMMY1:
 l circuit1: 2.8e-07   circuit2: 0.28   (delta=200%, cutoff=1%)
 w circuit1: 3e-06   circuit2: 3   (delta=200%, cutoff=1%)
nfet_03v3:3 vs. NMOS:1/nfet_03v3:MAIN:
 l circuit1: 2.8e-07   circuit2: 0.28   (delta=200%, cutoff=1%)
 w circuit1: 3e-06   circuit2: 3   (delta=200%, cutoff=1%)

The Layout Extracted netlist (note the u as in microns)

* NGSPICE file created from FVF.ext - technology: gf180mcuD
.subckt FVF VBULK VIN VOUT Ib
X0 VBULK VBULK VBULK VBULK nfet_03v3 ad=2.19p pd=7.46u as=19.77p ps=67.18u w=3u l=0.28u
X1 VBULK VBULK VBULK VBULK nfet_03v3 ad=2.19p pd=7.46u as=0 ps=0 w=3u l=0.28u
X2 Ib VIN VOUT VBULK nfet_03v3 ad=2.25p pd=7.5u as=2.25p ps=7.5u w=3u l=0.28u
X3 VOUT Ib VBULK VBULK nfet_03v3 ad=2.25p pd=7.5u as=2.25p ps=7.5u w=3u l=0.28u
X4 VBULK VBULK VBULK VBULK nfet_03v3 ad=2.19p pd=7.46u as=0 ps=0 w=3u l=0.28u
X5 VBULK VBULK VBULK VBULK nfet_03v3 ad=2.19p pd=7.46u as=0 ps=0 w=3u l=0.28u
.ends

and the schematic netlist

.include /foss/designs/Subham_MR/gLayout/src/glayout/pdk/gf180_mapped/gf180mcu_osu_sc_9T.spice
.subckt NMOS D G S B l=0.28 w=3 m=1 dm=1 
XMAIN   D G S B nfet_03v3 l={l} w={w} m={m}
XDUMMY1 B B B B nfet_03v3 l={l} w={w} m={dm}
XDUMMY2 B B B B nfet_03v3 l={l} w={w} m={dm}
.ends NMOS

.subckt FVF VIN VBULK VOUT Ib
X0 Ib VIN VOUT VBULK NMOS l=0.28 w=3 m=0.5 dm=1
X1 VOUT Ib VBULK VBULK NMOS l=0.28 w=3 m=0.5 dm=1
.ends FVF

[amisapta15]

This is a known problem as discussed in here and mentioned here (in the context of Klayout), See Workarounds, Point - 3 in README

The GF180 use SI units, and SKY130 use micron units.

[amisapta15]

On the Layout Netlist generation side, there is an option to extract the Netlist in SI units by seting extract style <style_name> where the style by default is ngspice() and can be set to ngspice(SI). Available extraction Styles can be seen by extract style listall

This approach makes the extraction from the Layout in SI units for all PDKs.

However, this does not solve the issue completely as the Schematic SPICE generated in gLayout is in micros without a unit identifier, as can be seen from the previous comment.

The easiest solution would have been to add a .option SCALE=1e-6 in the schematic netlist, to make sure all units are converted to SI units. However, netgen currently does not support the SCALE parameter in Netlist.

[amisapta15]

As I see it, there are two ways forward:

• Change gLayout LVS and Schematic Netlist Generation

  • Add extract style in case of SKy130 to SI
  • Change the Schematic Netlist function in fet.py to add u micron unit identifier in the Netlist generation.

• Or, switch to Klayout for LVS, which supports the scale option
  (See the same thread) or the repo instructions

The command would be
klayout -b -rd schematic=sky130_inverter.spice -rd lvs_sub=VSS -rd scale=true -r sky130_lvs.rb
with

# Load layout and set parameters
ly = RBA::Layout.new
ly.read("sky130_inverter.gds")
lvs = RBA::Lvs::lvs()

# Configure for Sky130 (micron units)
lvs.scale = $scale
lvs.schematic = $schematic
lvs.lvs_sub = $lvs_sub

# Run and output
lvs.compare
lvs.report("sky130_lvs.html")

Batch runs generate two files:

• lvs_report.html: Interactive HTML report with mismatch details.
• comp.out: Plain-text summary (pass/fail indicators)