build.gradle

buildscript {
    ext.kotlin_version = '1.3.10'
    repositories {
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}


subprojects {

    def projectName = name

    ext.applyKotlinToJS = {
        apply plugin: 'kotlin2js'

        repositories {
            jcenter()
            maven { url "https://dl.bintray.com/kotlin/kotlin-dev" }
            maven { url "https://kotlin.bintray.com/kotlinx" }
        }

        dependencies {
            implementation "org.jetbrains.kotlin:kotlin-stdlib-js:$kotlin_version"
            testCompile project(":kotlin-ava")
        }

        compileKotlin2Js {
            kotlinOptions {
                outputFile = "${projectDir}/build/nodejs-${projectName}.js"
                moduleKind = "commonjs"
                sourceMap = true
                sourceMapEmbedSources = "always"
            }
        }

        compileTestKotlin2Js {
            kotlinOptions {
                outputFile = "${projectDir}/build/nodejs-${projectName}-test.js"
                moduleKind = "commonjs"
                sourceMap = true
                sourceMapEmbedSources = "always"
            }
        }
    }
}