Repository navigation
Expand file tree
/
Copy pathbuild.gradle
More file actions
146 lines (134 loc) · 5.29 KB
/
Copy pathbuild.gradle
File metadata and controls
146 lines (134 loc) · 5.29 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
plugins {
id 'java'
id "io.freefair.lombok" version "9.2.0"
id "com.github.node-gradle.node" version "7.1.0" apply false
id "run.halo.plugin.devtools" version "0.9.0"
}
group = 'run.halo.comment.widget'
java {
toolchain {
languageVersion = JavaLanguageVersion.of(21)
}
}
tasks.withType(JavaCompile).configureEach {
options.encoding = "UTF-8"
options.release = 21
}
repositories {
mavenCentral()
}
dependencies {
implementation platform('run.halo.tools.platform:plugin:2.26.0')
compileOnly 'run.halo.app:api'
implementation 'org.altcha:altcha:2.0.3'
implementation 'org.json:json:20240303'
implementation 'org.lionsoul:ip2region:3.3.7'
testImplementation 'run.halo.app:api'
testImplementation 'org.springframework.boot:spring-boot-starter-test'
testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}
test {
useJUnitPlatform()
}
sourceSets.main.resources.exclude 'ui/**', 'static/**'
// Pin the source data and official maker together; updates must refresh the checksum.
def ipLocationRevision = '6a276cc7c4f9f2d7ff1d8ace14b91af59752f943'
def ipLocationChecksum = '06db87f5525f9db4ae7881f8799462cce76c0c264123153525506bce5d577ac2'
def ipLocationArchive = layout.buildDirectory.file('ip-location-maker/source.zip')
def ipLocationSource = layout.buildDirectory.dir('ip-location-maker/upstream')
def ipLocationResources = layout.buildDirectory.dir('generated/ip-location')
def downloadIpLocationSource = tasks.register('downloadIpLocationSource') {
inputs.property('revision', ipLocationRevision)
inputs.property('checksum', ipLocationChecksum)
outputs.file(ipLocationArchive)
doLast {
def target = ipLocationArchive.get().asFile
target.parentFile.mkdirs()
def digest = { File file ->
def sha = java.security.MessageDigest.getInstance('SHA-256')
file.withInputStream { stream ->
byte[] buffer = new byte[8192]
int count
while ((count = stream.read(buffer)) != -1) {
sha.update(buffer, 0, count)
}
}
sha.digest().encodeHex().toString()
}
if (!target.exists() || digest(target) != ipLocationChecksum) {
def connection = URI.create("https://codeload.github.com/lionsoul2014/ip2region/zip/${ipLocationRevision}").toURL().openConnection()
connection.connectTimeout = 30000
connection.readTimeout = 60000
connection.inputStream.withCloseable { input ->
target.withOutputStream { output -> output << input }
}
if (digest(target) != ipLocationChecksum) {
throw new GradleException('IP location source checksum mismatch')
}
}
}
}
def extractIpLocationSource = tasks.register('extractIpLocationSource', Sync) {
dependsOn downloadIpLocationSource
from({ zipTree(ipLocationArchive.get().asFile) }) {
include '*/maker/java/src/main/java/**', '*/data/ipv4_source.txt',
'*/data/ipv6_source.txt', '*/LICENSE.md'
eachFile { path = path.substring(path.indexOf('/') + 1) }
includeEmptyDirs = false
}
into ipLocationSource
}
def compileIpLocationMaker = tasks.register('compileIpLocationMaker', JavaCompile) {
dependsOn extractIpLocationSource
source ipLocationSource.map { it.dir('maker/java/src/main/java') }
classpath = files()
destinationDirectory = layout.buildDirectory.dir('ip-location-maker/classes')
}
def prepareIpLocationDatabase = tasks.register('prepareIpLocationDatabase')
[4, 6].each { version ->
def database = ipLocationResources.map { it.file("ip-location/ip2region_v${version}.xdb") }
def sourceData = ipLocationSource.map { it.file("data/ipv${version}_source.txt") }
def generateDatabase = tasks.register("generateIpLocationV${version}", JavaExec) {
dependsOn compileIpLocationMaker
classpath = files(compileIpLocationMaker.flatMap { it.destinationDirectory })
mainClass = 'org.lionsoul.ip2region.MakerApp'
maxHeapSize = '512m'
inputs.file(sourceData)
inputs.property('fields', '0,1,4')
outputs.file(database)
doFirst {
database.get().asFile.parentFile.mkdirs()
args = ["--src=${sourceData.get().asFile}", "--dst=${database.get().asFile}",
"--version=ipv${version}", '--field-list=0,1,4']
}
}
prepareIpLocationDatabase.configure { dependsOn generateDatabase }
}
tasks.named('processResources', Copy) {
dependsOn tasks.named('prepareIpLocationDatabase')
from(ipLocationResources) {
include 'ip-location/*.xdb'
}
from(ipLocationSource.map { it.file('LICENSE.md') }) {
into 'ip-location'
rename { 'LICENSE.txt' }
}
dependsOn project(':packages').tasks.named('pnpmBuild')
from(project(':packages').layout.projectDirectory.dir('ui/build/dist')) {
into 'ui'
}
from(project(':packages').layout.projectDirectory.dir('widget/build/dist')) {
into 'static'
}
doFirst {
delete layout.buildDirectory.dir('resources/main/ui'),
layout.buildDirectory.dir('resources/main/static')
}
}
tasks.named('clean') {
dependsOn project(':packages').tasks.named('clean')
}
halo {
version = "2.27.0"
debug = true
}