nullsound: note cut FX

Plus note delay FX for ADPCM-B which was missing from previous commits

Author: dciabrin

nullsound/fx-trigger.s

@@ -50,6 +50,28 @@ trigger_delay_init::
         ret
 
 
+;;; Enable delayed cut for the note currently playing
+;;; (note is stopped after a defined number of steps)
+;;; ------
+;;;   ix  : state for channel
+;;; [ hl ]: delay
+;;; [ hl modified ]
+trigger_cut_init::
+        ;; a: delay
+        ld      a, (hl)
+        inc     a
+        inc     hl
+
+        ;; configure trigger FX for delay
+        ld      TRIGGER_CUT(ix), a
+        xor     a
+        set     BIT_TRIGGER_ACTION_CUT, a
+        ld      TRIGGER_ACTION(ix), a
+        set     BIT_FX_TRIGGER, FX(ix)
+
+        ret
+
+
 ;;; Call an function from the action lookup table
 ;;; ------
 ;;; hl: function lookup table
@@ -89,6 +111,15 @@ eval_trigger_step::
         jr      nz, _trigger_end
         jr      _trigger_load_and_clear
 _trigger_post_delay:
+
+        ;; is the trigger a cut?
+        bit     BIT_TRIGGER_ACTION_CUT, TRIGGER_ACTION(ix)
+        jr      z, _trigger_post_cut
+        ;; check whether delay is reached
+        dec     TRIGGER_CUT(ix)
+        jr      nz, _trigger_end
+        jr      _trigger_cut_note
+_trigger_post_cut:
 _trigger_end:
         ret
 
@@ -115,3 +146,13 @@ _trigger_post_load_vol:
         res     BIT_FX_TRIGGER, FX(ix)
 
         ret
+
+_trigger_cut_note:
+        ld      bc, #TRIGGER_STOP_NOTE_FUNC
+        call    trigger_action_function
+        xor     a
+        ld      TRIGGER_ACTION(ix), a
+        res     BIT_FX_TRIGGER, FX(ix)
+
+        ret
+

nullsound/nss-adpcm-a.s

@@ -103,6 +103,7 @@ _state_adpcm_end:
 state_a_action_funcs::
         .dw     adpcm_a_configure_on
         .dw     adpcm_a_configure_vol
+        .dw     adpcm_a_stop_playback
 
 
 ;;;  Reset ADPCM playback state.
@@ -456,10 +457,9 @@ _a_on_end:
         ret
 
 
-;;; ADPCM_A_OFF
-;;; Stop the playback on a ADPCM-A channel
+;;; Release the note on a ADPCM-A channel and update the pipeline state
 ;;; ------
-adpcm_a_off::
+adpcm_a_stop_playback:
         push    bc
         push    de
 
@@ -485,6 +485,15 @@ _off_bit:
         pop     de
         pop     bc
 
+        ret
+
+
+;;; ADPCM_A_OFF
+;;; Stop the playback on a ADPCM-A channel
+;;; ------
+adpcm_a_off::
+        call    adpcm_a_stop_playback
+
         ;; ADPCM-A context will now target the next channel
         ld      a, (state_adpcm_a_channel)
         inc     a
@@ -585,3 +594,14 @@ adpcm_a_delay::
 
         ld      a, #1
         ret
+
+
+;;; ADPCM_A_CUT
+;;; Record that the note being played must be stopped after some steps
+;;; ------
+;;; [ hl ]: delay
+adpcm_a_cut::
+        call    trigger_cut_init
+
+        ld      a, #1
+        ret

nullsound/nss-adpcm-b.s

@@ -101,6 +101,7 @@ _state_adpcm_b_end:
 state_b_action_funcs::
         .dw     adpcm_b_configure_note_on
         .dw     adpcm_b_configure_vol
+        .dw     adpcm_b_note_off
 
 
 ;;;  Reset ADPCM playback state.
@@ -755,3 +756,26 @@ adpcm_b_portamento::
 
         ld      a, #1
         ret
+
+
+;;; ADPCM_B_DELAY
+;;; Enable delayed trigger for the next note and volume
+;;; (note and volume and played after a number of ticks)
+;;; ------
+;;; [ hl ]: delay
+adpcm_b_delay::
+        call    trigger_delay_init
+
+        ld      a, #1
+        ret
+
+
+;;; ADPCM_B_CUT
+;;; Record that the note being played must be stopped after some steps
+;;; ------
+;;; [ hl ]: delay
+adpcm_b_cut::
+        call    trigger_cut_init
+
+        ld      a, #1
+        ret

nullsound/nss-fm.s

@@ -157,6 +157,7 @@ _state_fm_end:
 state_fm_action_funcs:
         .dw     fm_configure_note_on
         .dw     fm_configure_vol
