build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            url uri('repo')
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.3.1'
        classpath 'com.iknow.multidex.builder.plugin:MultiDexBuildPlugin:1.0.0'
        classpath 'com.novoda:bintray-release:0.3.4'
    }
}

ext{
    root = project(":").projectDir
    // local.properties 来自于AS自动创建
    // 可以保存所有本地工程配置
    // 不允许上传git库
    Properties properties = new Properties()
    properties.load(project.rootProject.file('local.properties').newDataInputStream())

    // 从系统环境变量中或者local.properties配置文件中读取SDK位置
    if(System.getenv("ANDROID_HOME")!=null){
        sdkDir = System.getenv("ANDROID_HOME")
    }
    else{ // 在local.properties中定义
        sdkDir = properties.getProperty('sdk.dir')
    }

    //Debug代码：开发人员可以手动改为false，这样工程就是标准Android工程，可供开发调试。
    //改为true，请使用 gradle assembleRelease bundleRelease repackAll 命令打出多apk的release包。
    solidMode = true
    //可以在local.properties里修改这个值。添加一行 solidMode=false 即可。
    solidModeConfigValue = properties.getProperty('solidMode')
    if('true'.equalsIgnoreCase(solidModeConfigValue)){
        solidMode = true
    }
    else if ('false'.equalsIgnoreCase(solidModeConfigValue)){
        solidMode = false
    }

}

allprojects {
    repositories {
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}