-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathfoxref.prg
1710 lines (1413 loc) · 39.5 KB
/
foxref.prg
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
* Abstract...:
* Primary class for References application.
*
* Changes....:
*
#ifdef TESTING
* Below is a sample of using the FoxRef
* class programmatically
PUBLIC o AS FoxRef OF foxref.prg
cProject = "foxref"
cPattern = "oApp"
cFileDir = "c:\code\visgift"
* cSkeleton = "*.scx"
cFileTypes = "*.prg *.scx"
o = NEWOBJECT("FoxRef", "foxref.prg")
IF o.SetProject(cProject)
o.Quiet = .F.
o.FileTypes = cFileTypes
o.Search("for")
o.OverwritePrior = .F.
o.WildCards = .T.
o.Search("whil?")
ELSE
? "Unable to open project"
ENDIF
RETURN
#endif
#include "foxpro.h"
#include "foxref.h"
DEFINE CLASS FoxRef AS Session
PROTECTED lIgnoreErrors AS Boolean
PROTECTED lRefreshMode
PROTECTED cProgressForm
PROTECTED lCancel
PROTECTED tTimeStamp
PROTECTED lIgnoreErrors
PROTECTED ARRAY aFileTypes[1]
PROTECTED nFileTypeCnt
oSearchEngine = .NULL.
Comments = COMMENTS_INCLUDE
MatchCase = .T.
WholeWordsOnly = .F.
SubFolders = .F.
Wildcards = .F.
Quiet = .F. && quiet mode -- don't display search progress
ShowProgress = .T. && show a progress form
FileTypes = ''
ReportFile = REPORT_FILE
* MRU array lists
DIMENSION aLookForMRU[10]
DIMENSION aReplaceMRU[10]
DIMENSION aFolderMRU[10]
DIMENSION aFileTypesMRU[10]
aLookForMRU = ''
aReplaceMRU = ''
aFolderMRU = ''
aFileTypesMRU = ''
Pattern = ''
OverwritePrior = .T.
RefTable = ''
ProjectFile = ''
FileDirectory = ''
cSetID = ''
lRefreshMode = .F.
lIgnoreErrors = .F.
oProgressForm = .NULL.
lCancel = .F.
tTimeStamp = .NULL.
nFileTypeCnt = 0
cTalk = ''
nLangOpt = 0
cMessage = ''
cEscapeState = ''
cSYS3054 = ''
cSaveUDFParms = ''
cSaveLib = ''
cExclusive = ''
PROCEDURE Init()
THIS.cTalk = SET("TALK")
SET TALK OFF
SET DELETED ON
THIS.cExclusive = SET("EXCLUSIVE")
SET EXCLUSIVE OFF
THIS.cMessage = SET("MESSAGE",1)
THIS.nLangOpt = _VFP.LanguageOptions
_VFP.LanguageOptions=0
THIS.cEscapeState = SET("ESCAPE")
SET ESCAPE OFF
THIS.cSYS3054 = SYS(3054)
SYS(3054,0)
THIS.cSaveLib = SET("LIBRARY")
THIS.cSaveUDFParms = SET("UDFPARMS")
SET UDFPARMS TO VALUE
SET EXACT OFF
THIS.RestorePrefs()
* Create file type engine objects
THIS.AddFileType('', FILETYPE_CLASS_DEFAULT, FILETYPE_LIBRARY_DEFAULT) && default search engine
THIS.AddFileType("PRG", FILETYPE_CLASS_PRG, FILETYPE_LIBRARY_PRG) && program
THIS.AddFileType("H", FILETYPE_CLASS_H, FILETYPE_LIBRARY_H) && header
THIS.AddFileType("SCX", FILETYPE_CLASS_SCX, FILETYPE_LIBRARY_SCX) && form
THIS.AddFileType("VCX", FILETYPE_CLASS_VCX, FILETYPE_LIBRARY_VCX) && class library
THIS.AddFileType("DBF", FILETYPE_CLASS_DBF, FILETYPE_LIBRARY_DBF) && table
THIS.AddFileType("DBC", FILETYPE_CLASS_DBC, FILETYPE_LIBRARY_DBC) && database container
THIS.AddFileType("FRX", FILETYPE_CLASS_FRX, FILETYPE_LIBRARY_FRX) && report
THIS.AddFileType("LBX", FILETYPE_CLASS_LBX, FILETYPE_LIBRARY_LBX) && label
THIS.AddFileType("MNX", FILETYPE_CLASS_MNX, FILETYPE_LIBRARY_MNX) && menu
THIS.AddFileType("SPR", FILETYPE_CLASS_SPR, FILETYPE_LIBRARY_SPR) && screen
THIS.AddFileType("QPR", FILETYPE_CLASS_QPR, FILETYPE_LIBRARY_QPR) && query
THIS.AddFileType("MPR", FILETYPE_CLASS_MPR, FILETYPE_LIBRARY_MPR) && menu
ENDFUNC
PROCEDURE Destroy()
THIS.CloseProgress()
IF THIS.cEscapeState = "ON"
SET ESCAPE ON
ENDIF
IF THIS.cTalk = "ON"
SET TALK ON
ENDIF
IF THIS.cExclusive = "ON"
SET EXCLUSIVE ON
ENDIF
SYS(3054,INT(VAL(THIS.cSYS3054)))
_VFP.LanguageOptions = THIS.nLangOpt
IF THIS.cSaveUDFParms = "REFERENCE"
SET UDFPARMS TO REFERENCE
ENDIF
ENDFUNC
*!* PROCEDURE Error(nError, cMethod, nLine)
*!* IF THIS.lIgnoreErrors
*!* RETURN
*!* ENDIF
*!* DODEFAULT(nError, cMethod, nLine)
*!* ENDPROC
* To-Do: change this to a collection
* Add a filetype search -- This can be a collection in VFP8!!!
FUNCTION AddFileType(cFileType, cClassName, cClassLibrary)
LOCAL nIndex
LOCAL lSuccess
cFileType = ALLTRIM(UPPER(cFileType))
IF LEFT(cFileType, 1) == '.'
cFileType = SUBSTR(cFileType, 2)
ENDIF
lSuccess = .F.
nIndex = 0
IF VARTYPE(cFileType) <> 'C' OR EMPTY(cFileType)
cFileType = ''
nIndex = 1 && default search engine always the first row in the array
ELSE
IF THIS.nFileTypeCnt > 0
nIndex = ASCAN(THIS.aFileTypes, cFileType, -1, -1, 1, 14) && 14 = return row number, Exact On
ENDIF
ENDIF
IF PCOUNT() == 1
IF nIndex > 0
* remove filetype
=ADEL(THIS.aFileTypes, nIndex, 2)
THIS.nFileTypeCnt = THIS.nFileTypeCnt - 1
lSuccess = .T.
ENDIF
ELSE
IF VARTYPE(cClassLibrary) <> 'C' OR EMPTY(cClassLibrary)
cClassLibrary = FILETYPE_LIBRARY
ENDIF
oEngine = NEWOBJECT(cClassName, cClassLibrary)
IF VARTYPE(oEngine) == 'O'
IF nIndex == 0 OR THIS.nFileTypeCnt == 0
THIS.nFileTypeCnt = THIS.nFileTypecnt + 1
nIndex = THIS.nFileTypeCnt
DIMENSION THIS.aFileTypes[THIS.nFileTypeCnt, 2]
ENDIF
THIS.aFileTypes[nIndex, FILETYPE_EXTENSION] = cFileType
THIS.aFileTypes[nIndex, FILETYPE_ENGINE] = oEngine
lSuccess = .T.
ENDIF
ENDIF
RETURN lSuccess
ENDFUNC
PROCEDURE SearchInit()
LOCAL i
IF THIS.Wildcards
THIS.oSearchEngine = NEWOBJECT("Wildcard", "foxmatch.prg")
ELSE
THIS.oSearchEngine = NEWOBJECT("MatchDefault", "foxmatch.prg")
ENDIF
THIS.oSearchEngine.MatchCase = THIS.MatchCase
THIS.oSearchEngine.WholeWordsOnly = THIS.WholeWordsOnly
FOR i = 1 TO THIS.nFileTypecnt
WITH THIS.aFileTypes[i, FILETYPE_ENGINE]
.SetID = THIS.cSetID
.oSearchEngine = THIS.oSearchEngine
.Pattern = THIS.Pattern
.Comments = THIS.Comments
ENDWITH
ENDFOR
ENDPROC
* Do a replacement on designated file
FUNCTION ReplaceFile(cUniqueID, cReplaceText)
LOCAL nSelect
LOCAL nFileTypeIndex
LOCAL cFileType
LOCAL oFoxRefRecord
LOCAL lSuccess
lSuccess = .F.
IF USED("FoxRefCursor") AND VARTYPE(cUniqueID) == 'C' AND !EMPTY(cUniqueID) AND (FoxRefCursor.UniqueID == cUniqueID OR SEEK(cUniqueID, "FoxRefCursor", "UniqueID"))
nSelect = SELECT()
cFilename = ADDBS(RTRIM(FoxRefCursor.Folder)) + RTRIM(FoxRefCursor.Filename)
IF FILE(cFilename)
cFileType = UPPER(JUSTEXT(cFilename))
nFileTypeIndex = ASCAN(THIS.aFileTypes, cFileType, -1, -1, 1, 14) && 14 = return row number, Exact On
IF nFileTypeIndex == 0
nFileTypeIndex = 1 && this is the default search/replace engine to use
ENDIF
SELECT FoxRefCursor
SCATTER MEMO NAME oFoxRefRecord
WITH THIS.aFileTypes[nFileTypeIndex, FILETYPE_ENGINE]
lSuccess = .ReplaceWith(cReplaceText, oFoxRefRecord)
ENDWITH
ENDIF
SELECT (nSelect)
ENDIF
RETURN lSuccess
ENDFUNC
PROCEDURE FileTypes_Assign(cFileTypes)
THIS.FileTypes = CHRTRAN(cFileTypes, ',;', ' ')
ENDFUNC
FUNCTION CreateRefTable(cRefTable)
LOCAL lSuccess
LOCAL cSafety
lSuccess = .T.
THIS.RefTable = ''
cSafety = SET("SAFETY")
SET SAFETY OFF
IF USED(JUSTSTEM(cRefTable))
USE IN (cRefTable)
ENDIF
CREATE TABLE (cRefTable) FREE ( ;
UniqueID C(10), ;
SetID C(10), ;
RefID C(10), ;
RefType C(1), ;
DefType C(1), ;
Folder C(240), ;
Filename C(100), ;
Symbol C(254), ;
ClassName C(254), ;
ProcName C(254), ;
ProcLineNo I, ;
LineNo I, ;
ColPos I, ;
MatchLen I, ;
RefCode C(254), ;
RecordID C(10), ;
UpdField C(10), ;
Checked L, ;
TimeStamp T NULL, ;
Inactive L ;
)
INDEX ON RefType TAG RefType
INDEX ON SetID TAG SetID
INDEX ON RefID TAG RefID
INDEX ON UniqueID TAG UniqueID
INDEX ON Filename TAG Filename
INDEX ON Checked TAG Checked
* add the record that holds our results window search position & other options
INSERT INTO (cRefTable) ( ;
UniqueID, ;
SetID, ;
RefType, ;
Folder, ;
FileName, ;
Symbol, ;
ClassName, ;
ProcName, ;
ProcLineNo, ;
LineNo, ;
ColPos, ;
MatchLen, ;
RefCode, ;
RecordID, ;
UpdField, ;
Timestamp, ;
Inactive ;
) VALUES ( ;
SYS(2015), ;
'', ;
REFTYPE_INIT, ;
THIS.ProjectFile, ;
'', ;
'', ;
'', ;
'', ;
0, ;
0, ;
0, ;
0, ;
'', ;
'', ;
'', ;
DATETIME(), ;
.F. ;
)
* IIF(THIS.ProjectName == PROJECT_GLOBAL, cProjectOrDir, ''), ;
* IIF(!(THIS.ProjectName == PROJECT_GLOBAL), cProjectOrDir, ''), ;
* IIF(cScope == SCOPE_FOLDER, cProjectOrDir, ''), ;
* IIF(cScope <> SCOPE_FOLDER, cProjectOrDir, ''), ;
THIS.RefTable = cRefTable
USE IN (JUSTSTEM(cRefTable))
SET Safety &cSafety
RETURN lSuccess
ENDFUNC
* Open a FoxRef table
* Return TRUE if table exists and it's in the correct format
* [lCreate] = True to create table if it doesn't exist
FUNCTION OpenRefTable(cRefTable)
LOCAL lSuccess
IF USED("FoxRefCursor")
USE IN FoxRefCursor
ENDIF
THIS.RefTable = ''
lSuccess = .T.
IF !FILE(FORCEEXT(cRefTable, "DBF"))
lSuccess = THIS.CreateRefTable(cRefTable)
ENDIF
IF lSuccess
USE (cRefTable) ALIAS FoxRefCursor IN 0 SHARED AGAIN
IF TYPE("FoxRefCursor.RefType") == 'C'
THIS.RefTable = cRefTable
ELSE
lSuccess = .F.
MESSAGEBOX(BADTABLE_LOC + CHR(10) + CHR(10) + FORCEEXT(cRefTable, "DBF"), MB_ICONSTOP, APPNAME_LOC)
ENDIF
ENDIF
RETURN lSuccess
ENDFUNC
* Abstract:
* Set a specific project to display result sets for.
* Pass an empty string or "global" to display result sets
* that are not associated with a project.
*
* Parameters:
* [cProject]
FUNCTION SetProject(cProjectFile, lOverwrite)
LOCAL lInUse
LOCAL lSuccess
LOCAL cRefTable
LOCAL i
LOCAL lFoundProject
lSuccess = .F.
IF VARTYPE(cProjectFile) <> 'C'
cProjectfile = THIS.ProjectFile
ENDIF
IF EMPTY(cProjectFile)
* use the active project if a project name is not passsed
IF Application.Projects.Count > 0
cProjectFile = Application.ActiveProject.Name
ELSE
cProjectFile = PROJECT_GLOBAL
ENDIF
lSuccess = .T.
ELSE
* make sure Project specified is open
IF cProjectFile == PROJECT_GLOBAL
lSuccess = .T.
ELSE
cProjectFile = UPPER(FORCEEXT(FULLPATH(cProjectFile), "PJX"))
FOR i = 1 TO Application.Projects.Count
IF UPPER(Application.Projects(i).Name) == cProjectFile
cProjectFile = Application.Projects(i).Name
lSuccess = .T.
EXIT
ENDIF
ENDFOR
IF !lSuccess
IF FILE(cProjectFile)
* open the project
MODIFY PROJECT (cProjectFile) NOWAIT
* search again to find where in the Projects collection it is
FOR i = 1 TO Application.Projects.Count
IF UPPER(Application.Projects(i).Name) == cProjectFile
cProjectFile = Application.Projects(i).Name
lSuccess = .T.
EXIT
ENDIF
ENDFOR
ENDIF
ENDIF
ENDIF
ENDIF
IF lSuccess
IF EMPTY(cProjectFile) OR cProjectFile == PROJECT_GLOBAL
THIS.ProjectFile = PROJECT_GLOBAL
cRefTable = ADDBS(HOME()) + GLOBAL_TABLE + RESULT_EXT
ELSE
THIS.ProjectFile = UPPER(cProjectFile)
cRefTable = ADDBS(JUSTPATH(cProjectFile)) + JUSTSTEM(cProjectFile) + RESULT_EXT
ENDIF
IF lOverwrite
lSuccess = THIS.CreateRefTable(cRefTable)
ELSE
lSuccess = THIS.OpenRefTable(cRefTable)
ENDIF
ENDIF
RETURN lSuccess
ENDFUNC
FUNCTION Search(cPattern)
IF VARTYPE(cPattern) <> 'C' OR EMPTY(cPattern)
DO FORM FoxRefFind WITH THIS
ELSE
IF THIS.SetProject(, THIS.OverwritePrior)
IF THIS.ProjectFile == PROJECT_GLOBAL OR EMPTY(THIS.ProjectFile)
THIS.FolderSearch(cPattern)
ELSE
THIS.ProjectSearch(cPattern)
ENDIF
ENDIF
ENDIF
ENDFUNC
* Determine if the Reference table we want to open is
* actually one of ours. If we're overwriting or a reference
* table doesn't exist for this project, then create a new
* Reference Table.
*
* Once we have a reference table, then we add a new record
* that represents the search criteria for this particular
* search.
FUNCTION UpdateRefTable(cScope, cPattern, cProjectOrDir)
LOCAL nSelect
LOCAL cSafety
LOCAL cSearchOptions
LOCAL cRefTable
nSelect = SELECT()
IF VARTYPE(cRefTable) <> 'C' OR EMPTY(cRefTable)
cRefTable = THIS.RefTable
ENDIF
IF EMPTY(cRefTable)
RETURN .F.
ENDIF
IF USED("FoxRefCursor")
USE IN FoxRefCursor
ENDIF
*!* IF FILE(FORCEEXT(cRefTable, "DBF"))
*!* IF !THIS.OpenRefTable(cRefTable)
*!* RETURN .F.
*!* ENDIF
*!* ENDIF
IF !THIS.OpenRefTable(cRefTable)
RETURN .F.
ENDIF
THIS.tTimeStamp = DATETIME()
* build a string representing the search options that
* we can store to the FoxRef cursor
cSearchOptions = IIF(THIS.Comments == COMMENTS_EXCLUDE, 'X', '') + ;
IIF(THIS.Comments == COMMENTS_ONLY, 'C', '') + ;
IIF(THIS.MatchCase, 'M', '') + ;
IIF(THIS.WholeWordsOnly, 'W', '') + ;
IIF(THIS.SubFolders, 'S', '') + ;
IIF(THIS.Wildcards, 'Z', '') + ;
';' + THIS.FileTypes
* if we've already searched for this same exact symbol
* with the same exact criteria in the same exact project/folder,
* then simply update what we have
SELECT FoxRefCursor
LOCATE FOR RefType == REFTYPE_SEARCH AND Folder == PADR(cProjectOrDir, LEN(FoxRefCursor.Folder)) AND Symbol == PADR(cPattern + PATTERN_EOL, LEN(FoxRefCursor.Symbol)) AND RefCode == PADR(cSearchOptions, LEN(FoxRefCursor.RefCode))
THIS.lRefreshMode = FOUND()
IF THIS.lRefreshMode
THIS.tTimeStamp = FoxRefCursor.TimeStamp
THIS.cSetID = FoxRefCursor.SetID
REPLACE ALL Inactive WITH .T. ;
FOR SetID == THIS.cSetID AND (RefType == REFTYPE_RESULT OR RefType == REFTYPE_DEFINITION) ;
IN FoxRefCursor
ELSE
THIS.cSetID = SYS(2015)
* add the record that specifies the search criteria, etc
INSERT INTO FoxRefCursor ( ;
UniqueID, ;
SetID, ;
RefType, ;
Folder, ;
FileName, ;
Symbol, ;
ClassName, ;
ProcName, ;
ProcLineNo, ;
LineNo, ;
ColPos, ;
MatchLen, ;
RefCode, ;
RecordID, ;
UpdField, ;
Timestamp, ;
Inactive ;
) VALUES ( ;
SYS(2015), ;
THIS.cSetID, ;
REFTYPE_SEARCH, ;
cProjectOrDir, ;
'', ;
cPattern + PATTERN_EOL, ;
'', ;
'', ;
0, ;
0, ;
0, ;
0, ;
cSearchOptions, ;
'', ;
'', ;
THIS.tTimeStamp, ;
.F. ;
)
ENDIF
SELECT (nSelect)
RETURN .T.
ENDFUNC
* -- Search a Folder
FUNCTION FolderSearch(cPattern, cFileDir)
LOCAL nFileCnt
LOCAL i, j
LOCAL cFileDir
LOCAL nFileTypesCnt
LOCAL cFileTypes
LOCAL lAutoYield
LOCAL ARRAY aFileList[1]
LOCAL ARRAY aFileTypes[1]
IF VARTYPE(cPattern) <> 'C'
cPattern = THIS.Pattern
ENDIF
IF VARTYPE(cFileDir) <> 'C' OR EMPTY(cFileDir)
cFileDir = ADDBS(THIS.FileDirectory)
ELSE
cFileDir = ADDBS(cFileDir)
ENDIF
IF !DIRECTORY(cFileDir)
RETURN .F.
ENDIF
THIS.SetProject(PROJECT_GLOBAL, THIS.OverwritePrior)
IF !THIS.UpdateRefTable(SCOPE_FOLDER, cPattern, cFileDir)
RETURN .F.
ENDIF
THIS.SearchInit()
cFileTypes = CHRTRAN(THIS.FileTypes, ',;', ' ')
nFileTypesCnt = ALINES(aFileTypes, cFileTypes, .T., ' ')
lAutoYield = _VFP.AutoYield
_VFP.AutoYield = .T.
THIS.ProcessFolder(cFileDir, cPattern, @aFileTypes, nFileTypesCnt)
THIS.CloseProgress()
_VFP.AutoYield = lAutoYield
THIS.UpdateLookForMRU(cPattern)
THIS.UpdateFolderMRU(cFileDir)
THIS.UpdateFileTypesMRU(cFileTypes)
RETURN .T.
ENDFUNC
* used in conjuction with FolderSearch() for
* when we're searching subfolders
FUNCTION ProcessFolder(cFileDir, cPattern, aFileTypes, nFileTypesCnt)
LOCAL nFileCnt
LOCAL nFolderCnt
LOCAL cFilename
LOCAL i, j
LOCAL ARRAY aFileList[1]
LOCAL ARRAY aFolderList[1]
cFileDir = ADDBS(cFileDir)
FOR i = 1 TO nFileTypesCnt
IF THIS.lCancel
EXIT
ENDIF
nFileCnt = ADIR(aFileList, cFileDir + aFileTypes[i], '', 1)
FOR j = 1 TO nFileCnt
IF THIS.lCancel
EXIT
ENDIF
cFilename = aFileList[j, 1]
THIS.FileSearch(cFileDir + cFilename, cPattern)
ENDFOR
ENDFOR
* Process any sub-directories
IF !THIS.lCancel
IF THIS.SubFolders
nFolderCnt = ADIR(aFolderList, cFileDir + "*.*", 'D', 1)
FOR i = 1 TO nFolderCnt
IF !aFolderList[i, 1] == '.' AND !aFolderList[i, 1] == '..' AND 'D'$aFolderList[i, 5] AND DIRECTORY(cFileDir + aFolderList[i, 1])
THIS.ProcessFolder(cFileDir + aFolderList[i, 1], cPattern, @aFileTypes, nFileTypesCnt)
ENDIF
IF THIS.lCancel
EXIT
ENDIF
ENDFOR
ENDIF
ENDIF
ENDFUNC
* -- Search files in a Project
FUNCTION ProjectSearch(cPattern, cProjectFile)
LOCAL nFileIndex
LOCAL nProjectIndex
LOCAL oProjectRef
LOCAL oFileRef
LOCAL cFileTypes
LOCAL nFileTypesCnt
LOCAL lAutoYield
LOCAL lSuccess
LOCAL ARRAY aFileTypes[1]
LOCAL ARRAY aFileList[1]
IF VARTYPE(cPattern) <> 'C'
cPattern = THIS.Pattern
ENDIF
*!* IF VARTYPE(cProjectFile) == 'C' AND !EMPTY(cProjectFile)
*!* cProjectFile = UPPER(FORCEEXT(FULLPATH(cProjectFile), "PJX"))
*!* ELSE
*!* cProjectFile = ''
*!* ENDIF
*!* IF !THIS.SetProject(cProjectFile)
*!* RETURN .F.
*!* ENDIF
IF VARTYPE(cProjectFile) <> 'C' OR EMPTY(cProjectFile)
cProjectFile = THIS.ProjectFile
ENDIF
IF !THIS.SetProject(cProjectFile, THIS.OverwritePrior)
RETURN .F.
ENDIF
IF !THIS.UpdateRefTable(SCOPE_PROJECT, cPattern, THIS.ProjectFile)
RETURN .F.
ENDIF
THIS.SearchInit()
cFileTypes = THIS.FileTypes
lAutoYield = _VFP.AutoYield
_VFP.AutoYield = .T.
FOR EACH oProjectRef IN Application.Projects
IF UPPER(oProjectRef.Name) == THIS.ProjectFile
* process each file in the project
FOR EACH oFileRef IN oProjectRef.Files
IF THIS.WildCardMatch(cFileTypes, JUSTFNAME(oFileRef.Name))
THIS.FileSearch(oFileRef.Name, cPattern)
ENDIF
IF THIS.lCancel
EXIT
ENDIF
ENDFOR
EXIT
ENDIF
ENDFOR
THIS.CloseProgress()
_VFP.AutoYield = lAutoYield
THIS.UpdateLookForMRU(cPattern)
THIS.UpdateFileTypesMRU(cFileTypes)
RETURN .T.
ENDFUNC
* Search a file
FUNCTION FileSearch(cFilename, cPattern)
LOCAL cFileType
LOCAL nSelect
LOCAL cFileFind
LOCAL cFolderFind
LOCAL lSearch
LOCAL nSelect
LOCAL nFileTypeIndex
LOCAL ARRAY aFileList[1]
THIS.UpdateProgress(cFilename)
IF THIS.lCancel
RETURN
ENDIF
IF VARTYPE(cPattern) <> 'C'
cPattern = THIS.Pattern
ENDIF
nSelect = SELECT()
lSearch = .T.
* determine which search engine to use based upon the filetype
cFileType = UPPER(JUSTEXT(cFilename))
nFileTypeIndex = ASCAN(THIS.aFileTypes, cFileType, -1, -1, 1, 14) && 14 = return row number, Exact On
IF nFileTypeIndex == 0
nFileTypeIndex = 1 && this is the default search engine to use
ENDIF
WITH THIS.aFileTypes[nFileTypeIndex, FILETYPE_ENGINE]
.Filename = cFilename
* .FileTimeStamp = THIS.FileTimeStamp
* don't try to check the timestamp on a Table (DBF)
* because it isn't always updated when we modify
* certain things (such as values that are really stored in the
* database container)
IF THIS.lRefreshMode AND !.NoRefresh
* if we're refreshing results, then first see if
* we've already searched this file and the timestamp
* hasn't changed at all
cFileFind = PADR(JUSTFNAME(cFilename), 100)
cFolderFind = PADR(JUSTPATH(cFilename), 240)
SELECT FoxRefCursor
LOCATE FOR SetID == THIS.cSetID AND (RefType == REFTYPE_RESULT OR RefType == REFTYPE_DEFINITION OR RefType == REFTYPE_NOMATCH) AND FileName == cFileFind AND Folder == cFolderFind
IF FOUND()
IF FoxRefCursor.TimeStamp == .FileTimeStamp
UPDATE FoxRefCursor SET Inactive = .F. WHERE SetID == THIS.cSetID AND (RefType == REFTYPE_RESULT OR RefType == REFTYPE_DEFINITION OR RefType == REFTYPE_NOMATCH) AND FileName == cFileFind AND Folder == cFolderFind
lSearch = .F.
ENDIF
ENDIF
ENDIF
IF lSearch
.SearchFor(cPattern)
ENDIF
ENDWITH
SELECT (nSelect)
ENDFUNC
* refresh results for all Sets in the Ref table or a single set
FUNCTION RefreshResults(cSetID)
LOCAL nSelect
LOCAL lInUse
LOCAL i
LOCAL nCnt
LOCAL ARRAY aRefList[1]
nSelect = SELECT()
IF VARTYPE(cSetID) == 'C' AND !EMPTY(cSetID)
THIS.RefreshResultSet(cSetID)
ELSE
IF FILE(FORCEEXT(THIS.RefTable, "dbf"))
nSelect = SELECT()
lInUse = USED("FoxRefCursor")
IF !lInUse
USE (THIS.RefTable) ALIAS FoxRefCursor IN 0 SHARED AGAIN
ENDIF
SELECT SetID ;
FROM FoxRefCursor ;
WHERE RefType == REFTYPE_SEARCH AND !Inactive ;
INTO ARRAY aRefList
nCnt = _TALLY
*!* IF !lInUse AND USED("FoxRefCursor")
*!* USE IN FoxRefCursor
*!* ENDIF
FOR i = 1 TO nCnt
THIS.RefreshResultSet(aRefList[i])
ENDFOR
SELECT (nSelect)
ENDIF
THIS.cSetID = ''
ENDIF
ENDFUNC
* refresh an existing search set
FUNCTION RefreshResultSet(cSetID)
LOCAL lInUse
LOCAL nSelect
LOCAL lSuccess
LOCAL cScope
LOCAL cFolder
LOCAL cProject
LOCAL cPattern
LOCAL cSearchOptions
lSuccess = .F.
IF FILE(FORCEEXT(THIS.RefTable, "dbf"))
nSelect = SELECT()
lInUse = USED("FoxRefCursor")
IF !lInUse
USE (THIS.RefTable) ALIAS FoxRefCursor IN 0 SHARED AGAIN
ENDIF
SELECT FoxRefCursor
LOCATE FOR RefType == REFTYPE_SEARCH AND SetID == cSetID
lSuccess = FOUND()
IF lSuccess
cSearchOptions = LEFT(FoxRefCursor.RefCode, AT(';', FoxRefCursor.RefCode) - 1)
IF 'X'$cSearchOptions
THIS.Comments = COMMENTS_EXCLUDE
ENDIF
IF 'C'$cSearchOptions
THIS.Comments = COMMENTS_ONLY
ENDIF
THIS.MatchCase = 'M' $ cSearchOptions
THIS.WholeWordsOnly = 'W' $ cSearchOptions
THIS.SubFolders = 'S' $ cSearchOptions
THIS.Wildcards = 'Z' $ cSearchOptions
THIS.OverwritePrior = .F.
THIS.FileTypes = ALLTRIM(SUBSTR(FoxRefCursor.RefCode, AT(';', FoxRefCursor.RefCode) + 1))
cFolder = RTRIM(FoxRefCursor.Folder)
cProject = ''
IF UPPER(JUSTEXT(cFolder)) == "PJX"
cScope = SCOPE_PROJECT
cProject = cFolder
ELSE
cScope = SCOPE_FOLDER
ENDIF
IF PATTERN_EOL $ FoxRefCursor.Symbol
cPattern = LEFT(FoxRefCursor.Symbol, AT(PATTERN_EOL, FoxRefCursor.Symbol) - 1)
ELSE
cPattern = RTRIM(FoxRefCursor.Symbol)
ENDIF
ENDIF
IF !lInUse AND USED("FoxRefCursor")
USE IN FoxRefCursor
ENDIF
IF lSuccess
DO CASE
CASE cScope == SCOPE_FOLDER
THIS.FolderSearch(cPattern, cFolder)
CASE cScope == SCOPE_PROJECT
THIS.ProjectSearch(cPattern, cProject)
OTHERWISE
lSuccess = .F.
ENDCASE
ENDIF
SELECT (nSelect)
ENDIF
RETURN lSuccess
ENDFUNC
FUNCTION SetChecked(cUniqueID, lChecked)
IF PCOUNT() < 2
lChecked = .T.
ENDIF
IF USED("FoxRefCursor") AND SEEK(cUniqueID, "FoxRefCursor", "UniqueID")
REPLACE Checked WITH lChecked IN FoxRefCursor
ENDIF
ENDFUNC
* -- Show the Results form
FUNCTION ShowResults()
LOCAL i