Pawn 3.2.3664 code with samp_compatible patches applied

Author: Zeex

EXAMPLES/argument.p

@@ -0,0 +1,10 @@
+#include <args>
+
+main()
+    {
+    printf "Argument count = %d\n", argcount()
+
+    new opt[100]
+    for (new index = 0; argindex(index, opt); index++)
+        printf "Argument %d = %s\n", index, opt
+    }

EXAMPLES/c2f.p

@@ -0,0 +1,14 @@
+#include <rational>
+
+main()
+    {
+    new Rational: Celsius
+    new Rational: Fahrenheit
+
+    print "Celsius\t Fahrenheit\n"
+    for (Celsius = 5; Celsius <= 25; Celsius++)
+        {
+        Fahrenheit = (Celsius * 1.8) + 32
+        printf "%r \t %r\n", Celsius, Fahrenheit
+        }
+    }

EXAMPLES/capt.p

@@ -0,0 +1,37 @@
+bool: ispacked(string[])
+    return bool: (string[0] > charmax)
+
+my_strlen(string[])
+    {
+    new len = 0
+    if (ispacked(string))
+        while (string{len} != EOS)      /* get character from pack */
+            ++len
+    else
+        while (string[len] != EOS)      /* get cell */
+            ++len
+    return len
+    }
+
+strupper(string[])
+    {
+    assert ispacked(string)
+
+    for (new i=0; string{i} != EOS; ++i)
+        string{i} = toupper(string{i})
+    }
+
+main()
+    {
+    new s[10]
+
+    for (new i = 0; i < 5; i++)
+        s{i}=i+'a'
+    s{5}=EOS
+
+    printf("String is %s\n", ispacked(s) ? "packed" : "unpacked")
+    printf("String length is %d\n", my_strlen(s))
+    printf("Original:   %s\n", s)
+    strupper(s)
+    printf("Upper case: %s\n", s)
+    }

EXAMPLES/cards.p

@@ -0,0 +1,65 @@
+enum _: CardSuits
+    {
+    Clubs,
+    Diamonds,
+    Hearts,
+    Spades,
+    }
+
+const CardTypes = 13
+const TotalCards = CardSuits * CardTypes
+
+enum CardDescription
+    {
+    CardName[10 char],
+    CardSuit,
+    CardValue,
+    }
+
+new CardNames[CardTypes][] = { !"Ace", !"Two", !"Three", !"Four", !"Five",
+                               !"Six", !"Seven", !"Eight", !"Nine", !"Ten",
+                               !"Jack", !"Queen", !"King" }
+new CardValues[CardTypes]  = { 11, 2, 3, 4, 5, 6, 7, 8, 9, 10, 10, 10, 10 }
+
+main()
+    {
+    new Cards[ TotalCards ][ CardDescription ]
+
+    /* fill in the cards */
+    for (new suit = 0; suit < CardSuits; suit++)
+        {
+        for (new card = 0; card < CardTypes; card++)
+            {
+            new index = suit*CardTypes + card
+            strpack Cards[ index ][CardName], CardNames[ card ]
+            Cards[ index ][ CardSuit ] = suit
+            Cards[ index ][ CardValue ] = CardValues[ card ]
+            }
+        }
+
+    /* shuffle the cards (swap an arbitrary number of randomly selected cards) */
+    for (new iter = 0; iter < 200; iter++)
+        {
+        new first = random(TotalCards)
+        new second = random(TotalCards)
+        new TempCard[ CardDescription ]
+        TempCard = Cards[first]
+        Cards[ first ] = Cards[ second ]
+        Cards[ second ] = TempCard
+        }
+
+    /* print the cards with a subroutine */
+    for (new card = 0; card < TotalCards; card++)
+        PrintCard Cards[ card]
+    }
+
+PrintCard( TheCard[ CardDescription ] )
+    {
+    new SuitNames[ CardSuits ][] = { !"Clubs", !"Diamonds",
+                                     !"Hearts", !"Spades" }
+
+    printf !"%s of %s (valued %d)\n",
+           TheCard[ CardName ],
+           SuitNames[ TheCard[ CardSuit ] ],
+           TheCard[ CardValue ]
+    }

EXAMPLES/chat.p

@@ -0,0 +1,31 @@
+#include <datagram>
+
+@receivestring(const message[], const source[])
+    printf "[%s] says: %s\n", source, message
+
+@keypressed(key)
+    {
+    static string[100 char]
+    static index
+
+    if (key == '\e')
+        exit                    /* quit on 'Esc' key */
+
+    echo key
+    if (key == '\r' || key == '\n' || index char == sizeof string)
+        {
+        string{index} = '\0'    /* terminate string */
+        sendstring string
+        index = 0
+        string[index] = '\0'
+        }
+    else
+        string{index++} = key
+    }
+
+echo(key)
+    {
+    new string[2 char] = { 0 }
+    string{0} = key == '\r' ? '\n' : key
+    printf string
+    }

EXAMPLES/comment.p

@@ -0,0 +1,45 @@
+/* parse C comments interactively, using events and a state machine */
+
+main()
+    state plain
+
+@keypressed(key) <plain>
+    {
+    state (key == '/') slash
+    if (key != '/')
+        echo key
+    }
+
+@keypressed(key) <slash>
+    {
+    state (key != '/') plain
+    state (key == '*') comment
+    echo '/'    /* print '/' held back from previous state */
+    if (key != '/')
+        echo key
+    }
+
+@keypressed(key) <comment>
+    {
+    echo key
+    state (key == '*') star
+    }
+
+@keypressed(key) <star>
+    {
+    echo key
+    state (key != '*') comment
+    state (key == '/') plain
+    }
+
+echo(key) <plain, slash>
+    printchar key, yellow
+
+echo(key) <comment, star>
+    printchar key, green
+
+printchar(ch, colour)
+    {
+    setattr .foreground = colour
+    printf "%c", ch
+    }

EXAMPLES/faculty.p

@@ -0,0 +1,20 @@
+/* Calculation of the faculty of a value */
+
+main()
+    {
+    print "Enter a value: "
+    new v = getvalue()
+    new f = faculty(v)
+    printf "The faculty of %d is %d\n", v, f
+    }
+
+faculty(n)
+    {
+    assert n >= 0
+
+    new result = 1
+    while (n > 0)
+        result *= n--
+
+    return result
+    }

EXAMPLES/fib.p

@@ -0,0 +1,26 @@
+/* Calculation of Fibonacci numbers by iteration */
+
+main()
+    {
+    print "Enter a value: "
+    new v = getvalue()
+    if (v > 0)
+        printf "The value of Fibonacci number %d is %d\n",
+               v, fibonacci(v)
+    else
+        printf "The Fibonacci number %d does not exist\n", v
+    }
+
+fibonacci(n)
+    {
+    assert n > 0
+
+    new a = 0, b = 1
+    for (new i = 2; i < n; i++)
+        {
+        new c = a + b
+        a = b
+        b = c
+        }
+    return a + b
+    }

EXAMPLES/gcd.p

@@ -0,0 +1,17 @@
+/*
+  The greatest common divisor of two values,
+  using Euclides' algorithm .
+*/
+
+main()
+    {
+    print "Input two values\n"
+    new a = getvalue()
+    new b = getvalue()
+    while (a != b)
+        if (a > b)
+            a = a - b
+        else
+            b = b - a
+    printf "The greatest common divisor is %d\n", a
+    }