initial commit

Author: tfc

flake-module.nix

@@ -0,0 +1,11 @@
+sysmodule-flake:
+
+{ self, flake-parts-lib, lib, ... }: {
+  imports = [
+    ./modules/sys-discovery.nix
+  ];
+
+  config._module.args = { inherit sysmodule-flake; };
+
+  _file = __curPos.file;
+}

flake.lock

@@ -0,0 +1,17 @@
+{
+  description = "Importable flake.parts module for system modules";
+
+  inputs = {
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+  };
+
+  outputs = inputs: inputs.flake-parts.lib.mkFlake { inherit inputs; } ({ withSystem, flake-parts-lib, ... }: {
+    systems = [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin" ];
+    perSystem = { config, self', inputs', pkgs, system, ... }: { };
+    flake = {
+      flakeModules.default = flake-parts-lib.importApply ./flake-module.nix { inherit withSystem; };
+      lib = import ./lib.nix inputs.nixpkgs.lib;
+    };
+  });
+}

flake.nix

@@ -0,0 +1,55 @@
+lib:
+
+let
+  discoverNixOSConfigFiles = dir:
+    let
+      inherit (builtins)
+        attrNames
+        filter
+        listToAttrs
+        ;
+      names = attrNames (
+        lib.filterAttrs
+          (_: v: v == "directory")
+          (builtins.readDir dir)
+      );
+      hasConfigurationNix = name:
+        builtins.readDir "${dir}/${name}" ? "configuration.nix";
+      namesWithConfigs = filter hasConfigurationNix names;
+      toAttrItem = name: {
+        inherit name;
+        value = "${dir}/${name}/configuration.nix";
+      };
+    in
+    listToAttrs (map toAttrItem namesWithConfigs);
+
+  toNixOSSystem = specialArgs: configPath:
+    lib.nixosSystem {
+      inherit specialArgs;
+      modules = [ configPath ];
+    };
+in
+
+{
+  inherit
+    discoverNixOSConfigFiles
+    toNixOSSystem
+    ;
+
+  discoverNixOSConfigs = specialArgs: dir:
+    let
+      configs = discoverNixOSConfigFiles dir;
+    in
+    builtins.mapAttrs (_: toNixOSSystem specialArgs) configs;
+
+  modulesFromDir =
+    let
+      getNixFilesInDir = dir: builtins.filter
+        (file: lib.hasSuffix ".nix" file && file != "default.nix")
+        (builtins.attrNames (builtins.readDir dir));
+      genKey = str: lib.replaceStrings [ ".nix" ] [ "" ] str;
+      moduleFrom = dir: str: { "${genKey str}" = "${dir}/${str}"; };
+    in
+    dir:
+    builtins.foldl' (x: y: x // (moduleFrom dir y)) { } (getNixFilesInDir dir);
+}

lib.nix

@@ -0,0 +1,83 @@
+{ config, lib, self, sysmodule-flake, ... }:
+
+let
+  localLib = import ../lib.nix lib;
+  cfg = config.sysmodules-flake;
+
+  modulesDirs = {
+    darwinModules = "modules-darwin";
+    homeManagerModules = "modules-home-manager";
+    nixosModules = "modules-nixos";
+  };
+
+  configsDirs = {
+    darwinConfigurations = {
+      folder = "configs-darwin";
+      function = specialArgs: configPath: cfg.nix-darwin.lib.darwinSystem {
+        inherit specialArgs;
+        modules = [ configPath ];
+      };
+    };
+    nixosConfigurations = {
+      folder = "configs-nixos";
+      function = specialArgs: configPath: lib.nixosSystem {
+        inherit specialArgs;
+        modules = [ configPath ];
+      };
+    };
+  };
+
+  fileInPathExists = path: file:
+    let
+      paths = builtins.attrNames (builtins.readDir path);
+    in
+    builtins.elem file paths;
+
+  commonAttrs = pathAttrs: pathFunction:
+    let
+      existingPaths = lib.filterAttrs
+        (_: fileInPathExists cfg.modulesPath)
+        pathAttrs;
+      f = _: value: pathFunction "${cfg.modulesPath}/${value}";
+    in
+    builtins.mapAttrs f existingPaths;
+
+  modulesAttrs = commonAttrs modulesDirs localLib.modulesFromDir;
+
+  configAttrs =
+    let
+      specialArgs = cfg.specialArgs // { inherit (cfg) flakeInputs; };
+      existingPaths = lib.filterAttrs
+        (_: { folder, ... }: fileInPathExists cfg.modulesPath folder)
+        configsDirs;
+      toConfigs = _: { folder, function }:
+        let
+          configs = localLib.discoverNixOSConfigFiles "${cfg.modulesPath}/${folder}";
+        in
+        builtins.mapAttrs (_: function specialArgs) configs;
+    in
+      builtins.mapAttrs toConfigs existingPaths;
+
+in
+{
+  options.sysmodules-flake = {
+    modulesPath = lib.mkOption {
+      type = lib.types.path;
+      description = "Path with module folders configs.";
+      default = builtins.toPath self;
+    };
+    flakeInputs = lib.mkOption {
+      type = lib.types.attrs;
+      default = self.inputs;
+    };
+    specialArgs = lib.mkOption {
+      type = lib.types.attrs;
+      default = { };
+    };
+    nix-darwin = lib.mkOption {
+      type = lib.types.nullOr lib.types.attrs;
+      default = null;
+    };
+  };
+  config.flake = configAttrs // modulesAttrs;
+}