build.gradle

import io.gitlab.arturbosch.detekt.Detekt

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    dependencies {
        classpath libs.agp.buildscript
        classpath libs.kotlin.gradle
        classpath libs.nexus.staging
    }
}

plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.nexus.publish) apply false
    alias(libs.plugins.detekt)
}

tasks.withType(Detekt).configureEach {
    // Files to analyze
    setSource(files(rootProject.rootDir))

    // Configuration
    config.setFrom(files("$projectDir/detekt.yml"))
    allRules = true
    buildUponDefaultConfig = true

    reports {
        html.required.set(true)
        html.outputLocation.set(layout.buildDirectory.file("reports/detekt/detekt-report.html"))

        xml.required.set(true)
        xml.outputLocation.set(layout.buildDirectory.file("reports/detekt/detekt-checkstyle.xml"))
    }
}


tasks.register('clean', Delete) {
    delete rootProject.layout.buildDirectory
}

allprojects {
    group = 'com.telefonica.nestedscrollwebview'
    if (System.getProperty("SNAPSHOT_VERSION") != null) {
        version = System.getProperty("SNAPSHOT_VERSION")+"-SNAPSHOT"
    } else {
        version = System.getProperty("LIBRARY_VERSION") ?: "undefined"
    }
}
apply from: "${rootProject.projectDir}/publish_maven_central.gradle"