tests: reworks deps using more modern jvm-test-suite ands new full coverage reports.

Author: anthonydmays

auth-service/auth-service-web/auth-web-lib/build.gradle.kts

@@ -15,64 +15,4 @@ dependencies {
     implementation("org.springframework.security:spring-security-oauth2-authorization-server")
     implementation("org.springframework.security:spring-security-cas")
     implementation("org.springframework:spring-jdbc")
-}
-
-sourceSets {
-    create("integrationTest") {
-        compileClasspath += sourceSets.main.get().output
-        runtimeClasspath += sourceSets.main.get().output
-    }
-}
-
-val integrationTestImplementation by configurations.getting {
-    extendsFrom(configurations.implementation.get())
-}
-val integrationTestRuntimeOnly by configurations.getting
-
-configurations["integrationTestRuntimeOnly"].extendsFrom(configurations.runtimeOnly.get())
-
-val integrationTest = task<Test>("integrationTest") {
-    description = "Runs integration tests."
-    group = "verification"
-
-    testClassesDirs = sourceSets["integrationTest"].output.classesDirs
-    classpath = sourceSets["integrationTest"].runtimeClasspath
-    shouldRunAfter("test")
-
-    useJUnitPlatform()
-
-    testLogging {
-        events("passed")
-    }
-
-    finalizedBy("jacocoIntegrationTestReport")
-}
-
-dependencies {
-    integrationTestImplementation(platform("com.codedifferently.studycrm.platform:java-test-platform"))
-    integrationTestImplementation("org.junit.jupiter:junit-jupiter")
-    integrationTestImplementation("org.mockito:mockito-core")
-    integrationTestImplementation("org.springframework.boot:spring-boot-starter-test")
-    integrationTestImplementation("org.springframework.security:spring-security-test")
-    integrationTestRuntimeOnly("com.h2database:h2")
-    integrationTestRuntimeOnly("org.junit.platform:junit-platform-launcher")
-}
-
-tasks.register<JacocoReport>("jacocoIntegrationTestReport") {
-    executionData(tasks.named("integrationTest").get())
-    sourceSets(sourceSets["integrationTest"])
-
-    reports {
-        xml.required.set(true)
-        html.required.set(true)
-    }
-}
-
-tasks.jacocoTestReport { 
-    dependsOn("jacocoIntegrationTestReport")
-}
-
-tasks.check { 
-    dependsOn(integrationTest)
-    dependsOn("jacocoIntegrationTestReport")
 }

build-logic/java-shared/src/main/kotlin/com.codedifferently.studycrm.java-shared.gradle.kts

