ESP32 Perodically freezes and continues after a minute

[RUP3R70]

Hello. My name is Ruben, and I'm coding from Neuquén, in Patagonia (Argentina).
I'm working on an IoT project using an ESP32, Firebase, and an online web server. This is a work in progress.
The project was originally developed on an Arduino Duemilanove, then migrated to a NodeMCU ESP8266, and it worked correctly on both platforms.
However, now that it's running on an ESP32 (WROOM 32D DevkitC-V4), it's experiencing periodic freezes.
When I don't run the GET methods in the code, the ESP runs without issues. But when they are called, it freezes approximately every 34 seconds and hangs for about a minute, then continues for another 34 seconds and repeats the freeze. The error report says that the getBool or the getString method failed because of a 'connection refused' response.
I tried using another FirebaseData object to make the reading, as I read it might avoid a simultaneous writing and reading problem. I also tried changing the TX-RX buffer size. And added a few delay()s to give time to the processor and the internet connection.
Some variations I made, based on things I read in forums, only affected the time it took to freeze (from 34 to 50 seconds approximately).
What am I doing wrong?
As I said, it's a work in progress, so here is just a part of the code I'm using to test the problem.
Thanks in advance for any help.

#include <Arduino.h>
#include <WiFi.h>
#include <Firebase_ESP_Client.h>
#include <addons/TokenHelper.h>
#include <addons/RTDBHelper.h>


// Sensor DHT
#include <DHT.h>
#define DHTPIN 27
#define DHTTYPE DHT11

// WiFi
#define WIFI_SSID "XXXXXXXXXXXXXXXXXXX"
#define WIFI_PASSWORD "XXXXXXXXXXXXXXXXXXX"

// Firebase
#define API_KEY "XXXXXXXXXXXXXXXXXXX"
#define DATABASE_URL "XXXXXXXXXXXXXXXXXXX"

#define USER_EMAIL "XXXXXXXXXXXXXXXXXXX"
#define USER_PASSWORD "XXXXXXXXXXXXXXXXXXX"

// DC74HC4067
#define S0 18
#define S1 19
#define S2 21
#define S3 22
#define SIG 34

#define releLuz 32
#define releVent 33

#define LED_PIN 23

FirebaseData fbdo;
FirebaseData fbdoRead;
FirebaseAuth auth;
FirebaseConfig config;

bool signupOK = false;

long tiempoPasado = 0;
int pausa = 3000;

int sensores = 1;

bool releLuzStatus = false;

DHT dht(DHTPIN, DHTTYPE);


void leerTempHum()
{
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  float st = dht.computeHeatIndex(t, h, false);

  if (isnan(h) || isnan(t)) {
    Serial.println("No se puede leer el sensor DHT!");
    return;
  }

  Firebase.RTDB.setFloat(&fbdo, F("/Humedad"),h);
  Firebase.RTDB.setFloat(&fbdo, F("/Temperatura"),t);
  Firebase.RTDB.setFloat(&fbdo, F("/Sensacion Termica"),st);

  Serial.print("HUMEDAD: ");
  Serial.println(h);  
  Serial.print("TEMPERATURA: ");
  Serial.println(t);
  Serial.print("SENSACION TERMICA: ");
  Serial.println(st);
}

void rele(){  //ONLY TO TRY TO MAKE SOME PERIODICALL CHANGES ON THE RTDB. FOR NOW
   Firebase.RTDB.setBool(&fbdo, F("/releLuz"), !releLuzStatus);  
}

void leerCanalAnalogico(byte channel)
{
   digitalWrite(S0, bitRead(channel, 0));
   digitalWrite(S1, bitRead(channel, 1));
   digitalWrite(S2, bitRead(channel, 2));
   digitalWrite(S3, bitRead(channel, 3));
}

