A way to easy show diff between init.example.el and .doom.d/init.el

[liujoey]

Hi,

Today I've merged upstream and the make command removed the neotree package for me. I was very confused why would that happen. After an hour debugging and manually bisect the git log, I found out that you've moved the neotree package from :tools to :ui, and of cause you updated the init.example.el file accordingly.

The thing is, my ~/.doom.d/init.el still has neotree under :tools section, such that the package management script will not be able to discover the new change thus removed it.

The problem was solved for me, but it raise a question, would it be nice to have a default short-cut key to open a Ediff session on those two init files? This at least encourage people to check the difference between the two more often.

In Spacemacs there is a key mapping SPC f e d for this exact purpose, I would highly recommend to implement a similar function for this. Thank you.

[hlissner]

Sorry for the trouble! I realize these updates must seem sudden and unannounced (at least, to anyone not on our discord server).

I am working on a solution to this (several, in fact, including an "update diff" tool as spacemacs has and a news system ala M-x view-emacs-news to communicate upcoming and past changes). In the meantime, I suggest using git to do this:

git fetch

# then any of these four:
git log HEAD..origin      # lists all the new commit logs
git log -p HEAD..origin   # shows a diff of each commit
git diff HEAD..origin     # a diff of the whole update
git diff HEAD..origin init.example.el   # a diff of module name changes/new modules

# None of these change Doom's files. The update won't take effect until you `git pull`

[obsoke]

I copied this exact feature from Spacemacs as I also wanted to diff my init.el against the example.

;; taken from spacemacs & adjusted for my own needs
(defun obsoke/ediff-dotfile-and-template ()
  "ediff the current `dotfile' with the template"
  (interactive)
  (ediff-files
   "~/.doom.d/init.el"
   "~/.emacs.d/init.example.el"))

Then I just bound it to SPC d

(map!
 (:leader
   :desc "Diff dotfiles"          :nv "d" #'obsoke/ediff-dotfile-and-template))

[hlissner]

For posterity, this is the command I've been toying with for the time being. It's a little smarter than simply ediffing your init.el and init.example.el:

(defun doom--get-modules (file)
  (unless (file-exists-p file)
    (user-error "%s does not exist" file))
  (with-temp-buffer
    (insert-file-contents file)
    (when (re-search-forward "(doom! " nil t)
      (goto-char (match-beginning 0))
      (cdr (sexp-at-point)))))

(defun doom--put-modules (tmpfile modules)
  (with-temp-file tmpfile
    (delay-mode-hooks (emacs-lisp-mode))
    (insert (replace-regexp-in-string " " "\n" (prin1-to-string modules)))
    (indent-region (point-min) (point-max))))

;;;###autoload
(defun doom/what-has-changed ()
  "Open an ediff session to compare the module list in
~/.emacs.d/init.example.el and ~/.doom.d/init.el."
  (interactive)
  (let ((old-modules (doom--get-modules (expand-file-name "init.example.el" doom-emacs-dir)))
        (new-modules (doom--get-modules (expand-file-name "init.el" doom-private-dir)))
        (example-init-el "/tmp/doom-init.example.el")
        (private-init-el "/tmp/doom-private-init.el"))
    (doom--put-modules example-init-el old-modules)
    (doom--put-modules private-init-el new-modules)
    (ediff private-init-el example-init-el)))

[jerbaroo]

ediffing your init.el and init.example.el

This is a simple solution and works very well in spacemacs.

Could this issue be closed by supplying this command under a key binding? The relative usefulness compared to the simplicity of the solution seems to me quite high.

[jerbaroo]

But perhaps there are other intricacies that need to be considered?

[magnetophon]

For ediffing the init file, there is now (doom/ediff-init-and-example), bound under SPC h d i.

[AliGhahraei]

@magnetophon I'm running the latest version (commit 847bbf3), but I don't have doom/ediff-init-and-example and nothing seems to be bound under that key chord. I also used GitHub to search for that function in the source and it couldn't find it.

[magnetophon]

@AliGhahraei Oops, turns out it's in my config:

(defun doom/ediff-init-and-example ()
  "ediff the current `init.el' with the example in doom-emacs-dir"
  (interactive)
  (ediff-files (concat doom-private-dir "init.el")
               (concat doom-emacs-dir "init.example.el")))

(define-key! help-map
  "di"   #'doom/ediff-init-and-example
  )

I think Henrik wrote that code for me in the discord.

[dlukes]

This would be really useful to have in core Doom :) And probably prompt the user to perform the check on upgrade.

In the meantime, I tweaked the diff function to allow selecting any of the files inside DOOMDIR:

(defun dlukes/ediff-doom-config (file)
  "ediff the current config with the examples in doom-emacs-dir

There are multiple config files, so FILE specifies which one to
diff.
"
  (interactive
    (list (read-file-name "Config file to diff: " doom-private-dir)))
  (let* ((stem (file-name-base file))
          (customized-file (format "%s.el" stem))
          (template-file-regex (format "^%s.example.el$" stem)))
    (ediff-files
      (concat doom-private-dir customized-file)
      (car (directory-files-recursively
             doom-emacs-dir
             template-file-regex
             nil
             (lambda (d) (not (string-prefix-p "." (file-name-nondirectory d)))))))))

init.el is probably the one that changes the most, but it might come in handy to quickly diff the other ones as well.