[Dev] Avant-gout

[jbcaillau]

@ocots @PierreMartinon with CTDirect v0.17.1 and midpoint everywhere, mini-benchmark on Goddard (N = 5000, A100 run CPU / GPU):

julia> @btime s = solve(o, :adnlp, :ipopt; print_level=0, grid_size=N);
  21.128 s (38947050 allocations: 13.78 GiB)

julia> @btime s = solve(o, :exa, :ipopt; print_level=0, grid_size=N);
  6.177 s (397083 allocations: 24.86 MiB)

julia> @btime s = solve(o, :adnlp, :madnlp; print_level=MadNLP.WARN, grid_size=N);
  16.669 s (23938965 allocations: 13.16 GiB)

julia> @btime s = solve(o, :exa, :madnlp; print_level=MadNLP.WARN, grid_size=N);
  905.175 ms (405572 allocations: 110.68 MiB)

julia> CUDA.@time s = solve(o, :exa, :madnlp; print_level=MadNLP.WARN, grid_size=N, exa_backend=CUDABackend());
  0.654175 seconds (838.60 k CPU allocations: 42.568 MiB) (3.38 k GPU allocations: 179.577 MiB, 1.60% memmgmt time)

[jbcaillau]

FTR

using OptimalControl
using NLPModelsIpopt
using MadNLPMumps
using MadNLPGPU
using CUDA
using BenchmarkTools

function goddard()

    r0 = 1.0     
    v0 = 0.0
    m0 = 1.0 
    vmax = 0.1 
    mf = 0.6   
    Cd = 310.0
    Tmax = 3.5
    β = 500.0
    b = 2.0

    o = @def begin

        tf ∈ R, variable
        t ∈ [0, tf], time
        x = (r, v, m) ∈ R³, state
        u ∈ R, control
    
        x(0) == [r0, v0, m0]
        m(tf) == mf
        0 ≤ u(t) ≤ 1
        r(t) ≥ r0
        0 ≤ v(t) ≤ vmax
    
        ∂(r)(t) == v(t)
        ∂(v)(t) == -Cd * v(t)^2 * exp(-β * (r(t) - 1)) / m(t) - 1 / r(t)^2 + u(t) * Tmax / m(t)
        ∂(m)(t) == -b * Tmax * u(t)
    
        r(tf) → max
    
    end

    return o

end

o = goddard()
N = 5000
@btime solve(o, :adnlp, :ipopt; print_level=0, grid_size=N);
@btime solve(o, :exa, :ipopt; print_level=0, grid_size=N);
@btime solve(o, :adnlp, :madnlp; print_level=MadNLP.WARN, grid_size=N);
@btime solve(o, :exa, :madnlp; print_level=MadNLP.WARN, grid_size=N);
solve(o, :exa, :madnlp; print_level=MadNLP.WARN, grid_size=N, exa_backend=CUDABackend());
CUDA.@time solve(o, :exa, :madnlp; print_level=MadNLP.WARN, grid_size=N, exa_backend=CUDABackend());