A plethora of new optics

[skip ci]

Author: b-mehta

src/Control/Optics/Linear/Internal.hs

@@ -13,39 +13,48 @@ module Control.Optics.Linear.Internal
   , Iso, Iso'
   , Lens, Lens'
   , Prism, Prism'
-  , Traversal, Traversal'
+  , PTraversal, PTraversal'
+  , DTraversal, DTraversal'
     -- * Composing optics
   , (.>)
     -- * Common optics
   , swap, assoc
   , _1, _2
   , _Left, _Right
   , _Just, _Nothing
-  , traversed
+  , ptraversed, dtraversed
+  , both, both'
+  , get', gets', set'
     -- * Using optics
   , get, set, gets
   , match, match', build
+  , preview
   , over, over'
   , traverseOf, traverseOf'
   , lengthOf
   , withIso
+  , toListOf
     -- * Constructing optics
-  , iso, prism
+  , iso, prism, lens
   )
   where
 
 import qualified Data.Bifunctor.Linear as Bifunctor
 import Data.Bifunctor.Linear (SymmetricMonoidal)
 import Data.Functor.Const
 import Data.Functor.Linear
-import Data.Monoid
+import Data.Semigroup.Linear
 import Data.Profunctor.Linear
 import qualified Data.Profunctor.Kleisli.Linear as L
 import qualified Data.Profunctor.Kleisli.NonLinear as NL
 import Data.Void
-import Prelude.Linear
+import Prelude.Linear hiding ((<$>))
+-- ^ XXX: not entirely sure why the hiding is necessary here...
 import qualified Prelude as P
 
+-- TODO: documentation in this module
+-- Put the functions in some sensible order: possibly split into separate
+-- Lens/Prism/Traversal/Iso modules
 newtype Optic_ arr a b s t = Optical (a `arr` b -> s `arr` t)
 
 type Optic c a b s t =
@@ -57,8 +66,12 @@ type Lens a b s t = Optic (Strong (,) ()) a b s t
 type Lens' a s = Lens a a s s
 type Prism a b s t = Optic (Strong Either Void) a b s t
 type Prism' a s = Prism a a s s
-type Traversal a b s t = Optic Wandering a b s t
-type Traversal' a s = Traversal a a s s
+type PTraversal a b s t = Optic PWandering a b s t
+type PTraversal' a s = PTraversal a a s s
+type DTraversal a b s t = Optic DWandering a b s t
+type DTraversal' a s = DTraversal a a s s
+-- XXX: these will unify into
+-- type Traversal (p :: Multiplicity) a b s t = Optic (Wandering p) a b s t
 
 swap :: SymmetricMonoidal m u => Iso (a `m` b) (c `m` d) (b `m` a) (d `m` c)
 swap = iso Bifunctor.swap Bifunctor.swap
@@ -69,6 +82,10 @@ assoc = iso Bifunctor.lassoc Bifunctor.rassoc
 (.>) :: Optic_ arr a b s t -> Optic_ arr x y a b -> Optic_ arr x y s t
 Optical f .> Optical g = Optical (f P.. g)
 
+-- c is the complement (probably)
+lens :: (s ->. (c,a)) -> ((c,b) ->. t) -> Lens a b s t
+lens sca cbt = Optical $ \f -> dimap sca cbt (second f)
+
 prism :: (b ->. t) -> (s ->. Either t a) -> Prism a b s t
 prism b s = Optical $ \f -> dimap s (either id id) (second (rmap b f))
 
@@ -78,6 +95,37 @@ _1 = Optical first
 _2 :: Lens a b (c,a) (c,b)
 _2 = Optical second
 
+-- XXX: these will unify to
+-- > both :: forall (p :: Multiplicity). Traversal p a b (a,a) (b,b)
+both' :: PTraversal a b (a,a) (b,b)
+both' = _Pairing .> ptraversed
+
+both :: DTraversal a b (a,a) (b,b)
+both = _Pairing .> dtraversed
+
+-- XXX: these are a special case of Bitraversable, but just the simple case
+-- is included here for now
+_Pairing :: Iso (Pair a) (Pair b) (a,a) (b,b)
+_Pairing = iso Paired unpair
+
+newtype Pair a = Paired (a,a)
+unpair :: Pair a ->. (a,a)
+unpair (Paired x) = x
+
+instance P.Functor Pair where
+  fmap f (Paired (x,y)) = Paired (f x, f y)
+instance Functor Pair where
+  fmap f (Paired (x,y)) = Paired (f x, f y)
+instance Foldable Pair where
+  foldMap f (Paired (x,y)) = f x P.<> f y
+instance P.Traversable Pair where
+  traverse f (Paired (x,y)) = Paired P.<$> ((,) P.<$> f x P.<*> f y)
+instance Traversable Pair where
+  traverse f (Paired (x,y)) = Paired <$> ((,) <$> f x <*> f y)
+
+toListOf :: Optic_ (NL.Kleisli (Const [a])) a b s t -> s -> [a]
+toListOf l = gets l (\a -> [a])
+
 _Left :: Prism a b (Either a c) (Either b c)
 _Left = Optical first
 
