CurieBLE: typed characteristic values not initialized to 0

[sandeepmistry]

In v1.0.7 the following sketch would result in a characteristic with value 0, however in master the characteristic has an empty value (value of length 0).

#include <CurieBLE.h>

BLEPeripheral blePeripheral;  // BLE Peripheral Device (the board you're programming)
BLEService ledService("19B10000-E8F2-537E-4F6C-D104768A1214"); // BLE LED Service

BLEUnsignedCharCharacteristic switchCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);


void setup() {
  Serial.begin(9600);

  blePeripheral.addAttribute(ledService);
  blePeripheral.addAttribute(switchCharacteristic);

  blePeripheral.begin();
}

void loop() {
  // listen for BLE peripherals to connect:
  BLECentral central = blePeripheral.central();

  // if a central is connected to peripheral:
  if (central) {
    Serial.print("Connected to central: ");
    // print the central's MAC address:
    Serial.println(central.address());

    // while the central is still connected to peripheral:
    while (central.connected()) {
      // ...
    }

    // when the central disconnects, print it out:
    Serial.print(F("Disconnected from central: "));
    Serial.println(central.address());
  }
}

[SidLeung]

This issue is logged as Jira 804.

The issue suggests memory allocation error.

[sgbihu]

This implementation is same as 1.0.7. I think it is because the value not be initialized. So the length is 0. I don't think this is a bug.

[sandeepmistry]

I think the value is not set in the Nordic GATT table if it is setValue is called prior to adding the characteristic/service to BLE.

[sgbihu]

So what result you want to see? From you test code, I don't see where you output the data.

BTW, the characteristic has two API, one is valueSize, another is valueLength. So if you don't set a value, the valueLength always 0.

[sandeepmistry]

I expect a value of 0x00, if you look in BLETypedCharacteristic.h:

template<typename T> BLETypedCharacteristic<T>::BLETypedCharacteristic(const char* uuid, unsigned char properties) :
  BLECharacteristic(uuid, properties, sizeof(T))
{
    T value;
    memset(&value, 0x00, sizeof(value));

    setValue(value);
}

A memset + setValue is called in the constructor.

[sgbihu]

All typed characteristic are called this constructor. That's why I don't think the code has bug.

[sandeepmistry]

There's definitely an issue with setting characteristic values before adding them.

#include <CurieBLE.h>

BLEPeripheral blePeripheral;

// create service
BLEService testervice = BLEService("FF10");

BLECharacteristic testCharacteristic = BLECharacteristic("FF11", BLERead, "hello");
void setup() {
  Serial.begin(9600);

  // set advertised local name and service UUID
  blePeripheral.setLocalName("test");
  blePeripheral.setDeviceName("test");
  blePeripheral.setAdvertisedServiceUuid(testervice.uuid());

  // add service and characteristics
  blePeripheral.addAttribute(testervice);
  blePeripheral.addAttribute(testCharacteristic);

  blePeripheral.begin();

  Serial.println(F("Bluetooth test"));
}

void loop() {
  blePeripheral.poll();
}

This sketch can also be used to reproduce, I expected the test characteristic to have a value of "hello" but it's empty when I read the value.

[sgbihu]

I have duplicated this bug. And have solution now.

[kitsunami]

Addressed by #433 .