EnhancedTooltips/settings.gradle.kts at main · UltimatChamp/EnhancedTooltips · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
pluginManagement {
    repositories {
        mavenCentral()
        gradlePluginPortal()
        maven("https://maven.architectury.dev")
        maven("https://maven.fabricmc.net")
        maven("https://maven.neoforged.net/releases")
        maven("https://maven.kikugie.dev/snapshots")
    }
}

plugins {
    id("dev.kikugie.stonecutter") version "0.8.3"
}

stonecutter {
    create(rootProject) {
        fun register(version: String, vararg loaders: String) = loaders
            .forEach {
                if (it == "fabric" && stonecutter.eval(version, ">1.21.11"))
                    version("$version-$it", version).buildscript = "build.fabric_noremap.gradle.kts"
                else version("$version-$it", version).buildscript = "build.$it.gradle.kts"
            }

        register("1.21.1", "fabric", "neo")
        register("1.21.3", "fabric", "neo")
        register("1.21.4", "fabric", "neo")
        register("1.21.5", "fabric", "neo")
        register("1.21.8", "fabric", "neo")
        register("1.21.10", "fabric", "neo")
        register("1.21.11", "fabric", "neo")
        register("26.1.2", "fabric", "neo")

        vcsVersion = "26.1.2-fabric"
    }
}

rootProject.name = "EnhancedTooltips"