complete zsh config

Author: sgblanch

zsh.d/10defaults.zsh.tmpl

@@ -0,0 +1,30 @@
+#!/bin/zsh
+
+# Basic prompt of user@host:/path%
+#
+# Same format as scp/rsync path and can be copied and used as such
+PROMPT='%n@%m:%~%# '
+
+# Default text editor.
+EDITOR="nano"
+VISUAL="nano"
+
+# Default pager to read text files
+PAGER="less"
+
+export EDITOR VISUAL PAGER
+
+# Explicitly set zsh to emacs mode.  Otherwise it will guess based on
+# value of $EDITOR
+command -v bindkey > /dev/null 2>&1 && bindkey -e
+
+# GitHub API token for homebrew.  Lifts API rate limits that can plague
+# frequent 'brew' usage.
+#
+# WARNING: when creating token, unselect *all* scopes
+# See:
+#      man brew
+#      https://github.com/settings/tokens
+#      https://developer.github.com/v3/#rate-limiting
+#export HOMEBREW_GITHUB_API_TOKEN=""
+

zsh.d/15wintitle.zsh

@@ -0,0 +1,18 @@
+#!/bin/zsh
+
+case "${TERM}" in
+	xterm*)
+		# $'\e]0;...\a' # set xterm window and icon (tab) name
+		# $'\e]1;...\a' # set xterm icon (tab) name
+		# $'\e]2;...\a' # set xterm window name
+		# $'\e]6;...\a' # working document as file://host/path/file *
+		# $'\e]7;...\a' # working directory as file://host/path/dir/ *
+		#     * url-encoded
+		precmd() { print -Pn $'%{\e]2;%n %~\a%}'; }
+		;;
+	screen*|tmux*)
+		# $'\ePtmux;...\a\e\\' # pass control sequence to xterm
+		# $'\ek...\e\\'      # set tmux window name
+		precmd() { print -Pn $'\ePtmux;\e\e]2;%n %~\a\e\\' $'%{\ek%n %~\e\\%}'; }
+		;;
+esac

zsh.d/40zsh.zsh

@@ -0,0 +1,17 @@
+#!/bin/zsh
+
+# Don't put duplicate lines in the history. See zshoptions(1) for more options
+setopt histignorealldups
+
+# Append to the history file, don't overwrite it
+setopt appendhistory
+setopt incappendhistory
+
+# Share history between terminals
+setopt sharehistory
+
+typeset -U PATH path
+
+# Set the number of commands zsh should remember
+HISTSIZE=1000
+SAVEHIST=1000

zsh.d/50completions.zsh

@@ -0,0 +1,8 @@
+#!/bin/zsh
+
+if [[ -n "${HOMEBREW_PREFIX:-}" ]]; then
+  fpath=("${HOMEBREW_PREFIX}/share/zsh/site-functions" $fpath)
+
+  autoload -Uz compinit
+  compinit
+fi

zsh.d/50composer.zsh

@@ -0,0 +1,5 @@
+#!/bin/zsh
+
+for dir in "${HOME}/.composer/vendor/bin" "${HOME}/.local/composer/vendor/bin"; do
+	[[ -d "${dir}" ]] && path=("${dir}" $path)
+done

zsh.d/50golang.zsh

@@ -0,0 +1,21 @@
+#!/bin/zsh
+
+# Find GOROOT, preferring homebrew's go installation over golang.org's
+# install pkg
+for dir in "${HOMEBREW_PREFIX:-/usr/local}/opt/go/libexec" /usr/local/go; do
+	if [[ -d "${dir}" ]]; then
+		export GOROOT="${dir}"
+		break
+	fi
+done
+
+# Add commom-ish source directories to GOPATH
+if [[ -n "${GOROOT:-}" ]]; then
+	typeset -U -T GOPATH gopath
+	for dir in "${HOME}/go" "${HOME}/src"; do
+		gopath+=("${dir}")
+		path=("${dir}/bin" $path)
+	done
+
+	export GOPATH PATH
+fi

zsh.d/50less.zsh

@@ -0,0 +1,21 @@
+#!/bin/zsh
+
+# Use lesspipe, if available, to support more formats and syntax
+# highlighting
+for lesspipe in lesspipe lesspipe.sh; do
+	if command -v "${lesspipe}" > /dev/null; then
+		eval "$(SHELL=/bin/zsh "${lesspipe}")"
+		break
+	fi
+done
+
+# Defaults for less
+#     -i ignore case (when search term is lowercase
+#     -M verbose prompt
+#     -R show raw control characters (ANSI colors)
+LESS="-iMR"
+
+# Disable less's history file
+LESSHISTFILE=-
+
+export LESS LESSHISTFILE

zsh.d/50python.zsh

@@ -0,0 +1,8 @@
+#!/bin/zsh
+
+# Add python's user bin directory to PATH
+if command -v python3 >/dev/null; then
+	path=("$(python3 -m site --user-base)/bin" $path)
+fi
+
+export PATH

zsh.d/50ruby.zsh

@@ -0,0 +1,8 @@
+#!/bin/zsh
+
+# add ruby's user gems bin directory to PATH
+if command -v ruby > /dev/null; then
+	ruby_dir="$(ruby -r rubygems -e 'puts Gem.user_dir')/bin"
+	[[ -d "${ruby_dir}" ]] && path=("${ruby_dir}" $path)
+fi
+unset ruby_dir

zsh.d/60userbin.zsh

@@ -0,0 +1,4 @@
+#!/bin/zsh
+
+# Add common user bin directories to PATH
+path=( "${HOME}/bin" "$HOME/.local/bin" $path )