Conway's Game of Life in Ivy

[fzipp]

This loosely follows the steps in John Scholes' popular video.

)origin 0
r = (3 3 rho iota 9) in 1 2 3 4 7
R = -1 flip -2 rot 5 7 take r
op life R = 1 R or.and 3 4 == box +/ +/% 1 0 -1 o.flip (1 rot R) (0 rot R) (-1 rot R)
RR = 15 35 take -10 -20 take R
op cells gen n =
	n == 0: cells
	(life cells) gen n-1

op pic a = "-o"[a]

Display the 100-th generation:

pic RR gen 100
----oo-------------------o--o------
---o----------------------oo-------
-----------------------------------
-----------------------------------
----------o------------------------
---------o-o---------oo------------
---------o-o---------oo------------
----------o-----ooo----------------
-----------------------------ooo---
-----------------------------o--o--
-------------------------ooo-ooooo-
-----------------------oo--o---o-oo
-----------------------o-------o-o-
-----------------------o---o---oo--
---oo-------------------o--o-------

[robpike]

Very nice!

[robpike]

Would it be OK to use this example in the demo or maybe lib.ivy? I might tweak it a bit. Credit to you and Dyalog of course.

[fzipp]

Yes, that's okay, very gladly.

[fgergo]

@fzipp thanks, for this version!
I just realized we now have box.

2 possibly interesting comments for others who later find this discussion and are learning apl and ivy together:
Under the youtube video a pinned comment by Dyalog references a Jupyter notebook, it has:
life←{⊃1 ⍵ ∨.∧ 3 4 = +/ +/ 1 0 ¯1 ∘.⊖ 1 0 ¯1 ⌽¨ ⊂⍵}
+/ +/ instead of +/ +⌿ .
(In this case these are equivalent, though also note +/ , in next comment.)

https://dfns.dyalog.com/c_life.htm has:
life←{↑1 ⍵∨.∧3 4=+/,¯1 0 1∘.⊖¯1 0 1∘.⌽⊂⍵}
this translates to
op life R = 1 R or.and 3 4 == box +/ , 1 0 -1 o.flip 1 0 -1 o.rot box R
(Without box, I only had an ivy version explicitly listing the 9 flip + rot products.)

[tcolgate]

I missed this discussion before opening my issue, here's the solution I ended up with (after one tweak from rsc)

op life M = 1 M or.and 3 4 @== +/ +/ 1 0 -1 o.flip 1 0 -1 @rot M