Provide a unit test for targets_compatible_with feature

Author: plobsing

MODULE.bazel

@@ -328,6 +328,9 @@ dev_maven.install(
         "https://repo1.maven.org/maven2",
         "https://maven.google.com",
     ],
+    targets_compatible_with = [
+        "@platforms//os:android",
+    ],
 )
 dev_maven.install(
     name = "m2local_testing",

WORKSPACE

@@ -534,6 +534,9 @@ maven_install(
     repositories = [
         "https://repo1.maven.org/maven2",
     ],
+    targets_compatible_with = [
+        "@platforms//os:android",
+    ],
 )
 
 maven_install(

tests/unit/jvm_import/BUILD

@@ -15,6 +15,7 @@
 load("@bazel_skylib//rules:build_test.bzl", "build_test")
 load("@rules_java//java:defs.bzl", "java_import")
 load(":jvm_import_test.bzl", "jvm_import_test_suite")
+load(":platform_transition_jar.bzl", "platform_transition_jar")
 
 java_import(
     name = "java_import_that_consumes_the_downloaded_file_directly",
@@ -29,4 +30,41 @@ build_test(
     ],
 )
 
+platform(
+    name = "android",
+    constraint_values = ["@platforms//os:android"],
+)
+
+platform(
+    name = "linux",
+    constraint_values = ["@platforms//os:linux"],
+)
+
+# Platform constraint is valid on Android but invalid on Linux:
+#
+#     maven_install(
+#        name = "jvm_import_test",
+#        # ...
+#        targets_compatible_with = ["@platforms//os:android"],
+#        # ...
+#     )
+platform_transition_jar(
+    name = "findbugs_for_android",
+    src = "@jvm_import_test//:com_google_code_findbugs_jsr305_3_0_2",
+    platform = ":android",
+)
+
+platform_transition_jar(
+    name = "findbugs_for_linux",
+    src = "@jvm_import_test//:com_google_code_findbugs_jsr305_3_0_2",
+    platform = ":linux",
+)
+
+build_test(
+    name = "test_does_jar_artifact_work_with_matching_platform_constraint",
+    targets = [
+        ":findbugs_for_android",
+    ],
+)
+
 jvm_import_test_suite(name = "jvm_import_tests")

tests/unit/jvm_import/jvm_import_test.bzl

@@ -88,6 +88,16 @@ does_jvm_import_export_a_package_provider_test = analysistest.make(
     },
 )
 
+def _does_jvm_import_enforce_platform_constraints_impl(ctx):
+    env = analysistest.begin(ctx)
+    asserts.expect_failure(env, expected_failure_msg = "didn't satisfy constraint")
+    return analysistest.end(env)
+
+does_jvm_import_enforce_platform_constraints_test = analysistest.make(
+    _does_jvm_import_enforce_platform_constraints_impl,
+    expect_failure = True,
+)
+
 def _does_non_jvm_import_target_carry_metadata(ctx):
     env = analysistest.begin(ctx)
 
@@ -121,6 +131,10 @@ def jvm_import_test_suite(name):
         target_under_test = "@jvm_import_test//:com_google_code_findbugs_jsr305",
         src = "@jvm_import_test//:com_google_code_findbugs_jsr305",
     )
+    does_jvm_import_enforce_platform_constraints_test(
+        name = "does_jvm_import_enforce_platform_constraints_test",
+        target_under_test = ":findbugs_for_linux",
+    )
 
     # TODO: restore once https://github.com/bazelbuild/rules_license/issues/154 is resolved
     #    does_non_jvm_import_target_carry_metadata_test(

tests/unit/jvm_import/platform_transition_jar.bzl

@@ -0,0 +1,28 @@
+def _xsitn_impl(settings, attr):
+    return {"//command_line_option:platforms": str(attr.platform)}
+
+_transition = transition(
+    implementation = _xsitn_impl,
+    inputs = [],
+    outputs = ["//command_line_option:platforms"],
+)
+
+def _rule_impl(ctx):
+    return [
+        DefaultInfo(files = depset(transitive = [ctx.attr.src[0][DefaultInfo].files])),
+    ]
+
+platform_transition_jar = rule(
+    implementation = _rule_impl,
+    attrs = {
+        "src": attr.label(
+            cfg = _transition,
+        ),
+        "platform": attr.label(),
+    },
+    doc = """
+        Depend on a JAR for a specified platform.
+        This isn't typical usage - for the most part, Java builds should use a consistent config.
+        Using a transition enables modelling multi-platform builds within the build system for the purposes of testing.
+    """,
+)