+        .dw     fm_stop_playback
 
 
 ;;;  Reset FM playback state.
@@ -1086,13 +1087,11 @@ _fm_note_on_end:
         ret
 
 
-;;; FM_NOTE_OFF
-;;; Release the note on an FM channel. The sound will decay according
-;;; to the current configuration of the FM channel's operators.
+;;; Release the note on an FM channel and update the pipeline state
 ;;; ------
-fm_note_off::
-        push    bc
+fm_stop_playback:
         ;; stop all OPs of FM channel
+        push    bc
         ld      a, (state_fm_ym2610_channel)
         ld      c, a
         ld      b, #REG_FM_KEY_ON_OFF_OPS
@@ -1103,15 +1102,25 @@ fm_note_off::
         ;; will get cleaned during the next pipeline run
         res     BIT_PLAYING, PIPELINE(ix)
 
+        ;; record that playback is stopped
+        xor     a
+        res     BIT_NOTE_STARTED, PIPELINE(ix)
+
+        ret
+
+
+;;; FM_NOTE_OFF
+;;; Release the note on an FM channel. The sound will decay according
+;;; to the current configuration of the FM channel's operators.
+;;; ------
+fm_note_off::
+        call    fm_stop_playback
+
         ;; FM context will now target the next channel
         ld      a, (state_fm_channel)
         inc     a
         call    fm_ctx_set_current
 
-        ;; record that playback is stopped
-        xor     a
-        res     BIT_NOTE_STARTED, PIPELINE(ix)
-
         ld      a, #1
         ret
 
@@ -1339,3 +1348,14 @@ fm_delay::
 
         ld      a, #1
         ret
+
+
+;;; FM_CUT
+;;; Record that the note being played must be stopped after some steps
+;;; ------
+;;; [ hl ]: delay
+fm_cut::
+        call    trigger_cut_init
+
+        ld      a, #1
+        ret

nullsound/nss-ssg.s

@@ -134,6 +134,7 @@ _state_ssg_end:
 state_ssg_action_funcs:
         .dw     ssg_configure_note_on
         .dw     ssg_configure_vol
+        .dw     ssg_stop_playback
 
 
 ;;;  Reset SSG playback state.
@@ -713,10 +714,9 @@ _end_ssg_slide_step:
         ret
 
 
-;;; SSG_NOTE_OFF
-;;; Release (stop) the note on the current SSG channel.
+;;; Release the note on a SSG channel and update the pipeline state
 ;;; ------
-ssg_note_off::
+ssg_stop_playback:
         push    bc
 
         ;; c: disable mask (shifted for channel)
@@ -747,15 +747,24 @@ ssg_note_off::
         ;; will get cleaned during the next pipeline run
         res     BIT_PLAYING, PIPELINE(ix)
 
+        ;; record that playback is stopped
+        xor     a
+        res     BIT_NOTE_STARTED, PIPELINE(ix)
+
+        ret
+
+
+;;; SSG_NOTE_OFF
+;;; Release (stop) the note on the current SSG channel.
+;;; ------
+ssg_note_off::
+        call    ssg_stop_playback
+
         ;; SSG context will now target the next channel
         ld      a, (state_ssg_channel)
         inc     a
         call    fm_ctx_set_current
 
-        ;; record that playback is stopped
-        xor     a
-        res     BIT_NOTE_STARTED, PIPELINE(ix)
-
         ld      a, #1
         ret
 
@@ -1044,3 +1053,14 @@ ssg_pitch::
         pop     bc
         ld      a, #1
         ret
+
+
+;;; SSG_CUT
+;;; Record that the note being played must be stopped after some steps
+;;; ------
+;;; [ hl ]: delay
+ssg_cut::
+        call    trigger_cut_init
+
+        ld      a, #1
+        ret

nullsound/stream.s

@@ -520,6 +520,11 @@ nss_opcodes:
         .nss_op adpcm_b_portamento
         .nss_op ssg_pitch_slide_down
         .nss_op ssg_portamento
+        .nss_op fm_cut
+        .nss_op ssg_cut
+        .nss_op adpcm_a_cut
+        .nss_op adpcm_b_cut
+        .nss_op adpcm_b_delay
 
 
 

nullsound/struct-fx.inc

@@ -105,7 +105,9 @@ _vibrato_size:
 
         .lclequ TRIGGER_LOAD_NOTE_FUNC,         0
         .lclequ TRIGGER_LOAD_VOL_FUNC,          2
+        .lclequ TRIGGER_STOP_NOTE_FUNC,         4
 
         .lclequ BIT_TRIGGER_ACTION_DELAY,       0
+        .lclequ BIT_TRIGGER_ACTION_CUT,         1
         .lclequ BIT_TRIGGER_LOAD_NOTE,          4
         .lclequ BIT_TRIGGER_LOAD_VOL,           5