wsdl2java/build.gradle at master · yupzip/wsdl2java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
plugins {
    id "groovy"
    id "maven-publish"
    id "java-gradle-plugin"
    id 'com.gradle.plugin-publish' version '2.1.0'
    id 'idea'
    id 'eclipse'
}

group = 'com.yupzip'
version = '4.0.0'

compileJava {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    options.compilerArgs << '-parameters'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation localGroovy()

    testImplementation gradleTestKit()

    runtimeOnly "org.jetbrains.kotlin:kotlin-gradle-plugin:2.3.20"
}

java {
    withSourcesJar()
}

test {
    useJUnitPlatform()
}

gradlePlugin {
    website = 'https://github.com/yupzip/wsdl2java'
    vcsUrl = 'https://github.com/yupzip/wsdl2java'
    plugins {
        create('wsdl2java') {
            id = 'com.yupzip.wsdl2java'
            implementationClass = 'com.yupzip.wsdl2java.Wsdl2JavaPlugin'
            displayName = 'com.yupzip.wsdl2java'
            description = 'Generate java code form wsdl/xsd with cxf'
            tags.set(['wsdl2java'])
        }
    }
}

publishing {
    publications {
        create('mavenPublication', MavenPublication) {
            from components.java
        }
    }
}

wrapper {
    gradleVersion = '9.4.1'
}