build.gradle.kts

import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
	id("org.springframework.boot") version "3.0.5"
	id("io.spring.dependency-management") version "1.1.0"
	kotlin("jvm") version "1.8.20"
	kotlin("plugin.spring") version "1.8.20"
	kotlin("plugin.serialization") version "1.8.20"
	id("org.graalvm.buildtools.native") version "0.9.20"
}

group = "com.example"
version = "0.0.1-SNAPSHOT"
java.sourceCompatibility = JavaVersion.VERSION_17

repositories {
	mavenCentral()
}

configurations.all {
	// Logback + the XML infrastructure that it makes reachable are worth to exclude to get a smaller native footprint
	exclude(module = "spring-boot-starter-logging")
	// We use Kotlin Serialization so no need for Jackson and kotlin-reflect
	exclude(module = "spring-boot-starter-json")
	// We use tomcat-embed-programmatic instead
	exclude(module = "tomcat-embed-core")
	exclude(module = "tomcat-embed-websocket")
}

dependencies {
	implementation("org.springframework.boot:spring-boot-starter-mustache")
	implementation("org.springframework.boot:spring-boot-starter-web")
	implementation("org.apache.tomcat.experimental:tomcat-embed-programmatic:${dependencyManagement.importedProperties["tomcat.version"]}")
	implementation("org.springframework.boot:spring-boot-starter")
	implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.5.0")
	testImplementation("org.springframework.boot:spring-boot-starter-test")
	testImplementation("org.springframework.boot:spring-boot-starter-webflux")
	testImplementation("io.projectreactor:reactor-test")
	testImplementation("io.projectreactor.kotlin:reactor-kotlin-extensions")
}

tasks.withType<KotlinCompile> {
	compilerOptions {
		freeCompilerArgs = listOf("-Xjsr305=strict")
		jvmTarget = JvmTarget.JVM_17
	}
}

tasks.withType<Test> {
	useJUnitPlatform()
}