build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.5-SNAPSHOT" apply false
    id 'io.github.juuxel.loom-quiltflower' version '1.7.2' apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"
    apply plugin: "io.github.juuxel.loom-quiltflower"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.layered() {
            officialMojangMappings()
            parchment("org.parchmentmc.data:parchment-${rootProject.mappings}")
        }
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.archives_base_name
    version = "${rootProject.mod_version}+${rootProject.minecraft_version}" as Object
    group = rootProject.maven_group

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
        options.release = 17
    }

    repositories {
        // NeoForge
        maven { url "https://maven.neoforged.net/releases/" }

        // KubeJS / Rhino
        maven {
            // saps.dev Maven (KubeJS and Rhino)
            url = 'https://maven.saps.dev/releases'
            content {
                includeGroup 'dev.latvian.mods'
            }
        }

        // ThreeTAG
        maven {
            url 'https://maven.threetag.net'
        }

        // Parchment
        maven {
            url = 'https://maven.parchmentmc.net/'
            content {
                includeGroup 'org.parchmentmc.data'
            }
        }

        // CurseMaven
        maven {
            url = 'https://www.cursemaven.com'
            content {
                includeGroup 'curse.maven'
            }
        }

        // Modrinth
        maven {
            name = "Modrinth"
            url = "https://api.modrinth.com/maven"
            content {
                includeGroup 'maven.modrinth'
            }
        }

        // Trinkets
        maven {
            url = 'https://maven.terraformersmc.com/releases/'
        }

        // Architectury / REI
        maven {
            url = 'https://maven.shedaniel.me'
        }

        // JEI
        maven {
            url = 'https://dvs1.progwml6.com/files/maven/'
        }

        // Cardinal Components
        maven {
            name = 'Ladysnake Mods'
            url = 'https://maven.ladysnake.org/releases'
        }

        // Curios
        maven {
            url = 'https://maven.theillusivec4.top/'
        }

        // Ingredient Extension API
        maven {
            url = 'https://maven.blamejared.com'
        }

        // JitPack
        maven {
            url = 'https://jitpack.io'
        }

        // ForgeConfigAPI Port
        maven {
            name = "Fuzs Mod Resources"
            url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/"
        }

        // Player Animator
        maven {
            name = "KosmX's maven"
            url = 'https://maven.kosmx.dev/'
        }

        // GeckoLib
        maven {
            name = 'Gecko Lib'
            url = 'https://dl.cloudsmith.io/public/geckolib3/geckolib/maven/'
        }

        // Condensed Creative
        maven {
            url = 'https://maven.wispforest.io'
        }

        // Porting Lib
        maven { url = "https://mvn.devos.one/snapshots/" }

        // ReachEntityAttributes
        maven {
            url = 'https://maven.jamieswhiteshirt.com/libs-release'
            content {
                includeGroup 'com.jamieswhiteshirt'
            }
        }

        // Quilt
        maven { url "https://maven.quiltmc.org/repository/release/" }
    }

    java {
        withSourcesJar()
    }
}