espanso/flake.nix at dev · classicalBit/espanso · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
{
  description = "A cross-platform Text Expander written in Rust";

  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

  outputs =
    {
      self,
      nixpkgs,
      ...
    }:
    let
      supportedSystems = [
        "x86_64-linux"
        "x86_64-darwin"
        "aarch64-linux"
        "aarch64-darwin"
      ];
      eachSystem =
        with nixpkgs.lib;
        f: foldAttrs mergeAttrs { } (map (s: mapAttrs (_: v: { ${s} = v; }) (f s)) supportedSystems);
    in
    eachSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
      in
      {
        checks.espanso = self.packages.${system}.espanso.override { buildType = "debug"; };
        formatter = pkgs.nixfmt-rfc-style;
        packages = {
          espanso = pkgs.callPackage ./nix/espanso.nix { };
          default = self.packages.${system}.espanso;
        }
        // (nixpkgs.lib.optionalAttrs pkgs.stdenv.isLinux {
          espanso-wayland = (
            pkgs.callPackage ./nix/espanso.nix {
              waylandSupport = true;
            }
          );
        });
        devShells =
          let
            commonRustFlagsEnv = "-C target-cpu=native";
          in
          {
            default = pkgs.mkShell {
              name = "espanso";
              inputsFrom = [ self.checks.${system}.espanso ];
              packages =
                with pkgs;
                [
                  biome
                  clang-tools
                  rustfmt
                ]
                ++ lib.optional (stdenv.isx86_64 && stdenv.isLinux) [ cargo-tarpaulin ];
              shellHook = ''
                export RUST_BACKTRACE="1"
                export RUSTFLAGS="''${RUSTFLAGS:-""} ${commonRustFlagsEnv}";
              '';
            };
          };
      }
    );
}