bnf.txt

program ::= includes_list construct_list EOF

construct ::= structdecl
            | vardecl
            | funcdecl
            | funcdefn

construct_list ::= construct construct_list
                 | ε                   

includes_list ::= include includes_list
                | ε
include ::= Include LitString

structdecl ::= Struct Ident LBrace vardecl vardecl_list RBrace Semi

vardecl_list ::= vardecl vardecl_list    
               | ε

vardecl := type Ident array_sizes Semi

funcdecl ::= type Ident LParen formals RParen Semi
           | type Ident LParen RParen Semi

funcdefn ::= type Ident LParen formals RParen block
           | type Ident LParen RParen block

type ::= primitive_type
       | struct_type

primitive_type ::= (Type BuiltinType) stars
struct_type    ::= Struct Ident stars
sizeof_type    ::= type array_sizes

BuiltinType ::= Int
              | Double
              | Char
              | Void

formals ::= formals Comma formal
          | formal

formal ::= type Ident

stmt ::= expr Semi
       | block
       | While LParen expr RParen stmt
       | For LParen opt_expr Semi opt_expr Semi opt_expr RParen stmt
       | If LParen expr RParen stmt
       | If LParen expr RParen stmt Else stmt
       | Return opt_expr Semi
       | vardecl

block ::= LBrace block_stmts RBrace

block_stmts ::= stmt block_stmts
              | ε

opt_expr ::= expr
           | ε

expr ::= LitInt
       | LitString
       | LitChar
       | LitDouble
       | LitNull
       | Ident
       | (expr)
       | expr op expr
       | Minus expr
       | Not expr
       | arrayaccess
       | fieldaccess
       | indirect
       | deref
       | addressof
       | funccall
       | assign
       | sizeof
       | typecast
       | expr Increment
       | expr Decrement
       
op ::= Less
     | Leq
     | Greater
     | Geq
     | Neq
     | Equal
     | Plus
     | Minus
     | Div
     | Asterisk
     | Mod
     | Or
     | And
     | Caret
     | Ampers
     | Bar

funccall    ::= Ident LParen actuals RParen
              | Ident LParen RParen

arrayaccess ::= expr LBrack expr RBrack
fieldaccess ::= expr Dot Ident
indirect    ::= expr Arrow Ident
deref       ::= Asterisk expr
addressof   ::= Ampers expr
sizeof      ::= Sizeof LParen type RParen
              | Sizeof LParen expr RParen
typecast    ::= LParen type RParen expr
assign      ::= expr Assign expr
       
actuals ::= expr
          | actuals ',' expr

array_sizes ::= array_sizes LBrack LitInt RBrack
              | ε

stars ::= Asterisk stars
        | ε