project.gradle

// Common configuration applied to all projects


import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent
import org.jetbrains.gradle.ext.JUnit

import java.nio.file.Files
import java.nio.file.Paths
import java.nio.file.attribute.PosixFileAttributes
import java.nio.file.attribute.PosixFilePermission
import java.util.stream.Collectors
import java.util.stream.StreamSupport

import static org.apache.tools.ant.taskdefs.condition.Os.FAMILY_WINDOWS
import static org.apache.tools.ant.taskdefs.condition.Os.isFamily
import static org.jetbrains.gradle.ext.ShortenCommandLine.MANIFEST
import org.jetbrains.gradle.ext.Application
import org.jetbrains.gradle.ext.JUnit

// Configure versions in gradle.properties (putting a gradle.properties file
// in a subproject only overrides root properties of same name for the actual
// subproject, not for its children!)

configurations.all {
  resolutionStrategy {
    // check for changing (i.e. SNAPSHOT) updates every build
    cacheChangingModulesFor 0, 'seconds'

    //failOnVersionConflict()

    // This has been replaced with eclipse angus implementation
    exclude group: "com.sun.activation", module: "jakarta.activation"

    // This has been replaced with org.bouncycastle bcpkix-jdk18on
    exclude group: "org.bouncycastle", module: "bcpkix-jdk15on"

    // This has been replaced with org.bouncycastle bcprov-jdk18on
    exclude group: "org.bouncycastle", module: "bcprov-jdk15on"

    eachDependency { DependencyResolveDetails details ->
      if (details.requested.group == 'org.eclipse.angus' && details.requested.name == 'angus-activation' && details.requested.version == '1.0.0') {
        details.useVersion '2.0.0'
      }
      if (details.requested.group == 'commons-io' && details.requested.name == 'commons-io') {
        details.useVersion '2.14.0'
      }
    }
  }
}

subprojects {
  // Give test tasks more memory (Gradle 5 reduced this to 512MB)
  tasks.withType(Test) {
    maxHeapSize = "2g"
  }

  // Give compiler tasks more memory
  tasks.withType(GroovyCompile) {
    groovyOptions.forkOptions.memoryMaximumSize = '2g' // Set max heap to 2 GB
  }
}

tasks.configureEach { task ->
  if (task.name in [
    'findSonatypeStagingRepository',
    'closeSonatypeStagingRepository',
    'releaseSonatypeStagingRepository',
    'closeAndReleaseSonatypeStagingRepository'
  ]) {
    // See: https://github.com/gradle-nexus/publish-plugin/issues/221
    task.notCompatibleWithConfigurationCache("Gradle Nexus Publish plugin task keeps Gradle Task/Project state")
  }
}

// Default repositories for dependency resolution
repositories {
  mavenLocal()
  // Needs to be above central due to org.geotools:gt-main issues
  maven {
    url = "https://repo.osgeo.org/repository/release/"
    content {
      includeGroup "it.geosolutions.jgridshift"
      includeGroup "org.eclipse.imagen"
      includeGroupByRegex "org\\.geotools.*"
    }
  }
  mavenCentral()
  maven {
    url = "https://pkgs.dev.azure.com/OpenRemote/OpenRemote/_packaging/OpenRemote/maven/v1"
  }
  maven {
    url = "https://central.sonatype.com/repository/maven-snapshots"
  }
  maven {
    url = "https://repo.jenkins-ci.org/releases/"
  }
  maven {
    url = 'https://jitpack.io'
  }
  maven {
    url = 'https://plugins.gradle.org/m2'
  }
}

// Eclipse needs help
pluginManager.apply('eclipse')

// Intellij needs help
pluginManager.apply('idea')
// Use the same output directories in IDE as in gradle
idea {
  module {
    outputDir = file('build/classes/main')
    testOutputDir = file('build/classes/test')
    excludeDirs += file(".node")
    excludeDirs += file("node_modules")
    excludeDirs += file("dist")
    excludeDirs += file("lib")
    excludeDirs += file("build")
  }
}

def getYarnInstallTask() {
  tasks.getByPath(":yarnInstall")
}

ext {
  getYarnInstallTask = this.&getYarnInstallTask
}

// Add UI tasks
ext.npmCommand = { cmd ->
  isFamily(FAMILY_WINDOWS) ? "${cmd}.cmd" : cmd
}

// Add yarn tasks
tasks.register('yarnInstall', Exec) {
  commandLine npmCommand("yarn"), "install"
}
tasks.register('yarnInstallForce', Exec) {
  commandLine npmCommand("yarn"), "install", "--force"
}

// Configure Java build
plugins.withType(JavaPlugin).whenPluginAdded {
  // Use Java 21
  tasks.withType(JavaCompile) {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
    def warnLogFile = file("$buildDir/${name}Warnings.log")
    logging.addStandardErrorListener(new StandardOutputListener() {
              void onOutput(CharSequence output) {
                warnLogFile << output
              }
            })
    options.compilerArgs += ["-Xlint:unchecked", "-Xlint:deprecation", "-parameters"]
    options.encoding = 'UTF-8'
  }

  // Allow dependencyInsight checks across all projects
  tasks.register('allDependencyInsight', DependencyInsightReportTask) {}

  base {
    // JAR/ZIP base name is the fully qualified subproject name
    archivesName = "${rootProject.name}${path.replaceAll(":", "-")}"
  }

  pluginManager.apply(libs.plugins.testLogger.get().pluginId)

  test {
    workingDir = rootProject.projectDir
    // Extension-only repos don't ship the manager UI tree expected by ManagerWebService.
    // Point tests at a minimal placeholder docroot so container startup still succeeds.
    environment "OR_APP_DOCROOT", rootProject.file("test-support/manager-app").absolutePath
    useJUnitPlatform()
    testLogging {
      // set options for log level LIFECYCLE
      events = [TestLogEvent.FAILED, TestLogEvent.PASSED, TestLogEvent.SKIPPED]
      exceptionFormat = TestExceptionFormat.FULL
      showExceptions = true
      showCauses = true
      showStackTraces = true

      // set options for log level DEBUG and INFO
      debug {
        events = [
          TestLogEvent.STARTED,
          TestLogEvent.FAILED,
          TestLogEvent.PASSED,
          TestLogEvent.SKIPPED,
          TestLogEvent.STANDARD_ERROR
        ]
        exceptionFormat = TestExceptionFormat.FULL
      }
      info.events = debug.events
      info.exceptionFormat = debug.exceptionFormat
    }

    addTestListener(new TestSummaryListener())
  }
}

// Configure Spotless
if (project == rootProject) {
  apply from: "${rootDir}/spotless.gradle"
}

// POM generator