-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathFirebug.asm
2777 lines (2777 loc) · 54 KB
/
Firebug.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
.OPT NO LIST
;
; *************************
; * FIREBUG *
; * by Kyle Peacock *
; * & Tom Hudson *
; * ANALOG Computing *
; * All Rights Reserved *
; *************************
;
; Redefined Characters by
; Jon Bell -- 6/26/84
;
; CONSTANTS
;
GAMESET = $0400 ;CHARACTER SET
PLAYBS = $00 ;P/M BASE ADDR.
SCREENBASE = $2000 ;BOARD RAM.
MISS = PLAYBS+768 ;MISSILEs
BOMB = 15
;
; ZERO PAGE USAGE
;
*= $80
LO *= *+2 ;2-BYTE POINTERS
BMB *= *+2
ZLO *= *+2 ;Z-PAGE POINTER.
LOW *= *+2 ;Z-PGAE POINTER.
HLO *= *+2
DRWLO *= *+2 ;CHAR DATA PNTR.
PLLO *= *+2 ;CHAR WORK PNTR.
ADL *= *+2
ELO *= *+2
ELO2 *= *+2
BLO *= *+2
BLO2 *= *+2
BUGL *= *+2 ;FIREBUG X & Y.
SCORE *= *+3 ;BCD SCORE VALUE
SCOADD *= *+3 ;SCORE ADD VALUE
HBIT *= *+1 ;HSCROL RAM COPY
VBIT *= *+1 ;VSCROL RAM COPY
DIGGIN *= *+1 ;DIGGING FLAG
CHANGE1 *= *+1 ;MATING SOUND 1.
CHANGE2 *= *+1 ;MATING SOUND 2.
BULLNOISE *= *+1 ;BULLET NOISE
BOOMNOISE *= *+1 ;BULLET NOISE
NOBULL *= *+2 ;SPARKS FIRED.
BULLX *= *+4 ;SPARK X-COORD.
BULLY *= *+4 ;SPARK Y-COORD.
BULLDIR *= *+4 ;SPARK DIRECT.
BULLTIME *= *+4 ;SPARK LIFE
BULLPNT *= *+1 ;BAR LINE PNTR.
PLAYNO *= *+1 ;PLAYER UP.
STARTLEVEL *= *+1 ;STARTING LVL.
LEVEL *= *+1 ;CURRENT LEVEL
BCDLVL *= *+1 ;BCD LEVEL #
TIMER *= *+1 ;GENERAL TIMER
VSTOP *= *+1 ;HALT FLAG.
YPOINT *= *+1 ;BOARD Y-COORD.
XPOINT *= *+1 ;BOARD X-COORD.
YTEMP *= *+1 ;Y-REG TEMP HOLD
MINX *= *+1 ;MIN X VALUE
MINY *= *+1 ;MIN Y VALUE
MAXX *= *+1 ;MAX X VALUE
MAXY *= *+1 ;MAX Y VALUE
MAXBUGS *= *+1 ;# OF CHARs
EATNOISE *= *+1 ;EATING SOUND
GENTIM *= *+1 ;MATING TIMER
GENCTR *= *+1 ;MATING COUNTER
XCOORD *= *+1 ;X COORDINATE
YCOORD *= *+1 ;Y COORDINATE
LISTPOINT *= *+1 ;D-LIST PNTR.
NEWBACK *= *+1 ;BOARD B-COLOR.
MOVETIME *= *+1 ;MOVEMENT TIMER.
FIRETIME *= *+1 ;FIRING TIMER.
PHASETIME *= *+1 ;PHASE TIMER.
ETRY *= *+1
OLDVAL *= *+1 ;OLD CHAR
EGGS *= *+1 ;BABY COUNT
ENIX *= *+1 ;ENEMY INDEX
GNEWIX *= *+1 ;GENERATION INDX
NEWTYP *= *+1 ;NEW ENEMY TYPE
GENFLG *= *+1 ;MATING FLAG
BUGTIM *= *+1 ;BUG TIMER
EXPPH *= *+1 ;EXPLOSION PHASE
EXPCHR *= *+1 ;EXPL. CHARACTER
BOMBCT *= *+1 ;# OF BOMBS
XTEMP *= *+1 ;X SAVE AREA
EXNOISE *= *+1 ;EXPLOSION SOUND
ARMTIM *= *+1 ;BOMB ARM TIMER
BULTIM *= *+1 ;BULLET TIMER
SHCOLR *= *+1 ;TEXT COLOR
SHOBYT *= *+1 ;TEXT CHAR
LIVES *= *+1 ;# OF BUGS LEFT
ECOUNT *= *+1 ;# OF BABIES
EGGTOT *= *+1 ;# OF EGGS
EGGIX *= *+1 ;BABY INDEX
EGROUP *= *+1 ;BABY GROUP #
TYPE *= *+5 ;CHAR. TYPE.
PHASE *= *+5 ;CHAR. PHASE.
;
; RAM USAGE
;
*= $0500
ETYP *= *+30 ;ENEMY TYPE
EACT *= *+30 ;ENEMY ACTIVE
EDIR *= *+30 ;ENEMY DIRECTION
EADL *= *+30 ;ENEMY ADDR LO
EADH *= *+30 ;ENEMY ADDR HI
BOMBL *= *+100 ;BOMB ADDR LO
BOMBH *= *+100 ;BOMB ADDR HI
ARMED *= *+100 ;BOMB ARMED FLAG
EGGL *= *+52 ;BABY ADDR LO
EGGH *= *+52 ;BABY ADDR HI
EGGACT *= *+52 ;BABY ACTIVE
; **********************
; * MASTER EQUATE FILE *
; **********************
;
; I/O Routines
;
DSKINV = $E453
SIOINV = $E465
;
; Operating System Equates
;
CASINI = $02
DOSVEC = $0A
DOSINI = $0C
ATRACT = $4D
POKMSK = $10
BRKKEY = $11
RTCLOK = $12
VDSLST = $0200
VIMIRQ = $0216
CDTMV1 = $0218
CDTMV2 = $021A
CDTMV3 = $021C
CDTMV4 = $021E
CDTMV5 = $0220
CDTMA1 = $0226
CDTMA2 = $0228
CDTMF3 = $022A
CDTMF4 = $022C
CDTMF5 = $022E
SRTIMR = $022B
SDMCTL = $022F
SDLSTL = $0230
SDLSTH = $0231
SSKCTL = $0232
LPENH = $0234
LPENV = $0235
GPRIOR = $026F
PADDL0 = $0270
STICK0 = $0278
STICK1 = $0279
STRIG0 = $0284
SHFLK = $02BE
PCOLR0 = $02C0
COLOR0 = $02C4
COLOR1 = $02C5
COLOR2 = $02C6
COLOR3 = $02C7
COLOR4 = $02C8
MEMLO = $02E7
CHART = $02F3
CHBAS = $02F4
CH = $02FC
DDEVIC = $0300
DUNIT = $0301
DCOMND = $0302
DSTATS = $0303
DBUFLO = $0304
DBUFHI = $0305
DTIMLO = $0306
DBYTLO = $0308
DBYTHI = $0309
DAUX1 = $030A
DAUX2 = $030B
ICCOM = $0342
ICBAL = $0344
ICBAH = $0345
ICBLL = $0348
ICBLH = $0349
ICAX1 = $034A
ICAX2 = $034B
CIOV = $E456
SIOV = $E465
SETVBV = $E45C
SYSVBV = $E45F
XITVBV = $E462
OSRETN = $E474
CLICK = $FCD8
;
; Hardware Registers
;
HPOSP0 = $D000
HPOSP1 = $D001
HPOSP2 = $D002
HPOSP3 = $D003
M0PF = $D000
M1PF = $D001
M2PF = $D002
M3PF = $D003
HPOSM0 = $D004
HPOSM1 = $D005
HPOSM2 = $D006
HPOSM3 = $D007
P0PF = $D004
P1PF = $D005
P2PF = $D006
P3PF = $D007
M0PL = $D008
M1PL = $D009
M2PL = $D00A
M3PL = $D00B
P0PL = $D00C
P1PL = $D00D
P2PL = $D00E
P3PL = $D00F
SIZEP0 = $D008
SIZEP1 = $D009
SIZEP2 = $D00A
SIZEP3 = $D00B
SIZEM = $D00C
GRAFP0 = $D00D
GRAFP1 = $D00E
GRAFP2 = $D00F
GRAFP3 = $D010
TRIG0 = $D010
GRAFM = $D011
COLPM0 = $D012
COLPM1 = $D013
COLPM2 = $D014
COLPM3 = $D015
COLPF0 = $D016
COLPF1 = $D017
COLPF2 = $D018
COLPF3 = $D019
COLBK = $D01A
PRIOR = $D01B
VDELAY = $D01C
GRACTL = $D01D
HITCLR = $D01E
CONSOL = $D01F
POT0 = $D200
AUDF1 = $D200
AUDF2 = $D202
AUDF3 = $D204
AUDF4 = $D206
AUDC1 = $D201
AUDC2 = $D203
AUDC3 = $D205
AUDC4 = $D207
AUDCTL = $D208
ALLPOT = $D208
KBCODE = $D209
STIMER = $D209
RANDOM = $D20A
SERIN = $D20A
SKREST = $D20A
POTGO = $D20B
SEROUT = $D20C
IRQEN = $D20E
IRQST = $D20E
SKCTL = $D20F
SKSTAT = $D20F
PORTA = $D300
DMACTL = $D400
CHACTL = $D401
DLISTL = $D402
DLISTH = $D403
HSCROL = $D404
VSCROL = $D405
PMBASE = $D407
CHBASE = $D409
WSYNC = $D40A
VCOUNT = $D40B
PENH = $D40C
PENV = $D40D
NMIEN = $D40E
NMIRES = $D40F
NMIST = $D40F
;
*= $0800 ;prog start
;
; *****************************
; * FIREBUG IGNITION *
; * Tom Hudson & Kyle Peacock *
; *****************************
;
.LOCAL
;
BICFLICK
LDA #$24 ;RELOCATE PROG
STA HLO+1 ;TO $0800
LDA #$08 ;FROM $2400
STA LO+1 ;(DISK ONLY)
LDA #0
STA HLO
STA LO
RELOC1 LDY #0
RELOC2 LDA (HLO),Y
STA (LO),Y
DEY
BNE RELOC2
INC LO+1
INC HLO+1
LDA HLO+1
CMP #$38
BNE RELOC1
JMP DIGIN
DIGIN
LDA #$22 ;TURN ON...
STA SDMCTL ;SCREEN
LDA #$04 ;NUMBER OF CHARs
STA MAXBUGS ;TO MANIPULATE.
LDA #$01 ;STARTING LEVEL
STA STARTLEVEL ;IS ONE.
IGNITE
LDA #$01 ;SET UP.
STA LISTPOINT ;DISPLAY LIST.
STA HPOSM2 ;PLACE BORDERS
STA HPOSM3 ;OFFSCREEN.
STA VSTOP ;HALT VBLANK.
JSR SOUNDOFF ;SOUNDS OFF.
LDA #$06 ;SET ACC.
LDX #VBLANK/256 ;HI ADDR.
LDY #VBLANK&255 ;LO ADDR.
JSR SETVBV ;VBLANK INIT.
LDA #$07 ;SET ACC.
LDX #DBLANK/256 ;HI ADDR
LDY #DBLANK&255 ;LO ADDR.
JSR SETVBV ;DBLANK INIT.
LDA #$C0 ;SET ACC.
STA NMIEN ;ENABLE DLIs
?NOPRESS
LDA CONSOL ;GET CONSOLE.
CMP #7 ;UNTOUCHED?
BEQ ?PRESS ;IF =0 BRANCH!
STA ?PREV ;SAVE CONSOLE.
JMP ?NOPRESS ;JUMP ON IT!
?PRESS
LDA ?PREV ;PREV. CONSOLE.
CMP #6 ;START PRESSED?
BEQ ?VAROOM ;IF =6 BRANCH!
LDA SKSTAT ;KEYBOARD KEY
AND #$04 ;STILL PRESSED?
BEQ ?NOPRESS ;IF =0 BRANCH!
LDA CH ;GET CHARACTER.
LDX #$08 ;SET INDEX-X.
?NUMCOMP
CMP ?NUMBASE,X ;IS CHAR A #?
BEQ ?GOTANUM ;YES! BRANCH!
DEX ;NO. RESET PNTR.
BPL ?NUMCOMP ;HANDLE ALL.
BMI ?NOPRESS ;NO #s PRESSED.
?GOTANUM
STX STARTLEVEL ;SAVE START-
INC STARTLEVEL ;ING LEVEL #.
STX BCDLVL
INC BCDLVL
JSR SHOLVL
JSR SETCOLORS
LDA #$FF ;RESET KEYBOARD
STA CH ;CHARACTER.
JMP ?NOPRESS ;JUMP ON IT.
?VAROOM
LDA #$00
STA ?PREV ;RESET PREVIOUS.
JSR INIT ;INITIALIZE
NEWLVL
LDA #$00 ;CLEAR.
STA VSTOP ;START VBLANK.
STA LISTPOINT ;SET DISPLAY.
MAINLN
;
; GAME PAUSED?
;
LDA CONSOL ;CONSOLE BUTTON.
CMP #$07 ;UNTOUCHED?
BEQ ?PCHECK ;YES. BRANCH!
JMP IGNITE ;RESTART ALL!!!
?PCHECK
LDA CH ;IS KEYBOARD
CMP #$21 ;SPACEBAR?
BNE ?PAUSE ;IF NOT, BRANCH!
LDA SKSTAT ;STILL HOLDING
AND #$04 ;DOWN KEY?
BEQ ?PAUSE ;IF YES, BRANCH!
LDA #$01
STA VSTOP ;HALT VBLANK.
STA CH ;CLEAR CHAR.
JSR SOUNDOFF ;SOUNDS OFF.
?WAIT
LDA CH ;IF SPACEBAR
CMP #$21 ;PRESSED?
BNE ?WAIT ;NO. BRANCH!
?WAITMORE
LDA SKSTAT ;IS SPACEBAR
AND #$04 ;STILL HELD?
BEQ ?WAITMORE ;YES, BRANCH!
LDA #$00 ;CLEAR
STA VSTOP ;START VBLANK.
STA CH ;RESET CHAR.
?PAUSE
LDA ARMTIM ;TIMER ELAPSED?
BNE CHKBUL ;NO! BRANCH!
LDA #1 ;RESET TIMER.
STA ARMTIM
JSR ARMBOM ;SUBROUTINE.
CHKBUL
LDA BULTIM ;TIMER ELAPSED?
BNE CHKBUG ;NO! BRANCH!
LDA #3 ;RESET TIMER.
STA BULTIM
JSR SPARK ;SUBROUTINE.
CHKBUG LDA BUGTIM ;TIMER UP?
BNE NOFBMV ;NO! BRANCH!
JSR MOVBUG ;SUBROUTINE.
LDA DIGGIN ;RESET TIMER
BEQ ?EIGHT
LDA #11 ;DIGGING.
BNE ?GOTSPD
?EIGHT
LDA #8 ;NOT DIGGING.
?GOTSPD
STA BUGTIM ;SAVE TIMER.
NOFBMV
LDA GENFLG ;MATING SEASON?
BEQ NOGTST ;YES!
LDA GENCTR ;SECOND ELAPSED?
BNE NOGTST ;NO!
LDA #60 ;SET TIMER TO
STA GENCTR ;1 SECOND
DEC GENTIM ;1 LESS SECOND
BNE NOGTST ;NOT ZERO!
LDA #0 ;TIME TO START
STA GENFLG ;MATING SEASON!
NOGTST
LDA TIMER ;TIMER ELAPSED?
BEQ DOENMY ;YES, DO ENEMIES
JMP MAINLN ;NO! BRANCH!
DOENMY LDA LEVEL ;RESET ENEMY
LSR A ;BUG MOVEMENT
CMP #16 ;TIMER ACCORDING
BCC ?GOTNEW ;TO LEVEL OF
LDA #15 ;GAME.
?GOTNEW
TAX ;[LEVEL 30 MAX.]
LDA ENSPEED,X
STA TIMER ;SAVE TIMER.
JSR ENMOVE ;MOVE ENEMIES
JSR BMOVE ;MOVE BABIES
LDA ECOUNT ;ANY ENEMIES?
BNE GAMECONT ;YES!
INC LEVEL ;NO ENEMIES,
SED ;ADVANCE LEVEL
LDA BCDLVL
CLC
ADC #1
STA BCDLVL
CLD ;HERE TOM?!?
JSR SHOLVL ;SHOW NEW LEVEL
JSR INIT3 ;RE-INIT
JMP NEWLVL ;AND PLAY!
GAMECONT
JMP MAINLN ;LOOP BACK!
ENSPEED
.BYTE 20,19,18,17,16,15
.BYTE 14,13,12,11,10,9
.BYTE 8,7,6,5
?NUMBASE
.BYTE $1F,$1E,$1A,$18,$1D
.BYTE $1B,$33,$35,$30
?PREV .BYTE 0
;
; *****************************
; * FIREBUG DEATH/ENEMY MOVER *
; * BY Tom Hudson *
; *****************************
;
;FIREBUG DEATH
;
DEAD LDA BUGL ;SET EXPLOSION
STA ELO ;POSITION = TO
LDA BUGL+1 ;BUG'S LAST
STA ELO+1 ;POSITION
JSR EXPLOD ;BOOM!!!
DEC LIVES ;1 LESS LIFE
BMI GAMOVR ;GAME OVER IF <0
JSR SHOLIV ;SHOW LIVES
JSR INIT3 ;RE-INIT LEVEL
JMP NEWLVL ;AND RESTART!
;
;GAME OVER!
;
GAMOVR
JSR INIT3 ;RE-INIT
JMP IGNITE ;AND SHOW TITLE
;
;ENEMY MOVER
;
ENMOVE LDA #0 ;ZERO...
STA ECOUNT ;ENEMY COUNT
LDX #29 ;30 ENEMIES MAX
ENLP STX ENIX ;SAVE INDEX
LDA EACT,X ;ACTIVE?
BNE ACTIVE ;YES!
JMP NXTEN ;NO, NEXT ENEMY
ACTIVE LDA EADL,X ;GET...
STA ADL ;ENEMY'S...
LDA EADH,X ;ADDRESS...
STA ADL+1 ;IN POINTER
LDY #0 ;GET THE CHAR...
LDA (ADL),Y ;FROM DISPLAY
CMP ETYP,X ;ENEMY OK?
BEQ ENMYOK ;YES!
LDA #0 ;UH-OH, HE'S NO
STA EACT,X ;LONGER ACTIVE!
LDA #12 ;GET ENEMY'S
SEC ;SCORE VALUE
SBC ETYP,X
AND #$06
ASL A
ASL A
ASL A ;AND PUT IN...
STA SCOADD+2 ;ADD VALUE
JSR ADDSCO ;ADD TO SCORE
JMP NXTEN ;NEXT ENEMY!
ENMYOK LDA #0 ;RESET MOVEMENT
STA OK+8 ;TO CHARS 8
STA OK+10 ;AND 10
LDA GENFLG ;MATING SEASON?
BNE GENDUN ;NO!
LDA #1 ;SET...
LDY ETYP,X ;ENEMY TYPE'S...
STA OK,Y ;OK FLAG
;
;PRIORITY MOVE CHECK
;
GENDUN LDA #3 ;TRY 4 DIRS.
STA GNEWIX ;SAVE IN INDEX
PRILP LDY GNEWIX ;GET INDEX
LDA EADL,X ;ADD...
CLC ;DIRECTION...
ADC DIRADL,Y ;OFFSET...
STA ADL ;TO...
LDA EADH,X ;ENEMY'S...
ADC DIRADH,Y ;ADDRESS
STA ADL+1
LDY #0 ;LOAD THE BYTE..
LDA (ADL),Y ;IN THAT DIR.
AND #$7F ;MASK HI BIT
STA OLDVAL ;SAVE OLD VALUE
TAY ;CHAR # IN Y
LDA OK,Y ;CAN WE GO THERE?
BEQ NOPRI ;NO!
LDA CHANCE,Y ;GET CHANCE
CMP #$FF ;100% CHANCE?
BNE NOPRI ;NO!
LDA GNEWIX ;GET DIRECTION,
STA EDIR,X ;SAVE DIRECTION,
JSR EXMOVE ;MOVE ENEMY!
JMP NXTEN ;NEXT ENEMY
NOPRI DEC GNEWIX ;NEXT DIRECTION
BPL PRILP ;KEEP CHECKIN'
;
;NO PRIORITY MOVE, SO LET'S TRY
;A RANDOM DIRECTION!
;
ETRYLP LDA #4 ;TRY 5 DIRS.
STA ETRY ;SAVE INDEX
GETDIR LDA EDIR,X ;GET OLD DIR.
BPL SETDIR ;IT'S MOVING!
LDA RANDOM ;RANDOMIZE A
AND #3 ;DIRECTION
SETDIR STA EDIR,X ;SAVE DIR.
JSR DIRCHK ;IS THAT DIR OK?
BPL NXTEN ;YES!
DEC ETRY ;NEXT DIR.
BPL GETDIR ;AND LOOP BACK
LDA #$FF ;DIDN'T MOVE!
STA EDIR,X
NXTEN LDX ENIX ;GET ENEMY INDEX
LDA EACT,X ;ACTIVE?
BEQ EDEAD ;NO!
INC ECOUNT ;1 MORE ENEMY
EDEAD DEX ;NEXT ENEMY
BMI ENDONE ;IF <0, FINISHED
JMP ENLP ;LOOP BACK.
ENDONE RTS ;ALL DONE!
;
;DIRECTION CHECK SUBROUTINE
;
DIRCHK TAY ;MOVE DIR. TO Y
LDA EADL,X ;NOW ADD...
CLC ;DIRECTION...
ADC DIRADL,Y ;OFFSET...
STA ADL ;TO ENEMY'S...
LDA EADH,X ;POSITION
ADC DIRADH,Y
STA ADL+1
LDY #0 ;GET THE BYTE...
LDA (ADL),Y ;FROM DISPLAY
AND #$7F ;MASK HI BIT
STA OLDVAL ;SAVE OLD CHAR
TAY ;GET CHAR IN Y
LDA OK,Y ;CAN ENEMY MOVE?
BNE OKMOVE ;YES!
NOMOVE LDA #$FF ;NO!
RTS ;RETURN
OKMOVE LDA CHANCE,Y ;GET CHANCE
CMP RANDOM ;MOVE OK?
BCC NOMOVE ;NO!
EXMOVE LDA EADL,X ;GET ENEMY'S
STA HLO ;OLD ADDRESS
LDA EADH,X
STA HLO+1
LDA #0 ;ERASE OLD...
TAY ;ENEMY IMAGE
STA (HLO),Y
INY
STA (HLO),Y
DEY
LDA ETYP,X ;GET ENEMY CHAR,
STA (ADL),Y ;PUT ON SCREEN
INY
CLC
ADC #1
STA (ADL),Y
LDA ADL ;UPDATE ENEMY...
STA EADL,X ;ADDRESS TABLE
LDA ADL+1
STA EADH,X
LDA OLDVAL ;GET OLD CHAR
CMP ETYP,X ;SAME AS ENEMY?
BEQ GENIT ;YES, GENERATE!!
JMP NOGEN ;NO, DON'T GEN.
GENIT LDA #0 ;ENEMY NOT...
STA EACT,X ;ACTIVE ANYMORE
;
;THIS CODE GENERATES A NEW
;GROUP OF ENEMY OBJECTS
;
LDA ETYP,X ;GET ENEMY TYPE
CMP #8 ;TYPE 8?
BNE TYP10 ;NO, TYPE 10!
LDA #7 ;TURN ON...
STA CHANGE1 ;CHANGE SOUND 1
LDA #10 ;GEN TYPE 10
BNE GNEW ;GENERATE 'EM!
TYP10 LDA #7 ;TURN ON...
STA CHANGE2 ;CHANGE SOUND 2
LDA #8 ;GEN TYPE 8
GNEW STA NEWTYP ;SAVE NEW TYPE
LDA #3 ;GEN. 4 ENEMIES
STA GNEWIX ;SAVE IN INDEX
GNEWLP LDY GNEWIX ;GET INDEX
LDA ADL ;GET ENEMY ADDR,
CLC ;ADD...
ADC DIRADL,Y ;DIRECTION...
STA HLO ;ADDRESS...
LDA ADL+1 ;OFFSET
ADC DIRADH,Y
STA HLO+1
LDY #0 ;GET THE CHAR...
LDA (HLO),Y ;FROM DISPLAY
AND #$7F ;MASK HI BIT
CMP #1 ;BORDER?
BEQ NONEW ;CAN'T GEN IT!
CMP #6 ;FIREBUG?
BEQ KILL ;KILL HIM!
CMP #8 ;ENEMY TYPE 8?
BEQ NONEW ;CAN'T GEN!
CMP #10 ;ENEMY TYPE 10?
BEQ NONEW ;CAN'T GEN!
CMP #12 ;BABY BUG?
BEQ KILL ;KILL IT!
CMP #15 ;BOMB?
BEQ NONEW ;CAN'T GENERATE
LDX #29 ;SCAN FOR...
SCANEW LDA EACT,X ;INACTIVE ENEMY
BEQ GOTNEW ;GOT ONE!
DEX ;TRY NEXT SLOT
BPL SCANEW ;KEEP TRYING
LDA #1 ;NONE AVAILABLE!
STA GENFLG ;MATING OVER
LDA #100 ;WAIT 100...
STA GENTIM ;SECONDS.
JMP MOVEOK ;PROCEED
GOTNEW LDA #1 ;SET ENEMY AS...
STA EACT,X ;ACTIVE
LDA #$FF ;SET UP FOR...
STA EDIR,X ;NO DIRECTION
LDA HLO ;SAVE ENEMY...
STA EADL,X ;ADDRESS
LDA HLO+1
STA EADH,X
LDA NEWTYP ;GET NEW TYPE
STA ETYP,X ;SAVE IN TABLE
STA (HLO),Y ;PUT ENEMY...
CLC ;ON SCREEN!
ADC #1
INY
STA (HLO),Y
NONEW DEC GNEWIX ;NEXT GEN.
BMI MOVEOK ;ALL DONE!
JMP GNEWLP ;LOOP IF MORE
MOVEOK LDA #0 ;STATUS=0 (OK)
RTS ;RETURN!
NOGEN CMP #6 ;HIT FIREBUG?
BNE MOVEOK ;NO, MOVE OK.
KILL PLA ;REMOVE...
PLA ;OLD...
PLA ;STACK...
PLA ;ENTRIES,
JMP DEAD ;KILL BUG!!!
;
; ****************************
; * FIREBUG MOVEMENT ROUTINE *
; * BY Tom Hudson *
; ****************************
;
MOVBUG LDA BUGL ;GET AND SAVE...
STA HLO ;FIREBUG ADDRESS
LDA BUGL+1
STA HLO+1
LDY #0 ;GET THAT...
LDA (HLO),Y ;DISPLAY BYTE
CMP #6 ;BUG OK?
BEQ BUGLIV ;YUP!
BNE KILBUG ;UH-OH! KILL HIM
BUGLIV
LDX STICK0 ;GET STICK
LDY SDIR,X ;AND DIRECTION
BPL TRYBMV ;TRY TO MOVE
NOBMV RTS ;NO MOVE!
TRYBMV LDA BUGL ;ADD...
CLC ;DIRECTION...
ADC DIRADL,Y ;OFFSET...
STA ADL ;TO...
LDA BUGL+1 ;BUG'S...
ADC DIRADH,Y ;ADDRESS
STA ADL+1
LDY #0 ;GET THAT...
LDA (ADL),Y ;DISPLAY BYTE
CMP #1 ;BORDER?
BEQ NOBMV ;CAN'T GO THERE!
CMP #12 ;BABY?
BEQ NOBMV ;CAN'T GO THERE!
CMP #15 ;BOMB?
BCS NOBMV ;CAN'T GO THERE!
CMP #6 ;DIRT/TRAIL?
BCC OKBMV ;GO AHEAD!
CMP #14 ;BUG TRAIL?
BEQ OKBMV ;GO AHEAD!
KILBUG PLA ;MUST BE ENEMY!
PLA ;CLEAR STACK,
JMP DEAD ;KILL BUG!
OKBMV CMP #0 ;ENEMY TRAIL?
BEQ NOTDIG ;NO DIGGING!
CMP #14 ;BUG TRAIL?
BEQ NOTDIG ;NO DIGGING!
LDA #1 ;SET DIGGING...
STA DIGGIN ;SOUND FLAG
BNE DRWBUG ;AND DRAW BUG
NOTDIG LDA #0 ;TURN OFF...
STA DIGGIN ;DIGGING SOUND
DRWBUG LDA #14 ;ERASE BUG...
STA (HLO),Y ;WITH BUG TRAIL
INY
STA (HLO),Y
DEY
LDA #6 ;DRAW BUG...
STA (ADL),Y ;IN NEW...
INY ;LOCATION
CLC
ADC #1
STA (ADL),Y
LDA ADL ;UPDATE BUG'S
STA BUGL ;ADDRESS
LDA ADL+1
STA BUGL+1
RTS ;ALL DONE!
; ******************************
; * FIREBUG INTERRUPTS & SOUND *
; * BY Kyle Peacock *
; ******************************
;
.LOCAL
;
VBLANK
CLD ;CHILL DECIMAL.
;
; RANDOMIZE DETONATION
;
LDX #7 ;CHANGE 8 BYTES.
?JUNKIT
LDA RANDOM ;RANDOM #
AND #$55 ;MASK FOR PF#0.
STA GAMESET+[8*17],X ;SAVE.
DEX ;HANDLE NEXT.
BPL ?JUNKIT ;NOT DONE-BRANCH
;
; SET UP CORRECT DISPLAY LIST
;
LDA LISTPOINT ;D-LIST PNTR.
ASL A ;MULTIPLY BY 2.
TAX ;MOVE A TO X.
LDA ?DLISTBASE,X ;LET'S
STA SDLSTL ;PAINT THE
LDA ?DLISTBASE+1,X ;GANG-
STA SDLSTL+1 ;GREEN, & EAT
LDA #GAMEDLI1&255 ;FRANKS &
STA VDSLST ;BEANS.
LDA #GAMEDLI1/256 ;C.B.I. IS
STA VDSLST+1 ;ON THE MOVE.
;
; CHANGE TITLE SCREEN
;
DEC ?SWITCHTIME ;DEC TIMER.
BPL ?SWITCHDONE ;>0 BRANCH!
LDA RANDOM ;RANDOM #
AND #$3F ;MASK BITS 7 & 6
ORA #$0F ;ADD BITS 0-3.
STA ?SWITCHTIME ;SAVE TIMER.
INC ?FLOPFLIP ;INC NAME
LDA ?FLOPFLIP ;TOGGLE FLAG.
AND #$01 ;EXAMINE BIT 0.
ASL A ;MULTIPLY BY 2.
ASL A ;MULTIPLY BY 4.
TAX ;MOVE A TO X.
LDA ?SWITCHBASE,X ;GET ADDR
STA SWITCH1 ;OF NAME DATA
LDA ?SWITCHBASE+1,X ;AND
STA SWITCH1+1 ;PLACE INTO
LDA ?SWITCHBASE+2,X ;PROPER
STA SWITCH2 ;AREA OF DISPLAY
LDA ?SWITCHBASE+3,X ;LIST.
STA SWITCH2+1
?SWITCHDONE
;
; HALT ATTRACT MODE?
;
LDA VSTOP ;VBLANK HALTED?
BNE ?VDONE ;YES!
STA ATRACT ;ATTRACT MODE.
;
; SPARK REGENERATION
;
DEC ?REGEN ;TIME UP?
BPL ?REGEND ;IF >0 BRANCH!
LDA STICK0 ;GET JOYSTICK.
CMP #15 ;CENTERED?
BNE ?GENSET1 ;NO! BRANCH!
LDX #$00 ;CLEAR INDEX.
BEQ ?GENSET2 ;BRANCH!
?GENSET1
LDX DIGGIN ;BUG IN DIRT?
?GENSET2
LDA ?GENSET,X ;REGENERATION RATE.
STA ?REGEN ;SAVE TIMER.
INC ?FLIPFLOP ;INC TOGGLE
LDA ?FLIPFLOP ;FLAG.
AND #$01 ;EXAMINE BIT 0.
BEQ ?REGEND ;IF EVEN-BRANCH!
LDX BULLPNT ;GET POINTER.
LDA BULLETLINE,X ;DETERMINE
CMP #20 ;IF WE SHOULD
BNE ?BULLSET ;MODIFY THIS
CPX #29 ;CHARACTER OR
BEQ ?REGEND ;MOVE TO NEXT.
INC BULLPNT ;MOVE TO NEXT
INX ;CHARACTER.
?BULLSET
DEC BULLETLINE,X ;MODIFY.
?REGEND
;
; DECREMENT COUNT DOWN TIMERS
;
LDA GENCTR
BEQ ?NOGENT
DEC GENCTR
?NOGENT
LDA BULTIM ;TIMER = 0?
BEQ ?NOBUL ;YES. BRANCH!
DEC BULTIM ;NO. DECREMENT.
?NOBUL
LDA ARMTIM ;TIMER = 0?
BEQ ?NOAT ;YES. BRANCH!
DEC ARMTIM ;NO. DECREMENT.
?NOAT
LDA TIMER ;TIMER = 0?
BEQ ?NOTIME ;YES. BRANCH!
DEC TIMER ;NO. DECREMENT.
?NOTIME
LDA BUGTIM ;TIMER = 0?
BEQ ?NOBTIM ;YES. BRANCH!
DEC BUGTIM ;NO. DECREMENT.
?NOBTIM
;
; FINE SCROLLING (REVISITED)
;
JSR SCROLL
?VDONE
;
; UPDATE LMS POINTERS
;
JSR SHIFTER
;
; VERTICAL BLANK DONE
;
JMP SYSVBV
;
; ***************************
; * DEFERRED VERTICAL BLANK *
; ***************************
;
DBLANK
CLD ;CHILL DECIMAL
;
; UPDATE CHARACTER SET
;
JSR DRAW
LDA VSTOP ;DBLANK HALTED?
BNE ?DDONE ;IF <>0 BRANCH!
;
; DIGGING SOUND
;
JSR DIGSOUND
;
; BUG TRANSFORMATION SOUNDs
;
JSR TRANSFORM
;
; FIRE EGG EATEN SOUND
;
JSR CHOMP
;
; SPARK FIRING SOUND
;
JSR POPGUN
;
; DETONATION SOUND
;
JSR KABOOM
;
; BOMB DETONATION SOUND
;
JSR BOOMBOX
;
; DEF. VERTICAL BLANK DONE
;
?DDONE
JMP XITVBV
;
; POINTERS' DATABASES
;
?DLISTBASE
.WORD GAMELIST
.WORD TITLELIST
?SWITCHBASE
.WORD TITLE2
.WORD TITLE4
.WORD TITLE4
.WORD TITLE2
;
; ****************
; * FIREBUG DLIs *
; ****************
;
GAMEDLI1
PHA ;SAVE ACC.
TXA ;MOVE X TO A.
PHA ;SAVE ACC.
TYA ;MOVE Y TO A.
PHA ;SAVE ACC.
LDA #GAMESET/256 ;BUG CHRs
LDX #$3F ;DMA CONTROL.
LDY NEWBACK ;BACKGROUND.
STA WSYNC ;SAVE IT.
STX DMACTL ;SAVE IT.
STY COLBK ;SAVE IT.
STA CHBASE ;SAVE IT.
LDA #GAMEDLI2&255 ;LOAD UP
STA VDSLST ;FOR NEXT DLI.
LDA #GAMEDLI2/256 ;SAVE NEXT
STA VDSLST+1 ;DLI ADDRESS.
PLA ;RESTORE ACC.
TAY ;MOVE A TO Y.
PLA ;RESTORE ACC.
TAX ;MOVE A TO X.
PLA ;RESTORE ACC.
RTI ;BOGGIE BABY...
GAMEDLI2
PHA ;SAVE ACC.
LDA COLOR4 ;BACKGROUND.
STA WSYNC ;SAVE IT.
STA COLBK ;SAVE IT.