zipzip-server/build.gradle at develop · zipzip-team/zipzip-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.15'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'com.diffplug.spotless' version '8.7.0'
}

group = 'org.zipzip'
version = '0.0.1-SNAPSHOT'
description = 'zipzip-server'

ext['commons-lang3.version'] = '3.20.0'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

repositories {
    mavenCentral()
}

dependencyManagement {
    imports {
        mavenBom 'software.amazon.awssdk:bom:2.47.4'
    }
}

dependencies {
    implementation 'software.amazon.awssdk:s3'
    implementation 'software.amazon.awssdk:apache5-client'
    implementation 'com.nimbusds:nimbus-jose-jwt:10.6'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.flywaydb:flyway-core'
    implementation 'org.flywaydb:flyway-database-postgresql'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.17'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.boot:spring-boot-testcontainers'
    testImplementation 'org.testcontainers:junit-jupiter'
    testImplementation 'org.testcontainers:postgresql'
    testRuntimeOnly 'com.h2database:h2'
    runtimeOnly 'org.postgresql:postgresql'
    testCompileOnly 'org.projectlombok:lombok'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testAnnotationProcessor 'org.projectlombok:lombok'
}

tasks.named('test') {
    useJUnitPlatform {
        if (!project.hasProperty('includeBenchmark')) {
            excludeTags 'benchmark'
        }
    }
}

spotless {
    java {
        googleJavaFormat('1.35.0').aosp().reflowLongStrings()
        removeUnusedImports()
        trimTrailingWhitespace()
        endWithNewline()
    }

    format 'misc', {
        target '*.gradle', '*.md', '*.yml', '*.yaml', '.gitignore', '.env.example'
        targetExclude 'build/**'
        trimTrailingWhitespace()
        endWithNewline()
    }
}

def isCi = providers.environmentVariable('CI').isPresent()

if (!isCi) {
    tasks.named('compileJava') {
        dependsOn 'spotlessJavaApply'
    }
}