void sensoresA(){
  for (byte i = 0; i < sensores; i++)
   {
      leerCanalAnalogico(i);
      int sigValue = analogRead(SIG);

      Serial.print("Sensor ");
      Serial.print(i+1);
      Serial.print(": ");
      Serial.print(sigValue);
      Serial.print(" \t ");
      Firebase.RTDB.setInt(&fbdo, F("/sensorSuelo{i}"),sigValue);
   }
   Serial.println();
}


void setup() {
  Serial.begin(9600);

  pinMode(LED_PIN, OUTPUT);

  pinMode(S0, OUTPUT);
  pinMode(S1, OUTPUT);
  pinMode(S2, OUTPUT);
  pinMode(S3, OUTPUT);
  pinMode(SIG, INPUT);  

  pinMode(releLuz, OUTPUT);
  pinMode(releVent, OUTPUT);

  pinMode(LED_PIN, OUTPUT);

  // WiFi
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  Serial.print("Conectando");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  Serial.println();
  Serial.print("Conectado: ") ;
  Serial.println(WiFi.localIP());

  // Firebase
  Serial.printf("Firebase Client v%s\n\n", FIREBASE_CLIENT_VERSION);

  config.api_key = API_KEY;
  config.database_url = DATABASE_URL;

  //CHANGE BUFFER SIZE
  //fbdo.setBSSLBufferSize(4096 /* Rx buffer size in bytes from 512 - 16384 */, 1024 /* Tx buffer size in bytes from 512 - 16384 */);
  //fbdoRead.setBSSLBufferSize(4096 /* Rx buffer size in bytes from 512 - 16384 */, 1024 /* Tx buffer size in bytes from 512 - 16384 */);
  
  //auth.user.email = USER_EMAIL;
  //auth.user.password = USER_PASSWORD;

  if (Firebase.signUp(&config, &auth, "", ""))  {
    Serial.println("Conectado con Firebase RTDB");
    signupOK = true;
  }else {
    Serial.printf("%s\n", config.signer.signupError.message.c_str());
  }  
  config.token_status_callback = tokenStatusCallback;

  Firebase.begin(&config, &auth);
  Firebase.reconnectNetwork(true); 

  // Sensor DHT
  Serial.println(F("Inicio del DHT11!"));
  dht.begin();
}

void loop() {
  if (Firebase.ready() && signupOK) {
    if (millis() - tiempoPasado >= pausa) {
      leerTempHum();
      sensoresA();
      //rele();
      delay(10);
      tiempoPasado = millis();
      Serial.println(millis());
    }

    if(Firebase.RTDB.getString(&fbdo, "/Led1Status")) {
        String ledstatus = fbdo.stringData();
        if(ledstatus.toInt() == 1)  {
          digitalWrite(LED_PIN, LOW);
          Serial.println("on");
        }else {
          digitalWrite(LED_PIN, HIGH);
          Serial.println("off");
        }
      }else {
        Serial.print("Error in getInt, ");
        Serial.println(fbdo.errorReason());
    } 

    if(Firebase.RTDB.getBool(&fbdoRead, "/releLuz")) {
        releLuzStatus = fbdoRead.to<bool>(); //fbdo.boolData();
        if(releLuzStatus == true)  {
          digitalWrite(releLuz, LOW);
          Serial.println("releLuz ON");
        }else {
          digitalWrite(releLuz, HIGH);
          Serial.println("releLuz OFF");
        }
    }else {
        Serial.print("Error in getBool, ");
        Serial.println(fbdoRead.errorReason());
    } 

  }else {
    Serial.println("Algo salió mal. Pruebe reiniciar el ESP32");
  }
}

[mobizt]

This seems to be the bug in ESP32 WiFiClient use internally in this library that causes the session time out.

I recommend you should consider moving to new library which is better and easier to use.

[mobizt]

With this library you can try to update ESP32 Arduino Core and try again.

[RUP3R70]

Thanks for your answer Mobitz.
Now I'm at my workplace, but as soon as I get home, I will try with the new library.
Should I consider the Sync, or the Async examples to update the code I shared?

[mobizt]

It depends on your application and you should try it first.

In both cases, SSL client requires the time for SSL handshake when connecting to the server.