@@ -90,8 +138,11 @@ _Just = prism Just (maybe (Left Nothing) Right)
 _Nothing :: Prism' () (Maybe a)
 _Nothing = prism (\() -> Nothing) Left
 
-traversed :: Traversable t => Traversal a b (t a) (t b)
-traversed = Optical wander
+ptraversed :: P.Traversable t => PTraversal a b (t a) (t b)
+ptraversed = Optical pwander
+
+dtraversed :: Traversable t => DTraversal a b (t a) (t b)
+dtraversed = Optical dwander
 
 over :: Optic_ LinearArrow a b s t -> (a ->. b) -> s ->. t
 over (Optical l) f = getLA (l (LA f))
@@ -105,6 +156,18 @@ get l = gets l P.id
 gets :: Optic_ (NL.Kleisli (Const r)) a b s t -> (a -> r) -> s -> r
 gets (Optical l) f s = getConst' (NL.runKleisli (l (NL.Kleisli (Const P.. f))) s)
 
+preview :: Optic_ (NL.Kleisli (Const (Maybe (First a)))) a b s t -> s -> Maybe a
+preview (Optical l) s = getFirst P.<$> (getConst (NL.runKleisli (l (NL.Kleisli (\a -> Const (Just (First a))))) s))
+
+get' :: Optic_ (L.Kleisli (Const (Top, a))) a b s t -> s ->. (Top, a)
+get' l = gets' l id
+
+gets' :: Optic_ (L.Kleisli (Const (Top, r))) a b s t -> (a ->. r) -> s ->. (Top, r)
+gets' (Optical l) f s = getConst' (L.runKleisli (l (L.Kleisli (\a -> Const (mempty, f a)))) s)
+
+set' :: Optic_ (L.Kleisli (MyFunctor a b)) a b s t -> s ->. b ->. (a, t)
+set' (Optical l) = runMyFunctor . L.runKleisli (l (L.Kleisli (\a -> MyFunctor (\b -> (a,b)))))
+
 set :: Optic_ (->) a b s t -> b -> s -> t
 set (Optical l) x = l (const x)
 
@@ -113,7 +176,7 @@ match (Optical l) = withIso swap (\x _ -> x) . L.runKleisli (l (L.Kleisli Left))
 
 -- will be redundant with multiplicity polymorphism
 match' :: Optic_ (NL.Kleisli (Either a)) a b s t -> s -> Either t a
