wooper.dev/flake.nix at main · buurro/wooper.dev · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";

    pyproject-nix = {
      url = "github:pyproject-nix/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    uv2nix = {
      url = "github:pyproject-nix/uv2nix";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.uv2nix.follows = "uv2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    uv2nix,
    pyproject-nix,
    pyproject-build-systems,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      inherit (nixpkgs) lib;

      pkgs = nixpkgs.legacyPackages.${system};

      workspace = uv2nix.lib.workspace.loadWorkspace {workspaceRoot = ./.;};

      overlay = workspace.mkPyprojectOverlay {
        sourcePreference = "wheel";
      };

      baseSet = pkgs.callPackage pyproject-nix.build.packages {
        python = pkgs.python314;
      };

      pythonSet = baseSet.overrideScope (
        lib.composeManyExtensions [
          pyproject-build-systems.overlays.default
          overlay
        ]
      );

      venv = pythonSet.mkVirtualEnv "wooper-dev-env" workspace.deps.default;
    in {
      packages =
        {
          default = pkgs.writeShellApplication {
            name = "wooper-dev";

            runtimeInputs = [venv];

            text = ''
              uvicorn wooper_dev.main:app --host=0.0.0.0
            '';
          };
        }
        // lib.optionalAttrs pkgs.stdenv.isLinux {
          containerImage = pkgs.dockerTools.streamLayeredImage {
            name = "ghcr.io/buurro/wooper.dev";
            tag = pythonSet.wooper-dev.version;
            contents = [
              venv
              pkgs.busybox
              pkgs.nix
              pkgs.dockerTools.caCertificates
            ];
            config = {
              Cmd = ["uvicorn" "wooper_dev.main:app" "--host=0.0.0.0"];
              ExposedPorts = {
                "8000/tcp" = {};
              };
            };
          };
        };
      devShells.default = pkgs.mkShell {
        name = "wooper";
        packages = [
          pkgs.uv
          pkgs.postgresql_17
        ];
      };
    });
}