vm.parseJson throwing error after git clone

[tinypell3ts]

We have a contracts project I've been using without any issues for months. I just cloned a version of the project from Github. Now, I'm getting an error from vm.parseJson in our Utils.sol script. This Utils script is responsible for creating a json file which includes the address of all of our contracts and the block they were deploy in.

Utils.sol

pragma solidity ^0.8.16;

import "forge-std/Script.sol";
import "forge-std/console.sol";

contract Utils is Script {
    error Utils_contractAddressNotFound(string contractName);

    string constant namesKey = "doNotRemoveUsedToParseFile";

    string[] contractNames;
    string tempContractJson;

    function getContractDeploymentAddress(string memory contractName) internal returns (address) {
        string memory deploymentFile = _readDeploymentFile();
        bytes memory contractAddress = vm.parseJson(deploymentFile, string.concat(".", contractName, ".address"));
        if (contractAddress.length == 0) {
            revert Utils_contractAddressNotFound(contractName);
        }
        return abi.decode(contractAddress, (address));
    }

    function exportContractDeployment(string memory _contractName, address _contractAddress, uint256 _startBlock)
        internal
    {
        string memory path = _getDeployedFilePath();

        // serialize json
        string memory contractJson;
        contractJson = vm.serializeAddress(_contractName, "address", _contractAddress);
        contractJson = vm.serializeUint(_contractName, "startBlock", _startBlock);

        string memory deploymentFile = _readDeploymentFile();
        bool fileExists = bytes(deploymentFile).length > 0;
        bool isInJsonFile = fileExists ? (vm.parseJson(deploymentFile, _contractName)).length > 0 : false;

        if (isInJsonFile) {
            // just update existing deployment address
            vm.writeJson(contractJson, path, string.concat(".", _contractName));
            return;
        }

        // wrap the address and startBlock with contract name
        contractJson = vm.serializeString("json", _contractName, contractJson);

        if (fileExists) {
            // get all contract names from that file
            contractNames = abi.decode(vm.parseJson(deploymentFile, namesKey), (string[]));
            // parse and reconstruct entire file
            for (uint256 i = 0; i < contractNames.length; i++) {
                (address contractAddress, uint256 startBlock) =
                    abi.decode(vm.parseJson(deploymentFile, contractNames[i]), (address, uint256));
                tempContractJson = "";
                tempContractJson = vm.serializeAddress(contractNames[i], "address", contractAddress);
                tempContractJson = vm.serializeUint(contractNames[i], "startBlock", startBlock);

                contractJson = vm.serializeString("json", contractNames[i], tempContractJson);
            }
        } else {
            // no deployments exist so ensure array is empty
            delete contractNames;
        }

        // add the contractNames array with new contract name
        contractNames.push(_contractName);
        contractJson = vm.serializeString("json", namesKey, contractNames);

        // overwrite json file
        vm.writeJson(contractJson, path);
    }

    function _getDeployedFilePath() internal view returns (string memory) {
        string memory inputDir = string.concat(vm.projectRoot(), "/deployed/");
        string memory file = string.concat(vm.toString(block.chainid), ".json");

        return string.concat(inputDir, file);
    }

    function _readDeploymentFile() internal returns (string memory) {
        try vm.readFile(_getDeployedFilePath()) returns (string memory result) {
            return result;
        } catch {
            return "";
        }
    }
}

The error:

forge script scripts/core/Globals.s.sol:Deploy --rpc-url anvil --broadcast -vvvv --legacy --slow
[⠔] Compiling...
No files changed, compilation skipped
Traces:
  [1510279] → new Deploy@0x5b73C5498c1E3b4dbA84de0F1833c4a029d90519
    └─ ← 7433 bytes of code

  [464352] Deploy::run() 
    ├─ [0] VM::envUint(PRIVATE_KEY) [staticcall]
    │   └─ ← <env var value>
    ├─ [0] VM::startBroadcast(<pk>) 
    │   └─ ← ()
    ├─ [394925] → new Globals@0xe7f1725E7734CE288F8367e1Bb143E90bb3F0512
    │   ├─ emit OwnershipTransferred(previousOwner: 0x0000000000000000000000000000000000000000, newOwner: 0xf39Fd6e51aad88F6F4ce6aB8827279cffFb92266)
    │   └─ ← 1853 bytes of code
    ├─ [0] VM::stopBroadcast() 
    │   └─ ← ()
    ├─ [0] VM::projectRoot() [staticcall]
    │   └─ ← /Users/andy/Projects/Open Format/core/contracts
    ├─ [0] VM::toString(31337) [staticcall]
    │   └─ ← 0x000000000000000000000000000000000000000000000000000000000000002000000000000000000000000000000000000000000000000000000000000000053331333337000000000000000000000000000000000000000000000000000000
    ├─ [0] VM::serializeAddress(Globals, address, Globals: [0xe7f1725E7734CE288F8367e1Bb143E90bb3F0512]) 
    │   └─ ← {"address":"0xe7f1725E7734CE288F8367e1Bb143E90bb3F0512"}
    ├─ [0] VM::serializeUint(Globals, startBlock, 1) 
    │   └─ ← {"address":"0xe7f1725E7734CE288F8367e1Bb143E90bb3F0512","startBlock":1}
    ├─ [0] VM::projectRoot() [staticcall]
    │   └─ ← /Users/andy/Projects/Open Format/core/contracts
    ├─ [0] VM::toString(31337) [staticcall]
    │   └─ ← 0x000000000000000000000000000000000000000000000000000000000000002000000000000000000000000000000000000000000000000000000000000000053331333337000000000000000000000000000000000000000000000000000000
    ├─ [0] VM::readFile(/Users/andy/Projects/Open Format/core/contracts/deployed/31337.json) [staticcall]
    │   └─ ← <file>
    ├─ [0] VM::parseJson(<JSON file>, Globals) [staticcall]
    │   └─ ← "path error: 
$Globals
^^^^^^^^
"
    └─ ← "path error: 
$Globals
^^^^^^^^
"


Error: 
path error: 
$Globals
^^^^^^^^


make[1]: *** [deploy-Globals] Error 1
make: *** [deploy] Error 2

It's important to note, no code has changed. The only thing that has happened is that I've used git clone. Ive tried forge install and forge clean.

Thanks

[mds1]

@mattsse @odyslam between this and #4844, could there have been a regression somewhere?

[tinypell3ts]

Here is my .gitmodules. It hasn't changed since it was working.

[submodule "lib/forge-std"]
	path = lib/forge-std
	url = https://github.com/foundry-rs/forge-std
	branch = v1.3.0
[submodule "lib/solidstate-solidity"]
	path = lib/solidstate-solidity
	url = https://github.com/solidstate-network/solidstate-solidity
	branch = v0.0.52
[submodule "lib/ERC721A-Upgradeable"]
	path = lib/ERC721A-Upgradeable
	url = https://github.com/chiru-labs/ERC721A-Upgradeable
	branch = v4.2.3

Update: Tested with multiple versions of forge and forge-std. Tested it with a colleague. Worked as expected until they ran forge clean.