build.gradle

plugins {
    id 'java-library'
    id 'io.freefair.lombok' version '8.10'
    id 'maven-publish'
    id 'signing'
    id 'org.jreleaser' version '1.14.0'
}

group 'io.github.ya-b'
version '0.1.4'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

repositories {
    mavenCentral()
}

dependencies {
    implementation 'net.jodah:expiringmap:0.5.11'
    implementation 'com.google.code.gson:gson:2.10'
    implementation 'com.squareup.okhttp3:okhttp:4.12.0'
    implementation 'org.apache.commons:commons-compress:1.26.1'
    implementation 'org.slf4j:slf4j-api:2.0.12'
    testImplementation 'ch.qos.logback:logback-classic:1.3.0'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.3'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.3'
}

test {
    useJUnitPlatform()
}

java {
    withJavadocJar()
    withSourcesJar()
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
    options.encoding = "UTF-8"
    failOnError = false
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId project.name
            from components.java
            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
            pom {
                name = 'registry-client'
                description = 'A java client for docker registry api v2'
                url = 'https://github.com/ya-b/registry-client.git'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'ya-b'
                        name = 'yangbo'
                        email = 'ya-b@outlook.com'
                    }
                }
                scm {
                    url = 'https://github.com/ya-b/registry-client.git'
                    connection = 'scm:git:https://github.com/ya-b/registry-client.git'
                    developerConnection = 'scm:git:https://github.com/ya-b/registry-client.git'
                }
            }

        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
    }
}

jreleaser {
    signing {
        active = 'ALWAYS'
        armored = true
    }
    deploy {
        maven {
            mavenCentral {
                sonatype {
                    active = 'ALWAYS'
                    url = 'https://central.sonatype.com/api/v1/publisher'
                    stagingRepository('build/staging-deploy')
                }
            }
        }
    }
}

static def updateReadMeVersion(String ver) {
    var file = new File("README.md")
    var content = new String(file.readBytes())
    var newContent = content.replaceAll("<version>\\d+\\.\\d+\\.\\d+</version>", "<version>$ver</version>")
    if (newContent != content) {
        file.write(newContent)
    }
}
updateReadMeVersion(version)