Move to gradle and paper weight

.gitattributes

@@ -0,0 +1,9 @@
+#
+# https://help.github.com/articles/dealing-with-line-endings/
+#
+# Linux start script should use lf
+/gradlew        text eol=lf
+
+# These are Windows script files and should use crlf
+*.bat           text eol=crlf
+

.gitignore

@@ -105,4 +105,11 @@ $RECYCLE.BIN/
 *.msp
 
 # Windows shortcuts
-*.lnk
+*.lnk
+# Ignore Gradle project-specific cache directory
+.gradle
+
+# Ignore Gradle build output directory
+build
+
+run/

build.gradle.kts

@@ -0,0 +1,110 @@
+import io.papermc.paperweight.userdev.ReobfArtifactConfiguration
+
+plugins {
+    java
+    id("io.papermc.paperweight.userdev") version "2.0.0-beta.14" apply false
+    id("xyz.jpenilla.run-paper") version "2.3.1"
+    id("com.gradleup.shadow") version "8.3.5"
+}
+
+java.disableAutoTargetJvm()
+
+//repos
+allprojects {
+    repositories {
+        mavenCentral()
+        maven {
+            name = "jitpack.io"
+            url = uri("https://jitpack.io")
+        }
+        maven {
+            name = "spigot-repo"
+            url = uri("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
+        }
+        maven {
+            name = "papermc"
+            url = uri("https://repo.papermc.io/repository/maven-public/")
+        }
+        maven {
+            name = "lauriichan-release"
+            url = uri("https://maven.lauriichan.me/release")
+        }
+        maven {
+            name = "jeff-media-public"
+            url = uri("https://hub.jeff-media.com/nexus/repository/jeff-media-public/")
+        }
+        maven {
+            name = "enginehub"
+            url = uri("https://maven.enginehub.org/repo/")
+        }
+        maven {
+            name = "placeholderapi"
+            url = uri("https://repo.extendedclip.com/content/repositories/placeholderapi/")
+        }
+        maven {
+            name = "codemc-repo"
+            url = uri("https://repo.codemc.io/repository/maven-public/")
+        }
+    }
+}
+
+subprojects {
+    apply(plugin = "java")
+    apply(plugin = "com.gradleup.shadow")
+
+    ext {
+        set("paperCompiler", ReobfArtifactConfiguration.REOBF_PRODUCTION)
+    }
+
+    //common dependencies
+    dependencies {
+        compileOnly("io.netty:netty-all:4.1.87.Final")
+    }
+
+    //if we are an NMS module
+    if (this@subprojects.name.startsWith("v1_")) {
+        //apply paper weight
+        apply(plugin = "io.papermc.paperweight.userdev")
+
+        //make sure it requires core
+        dependencies.implementation(project(":core"))
+
+        //make assemble require the re-obfuscated jar
+        this@subprojects.tasks {
+            assemble {
+                dependsOn("reobfJar")
+            }
+            withType<Javadoc>().configureEach {
+                options.encoding = Charsets.UTF_8.name() // We want UTF-8 for everything
+            }
+            withType<JavaCompile>().configureEach {
+                // Defaults to java 17, needs to be overridden in newer versions!
+                options.release = 17
+            }
+        }
+    }
+}
+
+tasks {
+    assemble {
+        dependsOn("shadowJar")
+    }
+    runServer {
+        version("1.21.4")
+    }
+}
+
+dependencies {
+    subprojects.forEach {
+        //if its a version jar we want the reobf variant
+        if (it.name.startsWith("v1_")) {
+            runtimeOnly(project(":${it.name}", configuration = "reobf"))
+        } else {
+            implementation(it)
+        }
+    }
+}
+
+java {
+    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
+}

core/build.gradle.kts

@@ -0,0 +1,41 @@
+plugins {
+    java
+    `maven-publish`
+}
+
+dependencies {
+    compileOnly("org.spigotmc", "spigot-api", "1.20.1-R0.1-SNAPSHOT")
+    compileOnly("io.papermc.paper:paper-api:1.20-R0.1-SNAPSHOT")
+
+    implementation("com.jeff-media:MorePersistentDataTypes:2.4.0")
+    implementation("com.jeff-media:custom-block-data:2.2.2")
+
+    compileOnly("me.lauriichan.spigot.justlootit:justlootit-core:1.7.0")
+    compileOnly("me.lauriichan.spigot.justlootit:justlootit-nms-api:1.7.0") {
+        exclude("me.lauriichan.laylib")
+    }
+    compileOnly("com.github.MilkBowl:VaultAPI:1.7")
+    compileOnly("com.sk89q.worldedit:worldedit-bukkit:7.3.0-SNAPSHOT")
+    compileOnly("com.sk89q.worldguard:worldguard-bukkit:7.1.0-SNAPSHOT")
+    compileOnly("me.clip:placeholderapi:2.11.6")
+    compileOnly("net.kyori:adventure-text-minimessage:4.17.0")
+    compileOnly("commons-io:commons-io:2.17.0")
+    compileOnly("org.bstats:bstats-bukkit:3.0.3")
+    compileOnly("com.github.decentsoftware-eu:decentholograms:2.8.5")
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("maven") {
+            groupId = "${rootProject.group}"
+            artifactId = "valhallammo-core"
+            version = "${rootProject.version}"
+
+            pom {
+                name.set("ValhallaMMO")
+                description.set(rootProject.description)
+            }
+        }
+    }
+}
+