@@ -1,5 +1,6 @@
 plugins {
     id("java")
+    id("jvm-test-suite")
     id("jacoco")
     id("eclipse")
     id("io.freefair.lombok")
@@ -39,16 +40,38 @@ configure<com.diffplug.gradle.spotless.SpotlessExtension> {
 
 dependencies {
     implementation(platform("com.codedifferently.studycrm.platform:java-platform"))
+}
+
+testing {
+    suites { 
+        withType<JvmTestSuite> { 
+            useJUnitJupiter()
+            dependencies { 
+                implementation(platform("com.codedifferently.studycrm.platform:java-test-platform"))
+                implementation("org.mockito:mockito-junit-jupiter")
+                runtimeOnly("com.h2database:h2")
+            }
+        }
 
-    testImplementation(platform("com.codedifferently.studycrm.platform:java-test-platform"))
-    testImplementation("org.springframework.boot:spring-boot-starter-test")
-    testImplementation("org.mockito:mockito-core")
-    testImplementation("org.junit.jupiter:junit-jupiter")
-    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
-    testRuntimeOnly("com.h2database:h2")
+        register<JvmTestSuite>("integrationTest") {
+            testType = TestSuiteType.INTEGRATION_TEST
+            
+            dependencies {
+                implementation(project())
+                runtimeOnly(project())
+            }
+
+            targets { 
+                all {
+                    testTask.configure {
+                        shouldRunAfter(testing.suites.named("test"))
+                    }
+                }
+            }
+        }
+    }
 }
 
-tasks.test {
-    useJUnitPlatform()
-    finalizedBy(tasks.jacocoTestReport)
+tasks.named("check") { 
+    dependsOn(testing.suites.named("integrationTest"))
 }

build-logic/spring-library/src/main/kotlin/com.codedifferently.studycrm.spring-library.gradle.kts

@@ -11,7 +11,15 @@ dependencies {
     implementation("org.springframework.boot:spring-boot-starter-security")
     implementation("org.springframework.boot:spring-boot-starter-validation")
 	implementation("org.springframework.security:spring-security-acl")
+}
 
-    testImplementation("org.springframework.boot:spring-boot-starter-test")
-    testImplementation("org.springframework.security:spring-security-test")
+testing {
+    suites { 
+        withType<JvmTestSuite> {
+            dependencies { 
+                implementation("org.springframework.boot:spring-boot-starter-test")
+                implementation("org.springframework.security:spring-security-test")
+            }
+        }
+    }
 }

build-logic/spring-web-library/src/main/kotlin/com.codedifferently.studycrm.spring-web-library.gradle.kts

@@ -9,5 +9,15 @@ dependencies {
     implementation("org.springframework.boot:spring-boot-starter-actuator")
     implementation("org.springframework.boot:spring-boot-starter-validation")
 	runtimeOnly("org.springframework:spring-context-support")
-    testImplementation("org.springframework.security:spring-security-test")
+}
+
+testing {
+    suites { 
+        withType<JvmTestSuite> {
+            dependencies { 
+                implementation("org.springframework.boot:spring-boot-starter-test")
+                implementation("org.springframework.security:spring-security-test")
+            }
+        }
+    }
 }

build.gradle.kts

@@ -3,19 +3,20 @@ import com.avast.gradle.dockercompose.ComposeExtension
 plugins {
     `kotlin-dsl`
     id("com.codedifferently.studycrm.java-shared")
-    id("jacoco-report-aggregation")
     id("com.avast.gradle.docker-compose") version "0.17.6"
+    id("jacoco-report-aggregation")
+    id("test-report-aggregation")
 }
 
 repositories {
     mavenCentral()
 }
 
 dependencies {
-    // Load bearing deps needed to aggregate jacoco reports.
-    implementation("com.codedifferently.studycrm.auth-service.main:auth-main-app")
-    implementation("com.codedifferently.studycrm.contact-service.main:contact-main-app")
-    implementation("com.codedifferently.studycrm.organization-service.main:organization-main-app")
+    // Load bearing deps needed to aggregate coverage reports.
+    jacocoAggregation("com.codedifferently.studycrm.auth-service.main:auth-main-app")
+    jacocoAggregation("com.codedifferently.studycrm.contact-service.main:contact-main-app")
+    jacocoAggregation("com.codedifferently.studycrm.organization-service.main:organization-main-app")
 }
 
 val eventuateCommonImageVersion: String by project
@@ -82,11 +83,30 @@ tasks.test {
     }
 }
 
-// Ensure that we generate the jacoco report for the repo.
-tasks.check {
-    dependsOn(tasks.named<JacocoReport>("testCodeCoverageReport")) 
+reporting {
+    reports {        
+        val testFullCodeCoverageReport by creating(JacocoCoverageReport::class) {
+            testType = TestSuiteType.PERFORMANCE_TEST
+        }
+    }
+}
+
+tasks.named<JacocoReport>("testFullCodeCoverageReport") {
+    description = "Build a full test coverage report including test and integrationTest results"
+    dependsOn( "testCodeCoverageReport", "integrationTestCodeCoverageReport" )
+    executionData.setFrom(fileTree( project.rootDir.absolutePath ).include( "**/build/jacoco/*.exec" ))
+
+    reports {
+        xml.required = true
+        html.required = true
+    }
 }
 
 tasks.register("coverage") {
-    dependsOn("testCodeCoverageReport")
+    dependsOn(tasks.named("testFullCodeCoverageReport"))
+}
+
+// Ensure that we generate the coverage report for the repo.
+tasks.check {
+    dependsOn(tasks.named("coverage")) 
 }

platforms/java-test-platform/build.gradle.kts

@@ -8,9 +8,12 @@ group = "com.codedifferently.studycrm.platform"
 javaPlatform.allowDependencies()
 
 val mockitoVersion: String by project
+val springBootVersion: String by project
+val junitBomVersion: String by project
 
 dependencies {
-    api(platform("org.junit:junit-bom:5.7.1"))
-
+    api(platform("org.junit:junit-bom:$junitBomVersion"))
+    api(platform("org.springframework.boot:spring-boot-dependencies:$springBootVersion"))
     api(platform("org.mockito:mockito-core:$mockitoVersion"))
+    api(platform("org.mockito:mockito-junit-jupiter:$mockitoVersion"))
 }

platforms/java-test-platform/gradle.properties

@@ -1 +1,3 @@
-mockitoVersion=5.10.0
+junitBomVersion=5.7.1
+mockitoVersion=5.10.0
+springBootVersion=3.2.2