build.gradle

plugins {
    id 'fabric-loom' version '1.0.11'
    id 'maven-publish'
    // for external java lib
    id 'java-library'
    // pack libs in our own jar
    id 'com.github.johnrengelman.shadow' version '7.1.2'
    // kotlin
    id "org.jetbrains.kotlin.jvm" version "1.7.21"
    // kotlinx serialization
    id 'org.jetbrains.kotlin.plugin.serialization' version '1.7.21'
}

version = project.mod_version
group = project.maven_group

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.
    maven { url 'https://jitpack.io' }
    // for test only
//    mavenLocal()
    mavenCentral()
}

dependencies {

    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    // mappings loom.officialMojangMappings()
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // run with online
    modImplementation "com.ptsmods:devlogin:3.1.1"
    // kotlin
    modImplementation "net.fabricmc:fabric-language-kotlin:1.8.6+kotlin.1.7.21"
    // kotlin logger
    shadow(implementation "io.github.microutils:kotlin-logging-jvm:3.0.4")
    // i2p-p2p-lib
    shadow(implementation "info.skyblond:i2p-p2p-chat:0.0.4")
    // Fabric API. You need this to load translation
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    testImplementation 'org.junit.jupiter:junit-jupiter:5.9.0'
}

test {
    useJUnitPlatform()
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    archivesBaseName = project.archives_base_name
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        jvmTarget = JavaLanguageVersion.of(targetJavaVersion)
    }
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}

shadowJar {
    configurations = [project.configurations.shadow]
    archiveClassifier.set("mca-shadow")
    // avoid classpath collide
    relocate "net.i2p", "info.skyblond.mc.mca.shadow.net.i2p"
    relocate "com.dampcake.bencode", "info.skyblond.mc.mca.shadow.com.dampcake.bencode"
}

remapJar {
    dependsOn(shadowJar)
    inputFile = tasks.shadowJar.archiveFile
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}