-match' (Optical l) = withIso swap (\x _ -> forget x) P.. NL.runKleisli (l (NL.Kleisli Left))
+match' (Optical l) = withIso swap (\x _ -> eta x) P.. NL.runKleisli (l (NL.Kleisli Left))
 
 build :: Optic_ (L.CoKleisli (Const b)) a b s t -> b ->. t
 build (Optical l) x = L.runCoKleisli (l (L.CoKleisli getConst')) (Const x)

src/Data/Functor/Linear.hs

@@ -15,7 +15,9 @@
 module Data.Functor.Linear where
 
 import Prelude.Linear.Internal.Simple
+import Prelude (Maybe(..))
 import Data.Functor.Const
+import Data.Semigroup.Linear
 
 class Functor f where
   fmap :: (a ->. b) -> f a ->. f b
@@ -74,3 +76,11 @@ instance Traversable [] where
 
 instance Functor (Const x) where
   fmap _ (Const x) = Const x
+
+instance Monoid x => Applicative (Const x) where
+  pure _ = Const mempty
+  Const x <*> Const y = Const (x <> y)
+
+instance Functor Maybe where
+  fmap _ Nothing = Nothing
+  fmap f (Just x) = Just (f x)

src/Data/Profunctor/Kleisli/Linear.hs

@@ -42,8 +42,8 @@ instance Control.Applicative f => Strong Either Void (Kleisli f) where
   first  (Kleisli f) = Kleisli (either (Data.fmap Left . f) (Control.pure . Right))
   second (Kleisli g) = Kleisli (either (Control.pure . Left) (Data.fmap Right . g))
 
-instance Control.Applicative f => Wandering (Kleisli f) where
-  wander (Kleisli f) = Kleisli (Data.traverse f)
+instance Control.Applicative f => DWandering (Kleisli f) where
+  dwander (Kleisli f) = Kleisli (Data.traverse f)
 
 -- | Linear co-Kleisli arrows for the comonad `w`. These arrows are still
 -- useful in the case where `w` is not a comonad however, and some

src/Data/Profunctor/Kleisli/NonLinear.hs

@@ -13,7 +13,7 @@ module Data.Profunctor.Kleisli.NonLinear
 import Data.Profunctor.Linear
 import Data.Void
 import qualified Prelude
-import Prelude.Linear (Either(..), forget)
+import Prelude.Linear (Either(..), eta)
 import Prelude.Linear.Internal.Simple (($))
 
 -- Non-linear Kleisli arrows for the monad `m`. As in the linear case,
@@ -22,7 +22,7 @@ import Prelude.Linear.Internal.Simple (($))
 newtype Kleisli m a b = Kleisli { runKleisli :: a -> m b }
 
 instance Prelude.Functor f => Profunctor (Kleisli f) where
-  dimap f g (Kleisli h) = Kleisli (\x -> forget g Prelude.<$> h (f x))
+  dimap f g (Kleisli h) = Kleisli (\x -> eta g Prelude.<$> h (f x))
 
 instance Prelude.Functor f => Strong (,) () (Kleisli f) where
   first  (Kleisli f) = Kleisli (\(a,b) -> (,b) Prelude.<$> f a)

src/Data/Profunctor/Linear.hs

@@ -1,24 +1,33 @@
+{-# LANGUAGE GADTs #-}
 {-# LANGUAGE FlexibleContexts #-}
+{-# LANGUAGE FlexibleInstances #-}
 {-# LANGUAGE KindSignatures #-}
 {-# LANGUAGE LinearTypes #-}
 {-# LANGUAGE MultiParamTypeClasses #-}
 {-# LANGUAGE NoImplicitPrelude #-}
+{-# LANGUAGE RankNTypes #-}
 {-# LANGUAGE TupleSections #-}
 {-# LANGUAGE TypeOperators #-}
 
 module Data.Profunctor.Linear
   ( Profunctor(..)
   , Monoidal(..)
   , Strong(..)
-  , Wandering(..)
+  , PWandering(..)
+  , DWandering(..)
   , LinearArrow(..), getLA
   , Exchange(..)
+  , Top(..)
+  , MyFunctor(..), runMyFunctor
   ) where
 
 import qualified Data.Functor.Linear as Data
+import qualified Control.Monad.Linear as Control
 import Data.Bifunctor.Linear hiding (first, second)
 import Prelude.Linear
 import Data.Void
+import qualified Prelude
+import Data.Functor.Const
 
 -- TODO: write laws
 
@@ -52,8 +61,17 @@ class (SymmetricMonoidal m u, Profunctor arr) => Strong m u arr where
   second arr = dimap swap swap (first arr)
   {-# INLINE second #-}
 
-class (Strong (,) () arr, Strong Either Void arr) => Wandering arr where
-  wander :: Data.Traversable f => a `arr` b -> f a `arr` f b
+-- XXX: Just as Prelude.Functor/Data.Functor will combine into
+-- > `class Functor (p :: Multiplicity) f`
+-- so will Traversable, and then we would instead write
+-- > class (...) => Wandering (p :: Multiplicity) arr where
+-- >   wander :: Traversable p f => a `arr` b -> f a `arr` f b
+-- For now, however, we cannot do this, so we use two classes instead:
+-- PreludeWandering and DataWandering
+class (Strong (,) () arr, Strong Either Void arr) => PWandering arr where
+  pwander :: Prelude.Traversable f => a `arr` b -> f a `arr` f b
+class (Strong (,) () arr, Strong Either Void arr) => DWandering arr where
+  dwander :: Data.Traversable f => a `arr` b -> f a `arr` f b
 
 ---------------
 -- Instances --
@@ -82,7 +100,38 @@ instance Strong (,) () (->) where
 instance Strong Either Void (->) where
   first f (Left x) = Left (f x)
   first _ (Right y) = Right y
+instance PWandering (->) where
+  pwander = Prelude.fmap
 
 data Exchange a b s t = Exchange (s ->. a) (b ->. t)
 instance Profunctor (Exchange a b) where
   dimap f g (Exchange p q) = Exchange (p . f) (g . q)
+
+data Top = forall x. Top x
+instance Show Top where
+  show (Top _) = "something"
+instance Control.Functor (Const (Top, a)) where
+  fmap f (Const (Top t, x)) = Const (Top (t,f), x)
+instance Monoid a => Control.Applicative (Const (Top, a)) where
+  pure x = Const (Top x, mempty)
+  Const (Top a, x) <*> Const (Top b, y) = Const (Top (a,b), x <> y)
+
+-- TODO: pick a more sensible name for this
+newtype MyFunctor a b t = MyFunctor (b ->. (a, t))
+runMyFunctor :: MyFunctor a b t ->. b ->. (a, t)
+runMyFunctor (MyFunctor f) = f
+
+instance Data.Functor (MyFunctor a b) where
+  fmap f (MyFunctor g) = MyFunctor (getLA (second (LA f)) . g)
+instance Control.Functor (MyFunctor a b) where
+  fmap f (MyFunctor g) = MyFunctor (thing f . g)
+    where thing :: (c ->. d) ->. (e, c) ->. (e, d)
+          thing k (x,y) = (x, k y)
+
+instance Prelude.Semigroup Top where
+  Top x <> Top y = Top (x,y)
+instance Semigroup Top where
+  Top x <> Top y = Top (x,y)
+instance Prelude.Monoid Top where
+  mempty = Top ()
+instance Monoid Top where

src/Data/Semigroup/Linear.hs

@@ -0,0 +1,70 @@
+{-# LANGUAGE DerivingVia #-}
+{-# LANGUAGE GeneralizedNewtypeDeriving #-}
+{-# LANGUAGE LinearTypes #-}
+{-# LANGUAGE NoImplicitPrelude #-}
+{-# LANGUAGE StandaloneDeriving #-}
+
+-- | = The linear semigroup hierarchy
+--
+-- TODO: documentation
+
+module Data.Semigroup.Linear
+  ( Semigroup(..)
+  , Monoid(..)
+  , LEndo(..), appLEndo
+  , module Data.Semigroup
+  )
+  where
+
+import Prelude.Linear.Internal.Simple
+import Data.Semigroup hiding (Semigroup(..))
+import qualified Data.Semigroup as Prelude
+import qualified Prelude
+import qualified Unsafe.Linear as Unsafe
+
+class Prelude.Semigroup a => Semigroup a where
+  (<>) :: a ->. a ->. a
+
+class (Semigroup a, Prelude.Monoid a) => Monoid a where
+  {-# MINIMAL #-}
+  mempty :: a
+  mempty = mempty
+  -- convenience redefine
+
+---------------
+-- Instances --
+---------------
+
+instance Semigroup () where
+  () <> () = ()
+
+data LEndo a = LEndo (a ->. a)
+
+appLEndo :: LEndo a ->. a ->. a
+appLEndo (LEndo f) = f
+
+instance Prelude.Semigroup (LEndo a) where
+  LEndo f <> LEndo g = LEndo (f . g)
+instance Prelude.Monoid (LEndo a) where
+  mempty = LEndo id
+instance Semigroup (LEndo a) where
+  LEndo f <> LEndo g = LEndo (f . g)
+instance Monoid (LEndo a) where
+
+instance (Semigroup a, Semigroup b) => Semigroup (a,b) where
+  (a,x) <> (b,y) = (a <> b, x <> y)
+instance (Monoid a, Monoid b) => Monoid (a,b)
+
+newtype LWrap a = LWrap a
+  deriving (Prelude.Semigroup, Prelude.Monoid)
+
+-- This instance is unsafe: do not export LWrap so it cannot be used.
+instance Prelude.Semigroup a => Semigroup (LWrap a) where
+  LWrap a <> LWrap b = LWrap (Unsafe.toLinear2 (Prelude.<>) a b)
+instance Prelude.Monoid a => Monoid (LWrap a)
+
+-- XXX: I think these are safe but I'm not fully confident
+deriving via (LWrap (Sum a)) instance Prelude.Num a => Semigroup (Sum a)
+deriving via (LWrap (Sum a)) instance Prelude.Num a => Monoid (Sum a)
+deriving via (LWrap (Product a)) instance Prelude.Num a => Semigroup (Product a)
+deriving via (LWrap (Product a)) instance Prelude.Num a => Monoid (Product a)